media-video/obs-studio: add missing 'dev-qt/qtsvg' dependency

Upstream started depending on this in '80875768'.

- https://github.com/obsproject/obs-studio/commit/80875768

Closes: https://bugs.gentoo.org/684906
Closes: https://github.com/gentoo/gentoo/pull/11652
Suggested-by: Jiří Helebrant <jiri.helebrant@nic.cz>
Package-Manager: Portage-2.3.66, Repoman-2.3.12
Signed-off-by: Jimi Huotari <chiitoo@gentoo.org>
Closes: https://github.com/gentoo/gentoo/pull/11886
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

diff --git a/media-video/obs-studio/obs-studio-23.1.0-r1.ebuild b/media-video/obs-studio/obs-studio-23.1.0-r1.ebuild
new file mode 100644 (file)
index 0000000..cc23ee0
--- /dev/null
+++ b/media-video/obs-studio/obs-studio-23.1.0-r1.ebuild
@@ -0,0 +1,130 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python{3_5,3_6,3_7} )
+
+inherit cmake-utils python-single-r1 xdg-utils
+
+if [[ ${PV} == *9999 ]]; then
+       inherit git-r3
+       EGIT_REPO_URI="https://github.com/obsproject/obs-studio.git"
+       EGIT_SUBMODULES=()
+else
+       SRC_URI="https://github.com/obsproject/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+       KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="Software for Recording and Streaming Live Video Content"
+HOMEPAGE="https://obsproject.com"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="+alsa fdk imagemagick jack luajit nvenc pulseaudio python speex truetype v4l"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+BDEPEND="
+       luajit? ( dev-lang/swig )
+       python? ( dev-lang/swig )
+"
+DEPEND="
+       >=dev-libs/jansson-2.5
+       dev-qt/qtcore:5
+       dev-qt/qtdeclarative:5
+       dev-qt/qtgui:5
+       dev-qt/qtmultimedia:5
+       dev-qt/qtnetwork:5
+       dev-qt/qtquickcontrols:5
+       dev-qt/qtsql:5
+       dev-qt/qtsvg:5
+       dev-qt/qttest:5
+       dev-qt/qtwidgets:5
+       dev-qt/qtx11extras:5
+       media-video/ffmpeg:=[x264]
+       net-misc/curl
+       x11-libs/libXcomposite
+       x11-libs/libXinerama
+       x11-libs/libXrandr
+       alsa? ( media-libs/alsa-lib )
+       fdk? ( media-libs/fdk-aac:= )
+       imagemagick? ( media-gfx/imagemagick:= )
+       jack? ( virtual/jack )
+       luajit? ( dev-lang/luajit:2 )
+       nvenc? (
+               || (
+                       <media-video/ffmpeg-4[nvenc]
+                       >=media-video/ffmpeg-4[video_cards_nvidia]
+               )
+       )
+       pulseaudio? ( media-sound/pulseaudio )
+       python? ( ${PYTHON_DEPS} )
+       speex? ( media-libs/speexdsp )
+       truetype? (
+               media-libs/fontconfig
+               media-libs/freetype
+       )
+       v4l? ( media-libs/libv4l )
+"
+RDEPEND="${DEPEND}"
+
+CMAKE_REMOVE_MODULES_LIST=( FindFreetype )
+
+pkg_setup() {
+       use python && python-single-r1_pkg_setup
+}
+
+src_configure() {
+       local libdir=$(get_libdir)
+       local mycmakeargs=(
+               -DDISABLE_ALSA=$(usex !alsa)
+               -DDISABLE_FREETYPE=$(usex !truetype)
+               -DDISABLE_JACK=$(usex !jack)
+               -DDISABLE_LIBFDK=$(usex !fdk)
+               -DDISABLE_PULSEAUDIO=$(usex !pulseaudio)
+               -DDISABLE_SPEEXDSP=$(usex !speex)
+               -DDISABLE_V4L2=$(usex !v4l)
+               -DLIBOBS_PREFER_IMAGEMAGICK=$(usex imagemagick)
+               -DOBS_MULTIARCH_SUFFIX=${libdir#lib}
+               -DOBS_VERSION_OVERRIDE=${PV}
+               -DUNIX_STRUCTURE=1
+       )
+
+       if use luajit || use python; then
+               mycmakeargs+=(
+                       -DDISABLE_LUA=$(usex !luajit)
+                       -DDISABLE_PYTHON=$(usex !python)
+                       -DENABLE_SCRIPTING=yes
+               )
+       else
+               mycmakeargs+=( -DENABLE_SCRIPTING=no )
+       fi
+
+       cmake-utils_src_configure
+}
+
+pkg_postinst() {
+       xdg_icon_cache_update
+
+       if ! use alsa && ! use pulseaudio; then
+               elog
+               elog "For the audio capture features to be available,"
+               elog "either the 'alsa' or the 'pulseaudio' USE-flag needs to"
+               elog "be enabled."
+               elog
+       fi
+
+       if ! has_version "sys-apps/dbus"; then
+               elog
+               elog "The 'sys-apps/dbus' package is not installed, but"
+               elog "could be used for disabling hibernating, screensaving,"
+               elog "and sleeping.  Where it is not installed,"
+               elog "'xdg-screensaver reset' is used instead"
+               elog "(if 'x11-misc/xdg-utils' is installed)."
+               elog
+       fi
+}
+
+pkg_postrm() {
+       xdg_icon_cache_update
+}

diff --git a/media-video/obs-studio/obs-studio-9999.ebuild b/media-video/obs-studio/obs-studio-9999.ebuild
index 34dfcfd0ddaf92923821d000947d64a5d7cb9655..d86c6eab447525e18bab4a74abb535e8399b4e8a 100644 (file)
--- a/media-video/obs-studio/obs-studio-9999.ebuild
+++ b/media-video/obs-studio/obs-studio-9999.ebuild
@@ -37,6 +37,7 @@ DEPEND="
        dev-qt/qtnetwork:5
        dev-qt/qtquickcontrols:5
        dev-qt/qtsql:5
+       dev-qt/qtsvg:5
        dev-qt/qttest:5
        dev-qt/qtwidgets:5
        dev-qt/qtx11extras:5