From: Pacho Ramos <pacho@gentoo.org>
Date: Tue, 1 May 2018 12:31:16 +0000 (+0200)
Subject: games-puzzle/ltris: Stop using games.eclass
X-Git-Url: http://git.tremily.us/?a=commitdiff_plain;h=0103fbd77542af2a771b2eb9df24d982fb3202f9;p=gentoo.git

games-puzzle/ltris: Stop using games.eclass

Package-Manager: Portage-2.3.31, Repoman-2.3.9
---

diff --git a/games-puzzle/ltris/ltris-1.0.19-r1.ebuild b/games-puzzle/ltris/ltris-1.0.19-r1.ebuild
new file mode 100644
index 000000000000..9f3d02d2cc06
--- /dev/null
+++ b/games-puzzle/ltris/ltris-1.0.19-r1.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit autotools desktop flag-o-matic
+
+DESCRIPTION="Very polished Tetris clone"
+HOMEPAGE="http://lgames.sourceforge.net/LTris/"
+SRC_URI="mirror://sourceforge/lgames/${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="nls"
+
+RDEPEND="
+	media-libs/libsdl[video]
+	media-libs/sdl-mixer
+	nls? ( virtual/libintl )
+"
+DEPEND="${RDEPEND}
+	nls? ( sys-devel/gettext )
+"
+
+src_prepare() {
+	default
+	eapply "${FILESDIR}"/${P}-gentoo.patch
+	mv configure.in configure.ac || die
+	AT_M4DIR=m4 eautoreconf
+	append-cflags -std=gnu89 # build with gcc5 (bug #570966)
+}
+
+src_configure() {
+	econf $(use_enable nls)
+}
+
+src_install() {
+	default
+	newicon icons/ltris48.xpm ${PN}.xpm
+	make_desktop_entry ltris LTris
+}