From: Lars Wendler <polynomial-c@gentoo.org>
Date: Mon, 10 Sep 2018 12:29:30 +0000 (+0200)
Subject: media-libs/openal: Bump to version 1.19.0
X-Git-Url: http://git.tremily.us/?a=commitdiff_plain;h=182fd8abb25293831695d2d6eee32311b7d21924;p=gentoo.git

media-libs/openal: Bump to version 1.19.0

Package-Manager: Portage-2.3.49, Repoman-2.3.10
---

diff --git a/media-libs/openal/Manifest b/media-libs/openal/Manifest
index 05af4b283e98..8e8fbf9f0419 100644
--- a/media-libs/openal/Manifest
+++ b/media-libs/openal/Manifest
@@ -1 +1,2 @@
 DIST openal-soft-1.18.2.tar.bz2 639420 BLAKE2B 8e31db9d3c6eb49fe4833a6449603dc6284e39810942536594fb5e96d0bc2b867b69bd90e64d40cf99f9a279f3809509cf1c9af3114a4887057e78962a5463e8 SHA512 752e2fb0a5a014caa6d6bac1590d3df46140b463fbaa13378fb5de89f1c97ee8b62bec74f68484d4ec02ee8755c1a2d0c9394cdb477db1b7401deae2fb9eeb4d
+DIST openal-soft-1.19.0.tar.bz2 575163 BLAKE2B 492166cccdfb0d5f35a2d731d2194ab844d89e7754ee636fc00969abe68026d9ffa1ce05c1b75f1c465ba413e1d16c1aee7e0dc86e24c97cbacb29353de20b73 SHA512 5fb8f54f271b36970f29335952173300dde15a798b4ac60e8167143b5806ed3178cc4f400e1d8da4354c2c3f57f28c90064e61740264b70d7c605d7d1b4273b3
diff --git a/media-libs/openal/openal-1.19.0.ebuild b/media-libs/openal/openal-1.19.0.ebuild
new file mode 100644
index 000000000000..2238743146d4
--- /dev/null
+++ b/media-libs/openal/openal-1.19.0.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit cmake-multilib
+
+MY_P="${PN}-soft-${PV}"
+
+DESCRIPTION="A software implementation of the OpenAL 3D audio API"
+HOMEPAGE="http://kcat.strangesoft.net/openal.html"
+SRC_URI="http://kcat.strangesoft.net/openal-releases/${MY_P}.tar.bz2"
+
+LICENSE="LGPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
+IUSE="
+	alsa coreaudio debug jack oss portaudio pulseaudio sdl qt5
+	cpu_flags_x86_sse cpu_flags_x86_sse2 cpu_flags_x86_sse4_1
+	cpu_flags_arm_neon
+"
+
+RDEPEND="
+	alsa? ( >=media-libs/alsa-lib-1.0.27.2[${MULTILIB_USEDEP}] )
+	jack? ( virtual/jack[${MULTILIB_USEDEP}] )
+	portaudio? ( >=media-libs/portaudio-19_pre20111121-r1[${MULTILIB_USEDEP}] )
+	pulseaudio? ( >=media-sound/pulseaudio-2.1-r1[${MULTILIB_USEDEP}] )
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtwidgets:5
+	)
+	sdl? ( media-libs/libsdl2 )
+"
+DEPEND="${RDEPEND}
+	oss? ( virtual/os-headers )"
+
+S="${WORKDIR}/${MY_P}"
+
+DOCS=( alsoftrc.sample docs/env-vars.txt docs/hrtf.txt ChangeLog README.md )
+
+src_configure() {
+	# -DEXAMPLES=OFF to avoid FFmpeg dependency wrt #481670
+	my_configure() {
+		local mycmakeargs=(
+			-DALSOFT_BACKEND_SDL2=$(usex sdl)
+			-DALSOFT_REQUIRE_ALSA=$(usex alsa)
+			-DALSOFT_REQUIRE_COREAUDIO=$(usex coreaudio)
+			-DALSOFT_REQUIRE_JACK=$(usex jack)
+			-DALSOFT_REQUIRE_OSS=$(usex oss)
+			-DALSOFT_REQUIRE_PORTAUDIO=$(usex portaudio)
+			-DALSOFT_REQUIRE_PULSEAUDIO=$(usex pulseaudio)
+			-DALSOFT_CPUEXT_SSE=$(usex cpu_flags_x86_sse)
+			-DALSOFT_CPUEXT_SSE2=$(usex cpu_flags_x86_sse2)
+			-DALSOFT_CPUEXT_SSE4_1=$(usex cpu_flags_x86_sse4_1)
+			-DALSOFT_UTILS=$(multilib_is_native_abi && echo "ON" || echo "OFF")
+			-DALSOFT_NO_CONFIG_UTIL=$(usex qt5 "$(multilib_is_native_abi && echo "OFF" || echo "ON")" ON)
+			-DALSOFT_EXAMPLES=OFF
+		)
+
+		use cpu_flags_arm_neon && mycmakeargs+=( -DALSOFT_CPUEXT_NEON=$(usex cpu_flags_arm_neon) )
+
+		cmake-utils_src_configure
+	}
+
+	multilib_parallel_foreach_abi my_configure
+}