sys-auth/google-authenticator-libpam-hardened: Initial live ebuild

Initial live ebuild for my fork of my hardened google-authenticator PAM
module.  Includes support for SHA-2 HMAC and 8-digit OTP codes, removes
bundled code and the possibility of incidentally sending your secrets
over to Google.

diff --git a/sys-auth/google-authenticator-libpam-hardened/google-authenticator-libpam-hardened-9999.ebuild b/sys-auth/google-authenticator-libpam-hardened/google-authenticator-libpam-hardened-9999.ebuild
new file mode 100644 (file)
index 0000000..9ce8f78
--- /dev/null
+++ b/sys-auth/google-authenticator-libpam-hardened/google-authenticator-libpam-hardened-9999.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+EGIT_REPO_URI="https://github.com/mgorny/google-authenticator-libpam-hardened.git"
+inherit autotools git-r3
+
+DESCRIPTION="PAM Module for two step verification via mobile platform"
+HOMEPAGE="https://github.com/mgorny/google-authenticator-libpam-hardened"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE="+qrcode"
+
+DEPEND="sys-auth/oath-toolkit:=
+       virtual/pam
+       qrcode? ( media-gfx/qrencode:= )"
+RDEPEND="${DEPEND}
+       !sys-auth/google-authenticator"
+
+src_prepare() {
+       default
+       eautoreconf
+}
+
+src_configure() {
+       local myconf=(
+               # TODO: use getpam_mod_dir after fixing build system
+               --libdir="/$(get_libdir)"
+
+               $(use_enable qrcode qrencode)
+       )
+
+       econf "${myconf[@]}"
+}
+
+src_install() {
+       default
+       find "${D}" -name '*.la' -delete || die
+}

diff --git a/sys-auth/google-authenticator-libpam-hardened/metadata.xml b/sys-auth/google-authenticator-libpam-hardened/metadata.xml
new file mode 100644 (file)
index 0000000..40610c9
--- /dev/null
+++ b/sys-auth/google-authenticator-libpam-hardened/metadata.xml
@@ -0,0 +1,15 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+       <maintainer type="person">
+               <email>mgorny@gentoo.org</email>
+               <name>Michał Górny</name>
+       </maintainer>
+       <use>
+               <flag name='qrcode'>Display QRcode after setup to accomodate
+                       automatic setup of OTP client apps.</flag>
+       </use>
+       <upstream>
+               <remote-id type="github">mgorny/google-authenticator-libpam-hardened</remote-id>
+       </upstream>
+</pkgmetadata>