dev-libs/libpeas: bump to 1.22.0

Package-Manager: Portage-2.3.48, Repoman-2.3.10

diff --git a/dev-libs/libpeas/Manifest b/dev-libs/libpeas/Manifest
index 357ea31b9d1b76c7e978cdae66057059c3f093e2..8de0c8b80c11be51bdebafac900cf6d3f6d4207d 100644 (file)
--- a/dev-libs/libpeas/Manifest
+++ b/dev-libs/libpeas/Manifest
@@ -1 +1,2 @@
 DIST libpeas-1.20.0.tar.xz 557872 BLAKE2B c10cd85ff6f15f2124541aba3b437e3216322647e36f93a2202df14aebda7c35896a5f77a40ddcd5a5f0300df11c274334cc3a8dfba3fe2745e0b364cb7eac4c SHA512 b3ddebf65e1a76493b5cd5150f60c13597c90398eea16c002e51d25449a595f7591bd0ccd1214ca3a8cbce724eb10f38a316e8c95092442034c048bc95cfdbf4
+DIST libpeas-1.22.0.tar.xz 561332 BLAKE2B 219918f8663cd60c9353f477ef905ce0d1e21bf5b7c09661c4cb3c8adbba3af9f5e93b9de8a1b098dab09b1f4071854a871c8ea1db878bda8fe9e51aa45e5f87 SHA512 9c1da1d4b5688c0f4d0647f3519dbfbed94c8921091057aaef0e41bf5ed3f8faf04a49ce9e4eea3fd7bf4ac4dfa1727d76a5f6dae2a4f52228d4c8c74b420c91

diff --git a/dev-libs/libpeas/libpeas-1.22.0.ebuild b/dev-libs/libpeas/libpeas-1.22.0.ebuild
new file mode 100644 (file)
index 0000000..8d8c434
--- /dev/null
+++ b/dev-libs/libpeas/libpeas-1.22.0.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+GNOME2_LA_PUNT="yes"
+PYTHON_COMPAT=( python{3_4,3_5,3_6,3_7} )
+
+inherit autotools eutils gnome2 multilib python-single-r1 virtualx
+
+DESCRIPTION="A GObject plugins library"
+HOMEPAGE="https://developer.gnome.org/libpeas/stable/"
+
+LICENSE="LGPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd ~amd64-linux ~x86-linux"
+
+IUSE="+gtk glade lua luajit +python"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="
+       >=dev-libs/glib-2.38:2
+       >=dev-libs/gobject-introspection-1.39:=
+       glade? ( >=dev-util/glade-3.9.1:3.10 )
+       gtk? ( >=x11-libs/gtk+-3:3[introspection] )
+       lua? (
+               >=dev-lua/lgi-0.9.0
+               luajit? ( >=dev-lang/luajit-2:2 )
+               !luajit? ( =dev-lang/lua-5.1*:0 ) )
+       python? (
+               ${PYTHON_DEPS}
+               >=dev-python/pygobject-3.2:3[${PYTHON_USEDEP}] )
+"
+DEPEND="${RDEPEND}
+       >=dev-util/gtk-doc-am-1.11
+       >=dev-util/intltool-0.40
+       virtual/pkgconfig
+
+       dev-libs/gobject-introspection-common
+       gnome-base/gnome-common
+"
+# eautoreconf needs gobject-introspection-common, gnome-common
+
+pkg_setup() {
+       use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+       # Gentoo uses unversioned lua - lua.pc instad of lua5.1.pc, /usr/bin/lua instead of /usr/bin/lua5.1
+       eapply "${FILESDIR}"/${PN}-1.14.0-lua.pc.patch
+       eautoreconf
+       gnome2_src_prepare
+}
+
+src_configure() {
+       # Wtf, --disable-gcov, --enable-gcov=no, --enable-gcov, all enable gcov
+       # What do we do about gdb, valgrind, gcov, etc?
+       local myconf=(
+               $(use_enable glade glade-catalog)
+               $(use_enable gtk)
+               --disable-static
+
+               # py2 not supported anymore
+               --disable-python2
+               $(use_enable python python3)
+
+               # lua
+               $(use_enable lua lua5.1)
+               $(use_enable $(usex luajit lua luajit) luajit)
+       )
+
+       gnome2_src_configure "${myconf[@]}"
+}
+
+src_test() {
+       # This looks fixed since 1.18.0:
+       #
+       # FIXME: Tests fail because of some bug involving Xvfb and Gtk.IconTheme
+       # DO NOT REPORT UPSTREAM, this is not a libpeas bug.
+       # To reproduce:
+       # >>> from gi.repository import Gtk
+       # >>> Gtk.IconTheme.get_default().has_icon("gtk-about")
+       # This should return True, it returns False for Xvfb
+       virtx emake check
+}