media-libs/gupnp-dlna: Version bump

Package-Manager: portage-2.2.27

diff --git a/media-libs/gupnp-dlna/Manifest b/media-libs/gupnp-dlna/Manifest
index a3dbc8ba56f7a27d3f17c3c6717353f2ff3166f7..8b9b935f6b3c652e3f53696ee3108ba971c05138 100644 (file)
--- a/media-libs/gupnp-dlna/Manifest
+++ b/media-libs/gupnp-dlna/Manifest
@@ -1 +1,2 @@
 DIST gupnp-dlna-0.10.3.tar.xz 328376 SHA256 dcbe5f5f721c76781f3d3bb1bfcdf9818df0905203d4e5759aecb9cb127872d5 SHA512 751969c117a21534a8137e3b89268518ee93a086e70a3d985656a14719c19abdae5c604195bbe68c114725be8ef3f56960b6288f82be59cb13b2e2ff27809f35 WHIRLPOOL b1f8680086564d661de5ff24ede40b635cc4e68597316a5c1ff1b55aa7082d9c7cd73d3e771ad0fa9540f666d36cdebc6a1df010544cf581470b92d727452069
+DIST gupnp-dlna-0.10.4.tar.xz 328596 SHA256 5641134baa8fe3a2e129de15fc6a992f2fe1006ea446b7566483eada4840e1d6 SHA512 167562dd493f6de0a7afd43337b8c191157b7903653c834c4219313e60e7725adf3d30f21f4c0655f9e6849677ecac80ea7d7e8a9786387204a387f1b9afa598 WHIRLPOOL 546dfed0a9ae93ceb73112855bf5a964d39d782fa215eb4fe6d0d054b0f851fa58e0c7309fa9e083a5a58eeb79dc1735a691bc32025ac09fa0f679ea44fa69fe

diff --git a/media-libs/gupnp-dlna/gupnp-dlna-0.10.4.ebuild b/media-libs/gupnp-dlna/gupnp-dlna-0.10.4.ebuild
new file mode 100644 (file)
index 0000000..7ab3dd1
--- /dev/null
+++ b/media-libs/gupnp-dlna/gupnp-dlna-0.10.4.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+GCONF_DEBUG="no"
+GNOME2_LA_PUNT="yes"
+VALA_USE_DEPEND="vapigen"
+
+inherit gnome2 vala
+
+DESCRIPTION="Library providing DLNA-related functionality for MediaServers"
+HOMEPAGE="https://wiki.gnome.org/Projects/GUPnP"
+
+LICENSE="LGPL-2"
+SLOT="2.0"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="+introspection"
+
+RDEPEND="
+       >=dev-libs/glib-2.34:2
+       >=dev-libs/libxml2-2.5:2
+       media-libs/gstreamer:1.0
+       media-libs/gst-plugins-base:1.0[introspection?]
+       introspection? ( >=dev-libs/gobject-introspection-0.6.4:= )
+"
+DEPEND="${RDEPEND}
+       >=dev-util/gtk-doc-am-1.11
+       virtual/pkgconfig
+       introspection? ( $(vala_depend) )
+"
+
+src_prepare() {
+       # Make doc parallel installable
+       cd "${S}"/doc/gupnp-dlna
+       sed -e "s/\(DOC_MODULE.*=\).*/\1${PN}-${SLOT}/" \
+               -e "s/\(DOC_MAIN_SGML_FILE.*=\).*/\1${PN}-docs-${SLOT}.sgml/" \
+               -i Makefile.am Makefile.in || die
+       sed -e "s/\(<book.*name=\"\)${PN}/\1${PN}-${SLOT}/" \
+               -i html/${PN}.devhelp2 || die
+       mv ${PN}-docs{,-${SLOT}}.sgml || die
+       mv ${PN}-overrides{,-${SLOT}}.txt || die
+       mv ${PN}-sections{,-${SLOT}}.txt || die
+       mv ${PN}{,-${SLOT}}.types || die
+       mv html/${PN}{,-${SLOT}}.devhelp2
+
+       cd "${S}"
+
+       use introspection && vala_src_prepare
+       gnome2_src_prepare
+}
+
+src_configure() {
+       gnome2_src_configure \
+               --disable-static \
+               $(use_enable introspection)
+}
+
+src_install() {
+       # Parallel install fails, upstream bug #720053
+       MAKEOPTS="${MAKEOPTS} -j1" gnome2_src_install
+}