dev-python/libcloud-2.8.2: Version bump, add py37, py38 (bug #719044)

Closes: https://bugs.gentoo.org/719044
Copyright: Sony Interactive Entertainment Inc.
Package-Manager: Portage-2.3.99, Repoman-2.3.22
Signed-off-by: Patrick McLean <chutzpah@gentoo.org>

diff --git a/dev-python/libcloud/Manifest b/dev-python/libcloud/Manifest
index 40018b9779f687ef4a7b23a493c622faa6db6a8d..d3c6b61c949b5f07a29355783ec25d09f22cb581 100644 (file)
--- a/dev-python/libcloud/Manifest
+++ b/dev-python/libcloud/Manifest
@@ -1 +1,2 @@
 DIST apache-libcloud-2.3.0.tar.bz2 1370556 BLAKE2B 14c6604d190d63f9049de2034b487cd7bb314add399339cac7a46dcbfea339497ede0d8058fd29dab43d53a45637fc5e60c71a5079fff6f45ed5023721eb68f2 SHA512 673c5b7b12f4510f2b43ea8199fab1e3f7ded62423d7d67301f5e3448c78750bc898c494a33d033844acf94bc292582371e9ac02ce1db6f4443a3966ef9fd0e8
+DIST apache-libcloud-2.8.2.tar.bz2 1559425 BLAKE2B 86baff68dae874ee9569646ac24831858784d8323dcbff5036ed0f26afdd47d859b68592d74084844f4b7d232c25f7a99d84fddbfcba54df6939f426203e59ff SHA512 9834cd54df11a27876bdc70c85e7d9e3063cd2639d9f19ccd17ec7841fc0e8db6fbc2d562320656a7db4edbe5a940e8562c929a21203757fabe78a4b48d89367

diff --git a/dev-python/libcloud/libcloud-2.8.2.ebuild b/dev-python/libcloud/libcloud-2.8.2.ebuild
new file mode 100644 (file)
index 0000000..b8b53b8
--- /dev/null
+++ b/dev-python/libcloud/libcloud-2.8.2.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+PYTHON_REQ_USE="ssl(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="Unified Interface to the Cloud - python support libs"
+HOMEPAGE="https://libcloud.apache.org/"
+SRC_URI="mirror://apache/${PN}/apache-${P}.tar.bz2"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="examples test"
+
+RDEPEND="
+       >=dev-python/requests-2.5.0[${PYTHON_USEDEP}]
+
+"
+BDEPEND="${RDEPEND}
+       test? (
+               dev-python/lockfile[${PYTHON_USEDEP}]
+               dev-python/requests-mock[${PYTHON_USEDEP}]
+               >=dev-python/cryptography-2.6.1[${PYTHON_USEDEP}]
+       )"
+
+S="${WORKDIR}/apache-${P}"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+       if use examples; then
+               mkdir examples || die
+               mv example_*.py examples || die
+       fi
+
+       # needed for tests
+       cp libcloud/test/secrets.py-dist libcloud/test/secrets.py || die
+
+       distutils-r1_python_prepare_all
+}
+
+python_install_all() {
+       use examples && dodoc -r examples
+       distutils-r1_python_install_all
+}