app-misc/pax-utils: bump up to 1.2.4

Two main fixes since main release:
- Python 3.7 support
- better fakeroot cooperation on powerpc and others

Bug: https://bugs.gentoo.org/671522
Bug: https://bugs.gentoo.org/675378
Package-Manager: Portage-2.3.55, Repoman-2.3.12
Signed-off-by: Sergei Trofimovich <slyfox@gentoo.org>

diff --git a/app-misc/pax-utils/Manifest b/app-misc/pax-utils/Manifest
index 1db68d4cb315827448a4a9517e5db8b3e290be50..84ce7bf2896873d5efacff723df8f769367c4aa3 100644 (file)
--- a/app-misc/pax-utils/Manifest
+++ b/app-misc/pax-utils/Manifest
@@ -1 +1,2 @@
 DIST pax-utils-1.2.3.tar.xz 661828 BLAKE2B 4764c47b7a31e7470a454127b9db3b5b27c703a96a66973a6248529a2d858ea38adb246a270a1f343a499515f55b25613bb20c46978e2e0dddc03e5ddb9a2aa7 SHA512 efcbce49aa7e5cd433f9b3fbc8fa82f6d7b0eb80ec40aafde453d6fe96e3565e066e5020f04d71537d8d4e820147f4203c0df2dd330ebb1358a26def3dd5484c
+DIST pax-utils-1.2.4.tar.xz 665648 BLAKE2B f0003f912e42a25c8b587764591f7c466aa4c7a24f38fe101d7b64ea5abca5511b2f9329fa5620d1b4ae1926c2272eb97d4ada0210d4e55d16c7766a055672f4 SHA512 03b84054c59e8ce64d2c07276c61245c8e9b3eca2fc430269531e2dafe120009b541ebb6adc4ff54c13a1da63caf0755fb026ba272cf17d04f75e06b893a3e95

diff --git a/app-misc/pax-utils/pax-utils-1.2.4.ebuild b/app-misc/pax-utils/pax-utils-1.2.4.ebuild
new file mode 100644 (file)
index 0000000..92c0806
--- /dev/null
+++ b/app-misc/pax-utils/pax-utils-1.2.4.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} )
+
+inherit eutils python-single-r1 toolchain-funcs unpacker
+
+DESCRIPTION="ELF utils that can check files for security relevant properties"
+HOMEPAGE="https://wiki.gentoo.org/index.php?title=Project:Hardened/PaX_Utilities"
+SRC_URI="mirror://gentoo/${P}.tar.xz
+       https://dev.gentoo.org/~slyfox/distfiles/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="caps debug python seccomp"
+
+RDEPEND="caps? ( >=sys-libs/libcap-2.24 )
+       python? (
+               ${PYTHON_DEPS}
+               dev-python/pyelftools[${PYTHON_USEDEP}]
+               )
+       seccomp? ( sys-libs/libseccomp )"
+DEPEND="${RDEPEND}
+       caps? ( virtual/pkgconfig )
+       seccomp? ( virtual/pkgconfig )
+       app-arch/xz-utils"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+_emake() {
+       emake \
+               USE_CAP=$(usex caps) \
+               USE_DEBUG=$(usex debug) \
+               USE_PYTHON=$(usex python) \
+               USE_SECCOMP=$(usex seccomp) \
+               "$@"
+}
+
+pkg_setup() {
+       if use python; then
+               python-single-r1_pkg_setup
+       fi
+}
+
+src_configure() {
+       # Avoid slow configure+gnulib+make if on an up-to-date Linux system
+       if use prefix || ! use kernel_linux ||
+               has_version '<sys-libs/glibc-2.10'
+       then
+               econf $(use_with caps) $(use_with debug) $(use_with python) $(use_with seccomp)
+       else
+               tc-export CC PKG_CONFIG
+       fi
+}
+
+src_compile() {
+       _emake
+}
+
+src_test() {
+       _emake check
+}
+
+src_install() {
+       _emake DESTDIR="${D}" PKGDOCDIR='$(DOCDIR)'/${PF} install
+
+       use python && python_fix_shebang "${ED}"/usr/bin/lddtree
+}