gnome-extra/gnome-weather: bump to 3.26.0

Signed-off-by: Mart Raudsepp <leio@gentoo.org>
Package-Manager: Portage-2.3.49, Repoman-2.3.11

diff --git a/gnome-extra/gnome-weather/Manifest b/gnome-extra/gnome-weather/Manifest
index a91afff3b26d16884cf12c32a0bdb299d0169b01..87a366a82a61e44eb4e1ae81de51a71ab7304716 100644 (file)
--- a/gnome-extra/gnome-weather/Manifest
+++ b/gnome-extra/gnome-weather/Manifest
@@ -1 +1,2 @@
 DIST gnome-weather-3.24.0.tar.xz 5358924 BLAKE2B 89091c0dd2e69109621450621a03231da9fc6032cfdc44386e632ab3e8e478fc9a02efff86417277fbdbd2c39d730efd76df1a787e14112dd0447b53715b5aff SHA512 c286c97dc1cbb4991e56ed49e8c788c6a58f0f0dcd5534812ee3e06a0570fd1bb0b45f7e35bdc11443f62dc3a2cd262db4f3d2b1f238cfc24236de88de4a4bce
+DIST gnome-weather-3.26.0.tar.xz 5362056 BLAKE2B 0a427f8be6f8b79346d106430f6673961d03ca6770940f92eb866859907c7dc2e11805091bd9715e922176acad5c971114c9df33e6551c8992051e6ef873a298 SHA512 adb5400ca2674142132e499880793f9c4fafaa9a4459b2718eb24180480f8e4e1edb81aad947283208c3fe32f1c662d380421efa1b6b57968268ca64318a33ff

diff --git a/gnome-extra/gnome-weather/gnome-weather-3.26.0.ebuild b/gnome-extra/gnome-weather/gnome-weather-3.26.0.ebuild
new file mode 100644 (file)
index 0000000..bc55ef1
--- /dev/null
+++ b/gnome-extra/gnome-weather/gnome-weather-3.26.0.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} )
+
+inherit gnome2 python-any-r1 virtualx
+
+DESCRIPTION="A weather application for GNOME"
+HOMEPAGE="https://wiki.gnome.org/Design/Apps/Weather"
+
+LICENSE="GPL-2+ LGPL-2+ MIT CC-BY-3.0 CC-BY-SA-3.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+
+RDEPEND="
+       >=app-misc/geoclue-2.3.1:2.0
+       >=dev-libs/gjs-1.50
+       >=dev-libs/glib-2.32:2
+       >=dev-libs/gobject-introspection-1.35.9:=
+       >=dev-libs/libgweather-3.25.91:=
+       gnome-base/gsettings-desktop-schemas
+       >=x11-libs/gtk+-3.11.4:3
+"
+# libxml2 required for glib-compile-resources
+DEPEND="${RDEPEND}
+       dev-libs/appstream-glib
+       dev-libs/libxml2:2
+       >=dev-util/intltool-0.26
+       virtual/pkgconfig
+       test? (
+               ${PYTHON_DEPS}
+               $(python_gen_any_dep 'dev-util/dogtail[${PYTHON_USEDEP}]') )
+"
+
+python_check_deps() {
+       use test && has_version "dev-util/dogtail[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+       use test && python-any-r1_pkg_setup
+}
+
+src_configure() {
+       gnome2_src_configure $(use_enable test dogtail)
+}
+
+src_test() {
+       virtx emake check TESTS_ENVIRONMENT="dbus-run-session"
+}