app-text/coolreader: use wxwidgets.eclass

See https://github.com/gentoo/gentoo/pull/6692
Closes: https://bugs.gentoo.org/642638
Package-Manager: Portage-2.3.19, Repoman-2.3.6

diff --git a/app-text/coolreader/coolreader-3.1.2.71-r3.ebuild b/app-text/coolreader/coolreader-3.1.2.71-r3.ebuild
new file mode 100644 (file)
index 0000000..9c7e43e
--- /dev/null
+++ b/app-text/coolreader/coolreader-3.1.2.71-r3.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+WX_GTK_VER="3.0"
+
+inherit cmake-utils wxwidgets
+
+if [ "${PV}" == 9999 ]
+then
+       inherit git-r3
+       # github mirror has some new commits to fix page margins settings
+       # sourceforge mirror saved as backup
+       #EGIT_REPO_URI="git://git.code.sf.net/p/crengine/crengine"
+       EGIT_REPO_URI="https://github.com/buggins/coolreader.git"
+       SRC_URI=""
+else
+       # git tag cr3.1.2-71
+       SRC_URI="https://dev.gentoo.org/~grozin/${P}.tar.bz2"
+fi
+
+DESCRIPTION="CoolReader - reader of eBook files (fb2,epub,htm,rtf,txt)"
+HOMEPAGE="https://sourceforge.net/projects/crengine/"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="wxwidgets"
+
+DEPEND="sys-libs/zlib
+       media-libs/libpng:0
+       virtual/jpeg:0
+       media-libs/freetype
+       wxwidgets? ( x11-libs/wxGTK:${WX_GTK_VER} )
+       !wxwidgets? ( dev-qt/qtcore:5 dev-qt/qtgui:5 dev-qt/qtwidgets:5 )"
+RDEPEND="${DEPEND}
+       wxwidgets? ( || ( media-fonts/liberation-fonts media-fonts/corefonts ) )"
+
+# 1st patch: To save cr3.ini to ~homedir.
+# 2nd patch: To build QT5 and WX GUI version of coolreader3;
+# setting correct vesrion number and years of cr3qt/cr3wx;
+# internal switching between wxGTK 2.8 or 3.0 version;
+# show wxWidgets version in "About" dialog window;
+# disabling "iCCP: known incorrect sRGB profile" warning popup window for wxwidgets GUI
+
+PATCHES=( "${FILESDIR}/cr3ini.diff" "${FILESDIR}/cr3.1.2.71-r1_qt5_wx.diff" )
+
+src_configure() {
+       CMAKE_USE_DIR="${S}"
+       CMAKE_BUILD_TYPE="Release"
+       if use wxwidgets; then
+               setup-wxwidgets
+               local mycmakeargs=(-D GUI=WX)
+       else
+               local mycmakeargs=(-D GUI=QT5)
+       fi
+       cmake-utils_src_configure
+}

diff --git a/app-text/coolreader/metadata.xml b/app-text/coolreader/metadata.xml
index afd1b4bc9da95ddd1d8367a56917ee1742867587..0bc14087cc2df02f4c26eed88be9c2bcdb7f1567 100644 (file)
--- a/app-text/coolreader/metadata.xml
+++ b/app-text/coolreader/metadata.xml
@@ -8,6 +8,9 @@
     A fast and small cross-platform XML/CSS based eBook reader for desktops and handheld devices.
     Supported formats: FB2, TXT, RTF, DOC, TCR, HTML, EPUB, CHM, PDB, MOBI.
   </longdescription>
+  <use>
+    <flag name="wxwidgets">Use <pkg>x11-libs/wxGTK</pkg> instead of Qt5</flag>
+  </use>
   <upstream>
     <remote-id type="sourceforge">crengine</remote-id>
   </upstream>