net-misc/remmina: bump to 1.4.1

We skipped 1.4.0 due to a build error on USE=-ssh

Package-Manager: Portage-2.3.89, Repoman-2.3.20
Signed-off-by: Ben Kohler <bkohler@gentoo.org>

diff --git a/net-misc/remmina/Manifest b/net-misc/remmina/Manifest
index ee61d3d2e81531591f276f2e0db3932cc0fe31b5..8a1f2411a51f77ab3ef5e388d1fb616c343ee342 100644 (file)
--- a/net-misc/remmina/Manifest
+++ b/net-misc/remmina/Manifest
@@ -2,3 +2,4 @@ DIST Remmina-v1.3.10.tar.gz 1651065 BLAKE2B 8d2f3068ad0938c4641deb2c20ccef10e309
 DIST Remmina-v1.3.4.tar.gz 1365473 BLAKE2B f71a9c0a0fa9eafa547abf192972da39f0cfe1ca3745a87783d6a9ec5bab0674d93df8815b589b25659990bb345748f8f464f401c7efb934e8e71b207b0dab67 SHA512 212ebc6e08c694861522a05feb51e4efa012ef3361debf079384c07e4354370f6cf7d2880ff442bbe03782421bac7f33343d8049207073d90925d1c894d30e7a
 DIST Remmina-v1.3.6.tar.gz 1538166 BLAKE2B f3fc60df2a1a31bd5aae7d8de2d85cd579fa4cc35a0351fbce80433e21583b67cfc81665307d02fbd4863f6a55695be81f9c4d07423d6c8122d84dd625b69c3b SHA512 ce16379aa163467d05018c900d0dc7c2a7d73c1c22dd06a9a3092efa7675fda505bfa31b20131b9a3a10c74788377db17961c0bc9e59c47b1c7a15bf347f3bab
 DIST Remmina-v1.3.9.tar.gz 1627404 BLAKE2B 4077b38e987a93f71f96597784949522659def04ad0d2ab05c72bebb94a3bbf2c2a222828965aaf76b0273a378950b5dd0e7acdb7543f0d6c7f3220d16eb281c SHA512 f87d30d30d6d9692f60cd27336ac0059a4374125b231cdf1e3710785b08fc77722112ea48e5717958b03fc5784abb9fcd86aa5a427c4d634cb3f2be1aac41945
+DIST Remmina-v1.4.1.tar.gz 1662456 BLAKE2B 17bc53459e2073c1df3a53963ab9775ab61d41904e592177c815bba9cf74d586152bf5c3af6fd2430c1e8d3e0203747f2d4e13093fdc343bcb9e4ebafaf50046 SHA512 90e78cc488d3d695373043ce2f7db6626e5a92f284aaa9e81a6683f4e3a1b7b2f025eff3ce456b98a180b2afc2419da76daed95dd164692c15c2a2219a354397

diff --git a/net-misc/remmina/remmina-1.4.1.ebuild b/net-misc/remmina/remmina-1.4.1.ebuild
new file mode 100644 (file)
index 0000000..37a0550
--- /dev/null
+++ b/net-misc/remmina/remmina-1.4.1.ebuild
@@ -0,0 +1,98 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit cmake-utils eutils gnome2-utils xdg-utils
+
+MY_P="${PN^}-v${PV}"
+
+DESCRIPTION="A GTK+ RDP, SPICE, VNC, XDMCP and SSH client"
+HOMEPAGE="https://remmina.org/"
+SRC_URI="https://gitlab.com/Remmina/Remmina/-/archive/v${PV}/${MY_P}.tar.gz"
+
+LICENSE="GPL-2+-with-openssl-exception"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="ayatana crypt cups examples gnome-keyring kwallet libressl nls spice ssh rdp telepathy vnc webkit zeroconf"
+
+CDEPEND="
+       dev-libs/glib:2
+       dev-libs/json-glib
+       dev-libs/libsodium:=
+       net-libs/libsoup
+       x11-libs/gdk-pixbuf
+       x11-libs/gtk+:3
+       x11-libs/libX11
+       x11-libs/libxkbfile
+       ayatana? ( dev-libs/libappindicator:3 )
+       crypt? ( dev-libs/libgcrypt:0= )
+       rdp? ( >=net-misc/freerdp-2.0.0_rc4_p1129
+               cups? ( net-print/cups:= ) )
+       gnome-keyring? ( app-crypt/libsecret )
+       kwallet? ( kde-frameworks/kwallet )
+       !libressl? ( dev-libs/openssl:0= )
+       libressl? ( dev-libs/libressl:0= )
+       spice? ( net-misc/spice-gtk[gtk3] )
+       ssh? ( net-libs/libssh:0=[sftp]
+               x11-libs/vte:2.91 )
+       telepathy? ( net-libs/telepathy-glib )
+       vnc? ( net-libs/libvncserver[jpeg] )
+       webkit? ( net-libs/webkit-gtk:4 )
+       zeroconf? ( net-dns/avahi[dbus,gtk3] )
+"
+DEPEND="${CDEPEND}
+       dev-util/intltool
+       virtual/pkgconfig
+       nls? ( sys-devel/gettext )
+"
+RDEPEND="${CDEPEND}
+       virtual/freedesktop-icon-theme
+"
+
+DOCS=( AUTHORS CHANGELOG.md README.md THANKS.md )
+PATCHES=( "${FILESDIR}"/${PN}-gcc10.patch )
+
+S="${WORKDIR}/${MY_P}"
+
+src_configure() {
+       local mycmakeargs=(
+               -DWITH_APPINDICATOR=$(usex ayatana)
+               -DWITH_GCRYPT=$(usex crypt)
+               -DWITH_EXAMPLES=$(usex examples)
+               -DWITH_LIBSECRET=$(usex gnome-keyring)
+               -DWITH_KF5WALLET=$(usex kwallet)
+               -DWITH_GETTEXT=$(usex nls)
+               -DWITH_TRANSLATIONS=$(usex nls)
+               -DWITH_FREERDP=$(usex rdp)
+               -DWITH_CUPS=$(usex cups)
+               -DWITH_SPICE=$(usex spice)
+               -DWITH_LIBSSH=$(usex ssh)
+               -DWITH_VTE=$(usex ssh)
+               -DWITH_TELEPATHY=$(usex telepathy)
+               -DWITH_LIBVNCSERVER=$(usex vnc)
+               -DWITH_WWW=$(usex webkit)
+               -DWITH_AVAHI=$(usex zeroconf)
+               -DWITH_ICON_CACHE=OFF
+               -DWITH_UPDATE_DESKTOP_DB=OFF
+       )
+       cmake-utils_src_configure
+}
+
+pkg_postinst() {
+       gnome2_icon_cache_update
+       xdg_mimeinfo_database_update
+       xdg_desktop_database_update
+
+       elog "To get additional features, some optional runtime dependencies"
+       elog "may be installed:"
+       elog ""
+       optfeature "encrypted VNC connections" net-libs/libvncserver[gcrypt]
+       optfeature "XDMCP support" x11-base/xorg-server[xephyr]
+}
+
+pkg_postrm() {
+       gnome2_icon_cache_update
+       xdg_mimeinfo_database_update
+       xdg_desktop_database_update
+}