sys-apps/apparmor: version bump 2.13.1

Package-Manager: Portage-2.3.51, Repoman-2.3.12
Signed-off-by: Michael Palimaka <kensington@gentoo.org>

diff --git a/sys-apps/apparmor-utils/Manifest b/sys-apps/apparmor-utils/Manifest
index 0a6a3ee99d9cc374e2eb66602b177718bcbc34cf..1556178a53fe51c7827dae76c7cfddcc2ef5a9d0 100644 (file)
--- a/sys-apps/apparmor-utils/Manifest
+++ b/sys-apps/apparmor-utils/Manifest
@@ -1 +1,2 @@
 DIST apparmor-2.12.tar.gz 7258450 BLAKE2B c1d4e01d836c5f567ddb7c5ecf36dde6efccf1e59ae219824129fd5c92162a3fed7ebdc492f181ae132b07db068660078a9631543d40fd20ab0b44cd4c646d4c SHA512 d85fd47c66333fe5658ee5e977b32142697f6e36c575550712ee2ace2ad0fbf2aa59c8fd3b82ad8821c0190adf8cc150cf623ea09a84d5b32bde050a03dd6e9a
+DIST apparmor-2.13.1.tar.gz 7367615 BLAKE2B 34a5f42b32bd4790f1075b76dfa17dd5b5cedfde7074eb0c57a3982a47e7b4dd2570bc056a4f4a8064c6a126a4727829cf5dcc04a4912f009338206faa887017 SHA512 e4b9788ecc0b59285f17d5e87669f507bf849c15d0ac3833e8d1d6aa2ece7add15814c75f257cea9d71a709c1af4990d8b76773e59fd42dbf5cfa2de0f9495a7

diff --git a/sys-apps/apparmor-utils/apparmor-utils-2.13.1.ebuild b/sys-apps/apparmor-utils/apparmor-utils-2.13.1.ebuild
new file mode 100644 (file)
index 0000000..0407708
--- /dev/null
+++ b/sys-apps/apparmor-utils/apparmor-utils-2.13.1.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python3_{4,5,6} )
+inherit eapi7-ver perl-module python-r1 toolchain-funcs
+
+MY_PV="$(ver_cut 1-2)"
+
+DESCRIPTION="Additional userspace utils to assist with AppArmor profile management"
+HOMEPAGE="https://gitlab.com/apparmor/apparmor/wikis/home"
+SRC_URI="https://launchpad.net/apparmor/${MY_PV}/${PV}/+download/apparmor-${PV}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE=""
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RESTRICT="test"
+
+DEPEND="
+       dev-lang/perl
+       ~sys-libs/libapparmor-${PV}
+       ${PYTHON_DEPS}"
+RDEPEND="${DEPEND}
+       ~sys-libs/libapparmor-${PV}[perl,python]
+       ~sys-apps/apparmor-${PV}
+       dev-perl/Locale-gettext
+       dev-perl/RPC-XML
+       dev-perl/TermReadKey
+       virtual/perl-Data-Dumper
+       virtual/perl-Getopt-Long"
+
+S=${WORKDIR}/apparmor-${PV}
+
+src_prepare() {
+       default
+
+       sed -i binutils/Makefile \
+               -e 's/Bstatic/Bdynamic/g' || die
+}
+
+src_compile() {
+       python_setup
+
+       pushd utils > /dev/null || die
+       # launches non-make subprocesses causing "make jobserver unavailable"
+       # error messages to appear in generated code
+       emake -j1
+       popd > /dev/null || die
+
+       pushd binutils > /dev/null || die
+       export EXTRA_CFLAGS="${CFLAGS}"
+       emake CC="$(tc-getCC)" USE_SYSTEM=1
+       popd > /dev/null || die
+}
+
+src_install() {
+       pushd utils > /dev/null || die
+       perl_set_version
+       emake DESTDIR="${D}" PERLDIR="${D}/${VENDOR_LIB}/Immunix" \
+               VIM_INSTALL_PATH="${D}/usr/share/vim/vimfiles/syntax" install
+
+       install_python() {
+               "${PYTHON}" "${S}"/utils/python-tools-setup.py install --prefix=/usr \
+                       --root="${D}" --version="${PV}"
+       }
+
+       python_foreach_impl install_python
+       python_replicate_script "${D}"/usr/bin/aa-easyprof "${D}"/usr/sbin/apparmor_status \
+               "${D}"/usr/sbin/aa-{audit,autodep,cleanprof,complain,disable,enforce,genprof,logprof,mergeprof,status,unconfined}
+       popd > /dev/null || die
+
+       pushd binutils > /dev/null || die
+       emake install DESTDIR="${D}" USE_SYSTEM=1
+       popd > /dev/null || die
+}

diff --git a/sys-apps/apparmor/Manifest b/sys-apps/apparmor/Manifest
index 0a6a3ee99d9cc374e2eb66602b177718bcbc34cf..1556178a53fe51c7827dae76c7cfddcc2ef5a9d0 100644 (file)
--- a/sys-apps/apparmor/Manifest
+++ b/sys-apps/apparmor/Manifest
@@ -1 +1,2 @@
 DIST apparmor-2.12.tar.gz 7258450 BLAKE2B c1d4e01d836c5f567ddb7c5ecf36dde6efccf1e59ae219824129fd5c92162a3fed7ebdc492f181ae132b07db068660078a9631543d40fd20ab0b44cd4c646d4c SHA512 d85fd47c66333fe5658ee5e977b32142697f6e36c575550712ee2ace2ad0fbf2aa59c8fd3b82ad8821c0190adf8cc150cf623ea09a84d5b32bde050a03dd6e9a
+DIST apparmor-2.13.1.tar.gz 7367615 BLAKE2B 34a5f42b32bd4790f1075b76dfa17dd5b5cedfde7074eb0c57a3982a47e7b4dd2570bc056a4f4a8064c6a126a4727829cf5dcc04a4912f009338206faa887017 SHA512 e4b9788ecc0b59285f17d5e87669f507bf849c15d0ac3833e8d1d6aa2ece7add15814c75f257cea9d71a709c1af4990d8b76773e59fd42dbf5cfa2de0f9495a7

diff --git a/sys-apps/apparmor/apparmor-2.13.1.ebuild b/sys-apps/apparmor/apparmor-2.13.1.ebuild
new file mode 100644 (file)
index 0000000..fad630e
--- /dev/null
+++ b/sys-apps/apparmor/apparmor-2.13.1.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit systemd toolchain-funcs
+
+MY_PV="$(ver_cut 1-2)"
+
+DESCRIPTION="Userspace utils and init scripts for the AppArmor application security system"
+HOMEPAGE="https://gitlab.com/apparmor/apparmor/wikis/home"
+SRC_URI="https://launchpad.net/${PN}/${MY_PV}/${PV}/+download/${PN}-${PV}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="doc"
+
+RDEPEND="~sys-libs/libapparmor-${PV}"
+DEPEND="${RDEPEND}
+       dev-lang/perl
+       sys-devel/bison
+       sys-devel/flex
+       doc? ( dev-tex/latex2html )
+"
+
+S=${WORKDIR}/apparmor-${PV}/parser
+
+PATCHES=(
+       "${FILESDIR}/${PN}-2.13.1-makefile.patch"
+       "${FILESDIR}/${PN}-2.11.1-dynamic-link.patch"
+)
+
+src_prepare() {
+       default
+
+       # remove warning about missing file that controls features
+       # we don't currently support
+       sed -e "/installation problem/ctrue" -i rc.apparmor.functions || die
+}
+
+src_compile()  {
+       emake CC="$(tc-getCC)" CXX="$(tc-getCXX)" USE_SYSTEM=1 arch manpages
+       use doc && emake pdf
+}
+
+src_test() {
+       emake CXX="$(tc-getCXX)" USE_SYSTEM=1 check
+}
+
+src_install() {
+       emake DESTDIR="${D}" DISTRO="unknown" USE_SYSTEM=1 install
+
+       dodir /etc/apparmor.d/disable
+
+       newinitd "${FILESDIR}/${PN}-init" ${PN}
+       systemd_newunit "${FILESDIR}/apparmor.service" apparmor.service
+
+       use doc && dodoc techdoc.pdf
+
+       exeinto /usr/share/apparmor
+       doexe "${FILESDIR}/apparmor_load.sh"
+       doexe "${FILESDIR}/apparmor_unload.sh"
+}

diff --git a/sys-apps/apparmor/files/apparmor-2.13.1-makefile.patch b/sys-apps/apparmor/files/apparmor-2.13.1-makefile.patch
new file mode 100644 (file)
index 0000000..239ff81
--- /dev/null
+++ b/sys-apps/apparmor/files/apparmor-2.13.1-makefile.patch
@@ -0,0 +1,25 @@
+--- a/Makefile
++++ b/Makefile
+@@ -28,7 +28,7 @@
+ CONFDIR=/etc/apparmor
+ INSTALL_CONFDIR=${DESTDIR}${CONFDIR}
+ LOCALEDIR=/usr/share/locale
+-MANPAGES=apparmor.d.5 apparmor.7 apparmor_parser.8 subdomain.conf.5 aa-teardown.8
++MANPAGES=apparmor.d.5 apparmor.7 apparmor_parser.8 aa-teardown.8
+ 
+ YACC  := bison
+ YFLAGS        := -d
+@@ -371,11 +371,9 @@
+ .PHONY: install-indep
+ install-indep: indep
+       install -m 755 -d $(INSTALL_CONFDIR)
+-      install -m 644 subdomain.conf $(INSTALL_CONFDIR)
++      install -m 755 -d ${DESTDIR}/usr/libexec
+       install -m 644 parser.conf $(INSTALL_CONFDIR)
+-      install -m 755 -d ${DESTDIR}/var/lib/apparmor
+-      install -m 755 -d $(APPARMOR_BIN_PREFIX)
+-      install -m 755 rc.apparmor.functions $(APPARMOR_BIN_PREFIX)
++      install -m 755 rc.apparmor.functions ${DESTDIR}/usr/libexec
+       $(MAKE) -C po install NAME=${NAME} DESTDIR=${DESTDIR}
+       $(MAKE) install_manpages DESTDIR=${DESTDIR}
+