dev-python/m2crypto: Bump to 0.35.2

Signed-off-by: Michał Górny <mgorny@gentoo.org>

diff --git a/dev-python/m2crypto/Manifest b/dev-python/m2crypto/Manifest
index 7e9058b257cd6d57b0309270c1edd861a432c4eb..7522684b83335286c2d8204c96d79a5112b10c0d 100644 (file)
--- a/dev-python/m2crypto/Manifest
+++ b/dev-python/m2crypto/Manifest
@@ -1 +1,2 @@
 DIST M2Crypto-0.31.0.tar.gz 1292016 BLAKE2B 3f1e0e8f686719ff87fa3a51cdc287be989fa1554866582deb1968fd04605270e14cbfd280f64211c043c5d8cb77a09e6a8cec6824ab15416ab94366aa73d2a3 SHA512 9f3e2afda4b8ac14aa64a1534e446eb6895ec7182ce5b7ded8008178e01139d383561a87f8c9fb5fe4b9c257ba5c6b93339955eb9e2f7417cd3f4832c35c4598
+DIST M2Crypto-0.35.2.tar.gz 1117706 BLAKE2B efa15e023be7755b94c642bb23eade912edcbbb76bcdfed3414d27937cd705ec4c83069ca620fe20e58e126549ba7f98e84f6f8330b78133a8a8b953d18f467b SHA512 3608b29a8e7d0732a2359e35fcaae191447aa7c0211ca3d057eed6cee7f0819f5c1121e7d41caca8cdea3c7911f8c447ee475b1b3d125e8dc3adde2718a59f36

diff --git a/dev-python/m2crypto/m2crypto-0.35.2.ebuild b/dev-python/m2crypto/m2crypto-0.35.2.ebuild
new file mode 100644 (file)
index 0000000..986af95
--- /dev/null
+++ b/dev-python/m2crypto/m2crypto-0.35.2.ebuild
@@ -0,0 +1,51 @@
+# Copyright 2018-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 python3_{5..7})
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+MY_PN="M2Crypto"
+DESCRIPTION="A Python crypto and SSL toolkit"
+HOMEPAGE="https://gitlab.com/m2crypto/m2crypto https://pypi.org/project/M2Crypto/"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_PN}-${PV}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos ~x86-macos"
+IUSE="libressl"
+
+RDEPEND="
+       !libressl? ( dev-libs/openssl:0= )
+       libressl? ( dev-libs/libressl:0= )
+       virtual/python-typing[${PYTHON_USEDEP}]
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+       >=dev-lang/swig-2.0.9
+       dev-python/setuptools[${PYTHON_USEDEP}]
+"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+PATCHES=(
+       "${FILESDIR}/${PN}-libressl-0.31.0.patch"
+)
+
+python_compile() {
+       # setup.py looks at platform.machine() to determine swig options.
+       # For exotic ABIs, we need to give swig a hint.
+       # https://bugs.gentoo.org/617946
+       local -x SWIG_FEATURES=
+       case ${ABI} in
+               x32) SWIG_FEATURES="-D__ILP32__" ;;
+       esac
+       distutils-r1_python_compile --openssl="${ESYSROOT}"/usr
+}
+
+python_test() {
+       esetup.py test
+}