media-sound/picoxine: Port to EAPI 7

Bug: https://bugs.gentoo.org/697272
Package-Manager: Portage-2.3.77, Repoman-2.3.17
Signed-off-by: David Seifert <soap@gentoo.org>

diff --git a/media-sound/picoxine/picoxine-0.0.7.ebuild b/media-sound/picoxine/picoxine-0.0.7.ebuild
index 32ccc01af5d95b31e84c689ebb1d9d0be06182d8..e2fc8dac19890bf058053ed6412edb4fd31e77a2 100644 (file)
--- a/media-sound/picoxine/picoxine-0.0.7.ebuild
+++ b/media-sound/picoxine/picoxine-0.0.7.ebuild
@@ -1,9 +1,9 @@
-# Copyright 1999-2018 Gentoo Foundation
+# Copyright 1999-2019 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=0
+EAPI=7
 
-inherit toolchain-funcs
+inherit flag-o-matic toolchain-funcs
 
 DESCRIPTION="Very small xine frontend for playing audio events"
 HOMEPAGE="http://www.kde-apps.org/content/show.php?content=39596"
@@ -12,32 +12,27 @@ SRC_URI="http://www.kde-apps.org/content/files/39596-${P}.tar.bz2"
 LICENSE="GPL-2"
 SLOT="0"
 KEYWORDS="~amd64 ~ppc ~x86"
-IUSE=""
 
-RDEPEND="media-libs/xine-lib"
-DEPEND="${RDEPEND}
-       virtual/pkgconfig"
+RDEPEND="media-libs/xine-lib:="
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
 
-src_unpack() {
-       unpack ${A}
-       cd "${S}"
-
-       rm -f "${S}/${PN}"
+src_prepare() {
+       default
+       rm -f ${PN} INSTALL || die
 }
 
-doecho() {
-       echo "$@"
-       "$@"
+src_configure() {
+       tc-export CC
+       append-cppflags $($(tc-getPKG_CONFIG) --cflags libxine)
+       export LDLIBS="$($(tc-getPKG_CONFIG) --libs libxine) -lm"
 }
 
 src_compile() {
-       doecho $(tc-getCC) -o ${PN} \
-               ${CFLAGS} $(pkg-config --cflags libxine) ${LDFLAGS} \
-               ${PN}.c -lm $(pkg-config --libs libxine) \
-               || die "build failed"
+       emake ${PN}
 }
 
 src_install() {
        dobin ${PN}
-       dodoc AUTHORS INSTALL
+       einstalldocs
 }