version bump

Package-Manager: portage-2.1.7.17/cvs/Linux i686

diff --git a/games-board/crafty/ChangeLog b/games-board/crafty/ChangeLog
index 31b12b336dc8375fee5af61b1bace87027687bc8..46c0072d3864d61158e6554ddf104c8bc5417cc3 100644 (file)
--- a/games-board/crafty/ChangeLog
+++ b/games-board/crafty/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for games-board/crafty
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-board/crafty/ChangeLog,v 1.39 2010/03/24 14:10:28 ranger Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-board/crafty/ChangeLog,v 1.40 2010/04/08 17:47:23 mr_bones_ Exp $
+
+*crafty-23.2 (08 Apr 2010)
+
+  08 Apr 2010; Michael Sterrett <mr_bones_@gentoo.org> +crafty-23.2.ebuild:
+  version bump
 
   24 Mar 2010; Brent Baude <ranger@gentoo.org> crafty-23.1.ebuild:
   stable ppc, bug 305903

diff --git a/games-board/crafty/crafty-23.2.ebuild b/games-board/crafty/crafty-23.2.ebuild
new file mode 100644 (file)
index 0000000..b95954b
--- /dev/null
+++ b/games-board/crafty/crafty-23.2.ebuild
@@ -0,0 +1,86 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/games-board/crafty/crafty-23.2.ebuild,v 1.1 2010/04/08 17:47:24 mr_bones_ Exp $
+
+EAPI=2
+inherit flag-o-matic toolchain-funcs games
+
+DESCRIPTION="Bob Hyatt's strong chess engine"
+HOMEPAGE="ftp://ftp.cis.uab.edu/pub/hyatt/"
+SRC_URI="http://www.craftychess.com/${P}.zip
+       ftp://ftp.cis.uab.edu/pub/hyatt/source/${P}.zip
+       ftp://ftp.cis.uab.edu/pub/hyatt/documentation/${PN}.doc.ascii"
+
+LICENSE="crafty"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="no-opts"
+RESTRICT="test"
+
+RDEPEND=""
+DEPEND="${RDEPEND}
+       app-arch/unzip"
+
+src_prepare() {
+       sed -i \
+               -e '/-o crafty/s/CC/CXX/' \
+               -e 's:CXFLAGS:CXXFLAGS:g' \
+               Makefile \
+               || die "sed failed"
+       sed -i \
+               -e "s:\"crafty.hlp\":\"${GAMES_DATADIR}/${PN}/crafty.hlp\":" option.c \
+               || die "sed failed"
+}
+
+src_compile() {
+       local makeopts="target=LINUX"
+
+       if ! use no-opts ; then
+               if [[ $(tc-getCC) = icc ]] ; then
+                       makeopts="${makeopts} asm=X86.o"
+                       append-flags -D_REENTRANT -tpp6 \
+                               -DCOMPACT_ATTACKS -DUSE_ATTACK_FUNCTIONS \
+                               -DUSE_ASSEMBLY_A -DUSE_ASSEMBLY_B -DFAST \
+                               -DSMP -DCPUS=4 -DCLONE -DDGT
+                       append-flags -O2 -fno-alias -fforce-mem \
+                               -fomit-frame-pointer -fno-gcse -mpreferred-stack-boundary=2
+               else
+                       if [[ "${CHOST}" == "i686-pc-linux-gnu" ]] \
+                       || [[ "${CHOST}" == "i586-pc-linux-gnu" ]] ; then
+                               append-flags -DCOMPACT_ATTACKS -DUSE_ATTACK_FUNCTIONS \
+                                       -DUSE_ASSEMBLY_A -DUSE_ASSEMBLY_B \
+                                       -DFAST -DSMP -DCPUS=4 -DCLONE -DDGT
+                               append-flags -fno-gcse \
+                                       -fomit-frame-pointer -mpreferred-stack-boundary=2
+                       elif [[ "${CHOST}" == "x86_64-pc-linux-gnu" ]] ; then
+                               append-flags -DCOMPACT_ATTACKS -DUSE_ATTACK_FUNCTIONS \
+                                       -DUSE_ASSEMBLY_A -DUSE_ASSEMBLY_B \
+                                       -DFAST -DSMP -DCPUS=4 -DCLONE -DDGT
+                               append-flags -fomit-frame-pointer
+                       else
+                               : # everything else :)
+                       fi
+               fi
+       fi
+       append-flags -DPOSIX -DSKILL
+       emake ${makeopts} crafty-make LDFLAGS="${LDFLAGS} -pthread" || die "build failed"
+}
+
+src_install() {
+       dogamesbin crafty || die "dogamesbin failed"
+       insinto "${GAMES_DATADIR}/${PN}"
+       doins crafty.hlp || die "doins failed"
+       dodoc "${DISTDIR}"/crafty.doc.ascii
+       prepgamesdirs
+}
+
+pkg_postinst() {
+       games_pkg_postinst
+       elog
+       elog "Note: No books or tablebases have been installed. If you want them, just"
+       elog "      download them from ${HOMEPAGE}."
+       elog "      You will find documentation there too. In most cases you take now "
+       elog "      your xboard compatible application, (xboard, eboard, knights) and "
+       elog "      just play chess against computer opponent. Have fun."
+       elog
+}