media-libs/libtgvoip: bump to new snapshot

Package-Manager: Portage-2.3.99, Repoman-2.3.22
Signed-off-by: Georgy Yakovlev <gyakovlev@gentoo.org>

diff --git a/media-libs/libtgvoip/Manifest b/media-libs/libtgvoip/Manifest
index 4f515fcc4c25473aeb194ced943dc6741ba1ffd7..15b115f37c17e8aa87bc96d0661945a5c4ae4174 100644 (file)
--- a/media-libs/libtgvoip/Manifest
+++ b/media-libs/libtgvoip/Manifest
@@ -1 +1,2 @@
 DIST libtgvoip-2.4.4_p20200301.tar.gz 1481876 BLAKE2B cb589eb5c1aacae92f2a6701fed727807f0527320276cd440754052469bae99d613ba3eb5f5166c169d9d0ee7eb77913e98b196f2269bb0a234bee8eed251ab1 SHA512 8d7e540e62447cfaf3e0ef98a2c3c0e9e16019299abd9e384f488d3f34b7efb750c3174175c287c2b520ebec649df55055bfca9736617c6adc33709c25a0cf0f
+DIST libtgvoip-2.4.4_p20200430.tar.gz 1481816 BLAKE2B 82bf6b880f28c9b63f547e473547298e25ea3b7e35b3a832a7375b0ae3a745ea3b5d55f5e635ec678e388a608532a14de85f50828da1dbc9ed77dc23be64b9e0 SHA512 f3130c50dfa7d3f710809bb72fb71d1b246bc91e9f8f413e704499011c8ff01f87a7226315f7cfd6edf2d2b8b6c875508185f516792ff5db74556aface33cdb4

diff --git a/media-libs/libtgvoip/libtgvoip-2.4.4_p20200430.ebuild b/media-libs/libtgvoip/libtgvoip-2.4.4_p20200430.ebuild
new file mode 100644 (file)
index 0000000..7d02572
--- /dev/null
+++ b/media-libs/libtgvoip/libtgvoip-2.4.4_p20200430.ebuild
@@ -0,0 +1,52 @@
+# Copyright 2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools
+
+EGIT_COMMIT="a045c9eea47b371c0c514c72c76172a211c894cb"
+
+DESCRIPTION="VoIP library for Telegram clients"
+HOMEPAGE="https://github.com/telegramdesktop/libtgvoip"
+SRC_URI="https://github.com/telegramdesktop/libtgvoip/archive/${EGIT_COMMIT}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Unlicense"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc64"
+IUSE="+alsa +dsp libressl pulseaudio"
+
+DEPEND="
+       !libressl? ( dev-libs/openssl:0= )
+       libressl? ( dev-libs/libressl:0= )
+       media-libs/opus:=
+       alsa? ( media-libs/alsa-lib )
+       pulseaudio? ( media-sound/pulseaudio )
+"
+RDEPEND="${DEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+REQUIRED_USE="|| ( alsa pulseaudio )"
+
+S="${WORKDIR}/${PN}-${EGIT_COMMIT}"
+
+src_prepare() {
+       default
+       eautoreconf
+}
+
+src_configure() {
+       local myconf=(
+               --disable-static
+               $(use_enable dsp)
+               $(use_with alsa)
+               $(use_with pulseaudio pulse)
+       )
+
+       econf "${myconf[@]}"
+}
+
+src_install() {
+       default
+       find "${D}" -name '*.la' -delete || die
+}