net-libs/nDPI: Add live ebuild

Package-Manager: Portage-2.3.89, Repoman-2.3.20
Signed-off-by: Jeroen Roovers <jer@gentoo.org>

diff --git a/net-libs/nDPI/nDPI-9999.ebuild b/net-libs/nDPI/nDPI-9999.ebuild
new file mode 100644 (file)
index 0000000..6e8aa67
--- /dev/null
+++ b/net-libs/nDPI/nDPI-9999.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit autotools git-r3 multilib
+
+DESCRIPTION="Open Source Deep Packet Inspection Software Toolkit"
+HOMEPAGE="https://www.ntop.org/"
+EGIT_REPO_URI="https://github.com/ntop/${PN}"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS=""
+IUSE="static-libs"
+
+DEPEND="
+       dev-libs/json-c:=
+       net-libs/libpcap
+"
+RDEPEND="
+       ${DEPEND}
+"
+
+src_prepare() {
+       eval $(grep '^NDPI_MAJOR=' autogen.sh)
+       eval $(grep '^NDPI_MINOR=' autogen.sh)
+       eval $(grep '^NDPI_PATCH=' autogen.sh)
+       NDPI_VERSION_SHORT="${NDPI_MAJOR}.${NDPI_MINOR}.${NDPI_PATCH}"
+
+       sed \
+               -e "s/@NDPI_MAJOR@/${NDPI_MAJOR}/g" \
+               -e "s/@NDPI_MINOR@/${NDPI_MINOR}/g" \
+               -e "s/@NDPI_PATCH@/${NDPI_PATCH}/g" \
+               -e "s/@NDPI_VERSION_SHORT@/${NDPI_VERSION_SHORT}/g" \
+               < "${S}/configure.seed" \
+               > "${S}/configure.ac" || die
+
+       sed -i \
+               -e "s%^libdir\s*=\s*\${prefix}/lib\s*$%libdir     = \${prefix}/$(get_libdir)%" \
+               src/lib/Makefile.in || die
+
+       default
+       eautoreconf
+
+       # Taken from autogen.sh (bug #704074):
+       sed -i \
+               -e "s/#define PACKAGE/#define NDPI_PACKAGE/g" \
+               -e "s/#define VERSION/#define NDPI_VERSION/g" \
+               configure || die
+}
+
+src_install() {
+       default
+       if ! use static-libs; then
+               rm "${D}"/usr/$(get_libdir)/lib${PN,,}.a || die
+       fi
+}