dev-python/appdirs: revbump to 1.4.3-r1, add py38 and EAPI=7

Copyright: Sony Interactive Entertainment Inc.
Package-Manager: Portage-2.3.79, Repoman-2.3.18
Signed-off-by: Patrick McLean <chutzpah@gentoo.org>

diff --git a/dev-python/appdirs/appdirs-1.4.3-r1.ebuild b/dev-python/appdirs/appdirs-1.4.3-r1.ebuild
new file mode 100644 (file)
index 0000000..c39cc51
--- /dev/null
+++ b/dev-python/appdirs/appdirs-1.4.3-r1.ebuild
@@ -0,0 +1,35 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 python3_{5,6,7,8} pypy{,3} )
+
+inherit distutils-r1
+
+DESCRIPTION="Module for determining appropriate platform-specific dirs"
+HOMEPAGE="https://github.com/ActiveState/appdirs"
+SRC_URI="https://github.com/ActiveState/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+
+PATCHES=( "${FILESDIR}"/${PN}-1.4.3-distutils.patch )
+
+python_test() {
+       "${PYTHON}" test/test_api.py -v || die "Tests fail with ${EPYTHON}"
+}
+
+[[ ${PV} == 1.4.3 ]] || die "Please remove pkg_preinst from the ebuild"
+pkg_preinst() {
+       _remove_egg_info() {
+               local pyver="$("${PYTHON}" -c 'import sys; print(sys.version[:3])')"
+               local egginfo="${ROOT}$(python_get_sitedir)/${P}-py${pyver}.egg-info"
+               if [[ -d ${egginfo} ]]; then
+                       einfo "Removing ${egginfo}"
+                       rm -r "${egginfo}" || die
+               fi
+       }
+       python_foreach_impl _remove_egg_info
+}