media-libs/sdl2-image: Bump to version 2.0.5

Package-Manager: Portage-2.3.68, Repoman-2.3.16
Signed-off-by: Lars Wendler <polynomial-c@gentoo.org>

diff --git a/media-libs/sdl2-image/Manifest b/media-libs/sdl2-image/Manifest
index 1f3815bde4fc71b328f543bbd598a6af1e3d09ad..0f4de5bea6a99d1799728ecde53a08afcf2a3e9f 100644 (file)
--- a/media-libs/sdl2-image/Manifest
+++ b/media-libs/sdl2-image/Manifest
@@ -1 +1,2 @@
 DIST SDL2_image-2.0.4.tar.gz 11682695 BLAKE2B 5e2a456d770ab2b6b82d5573d9e6eed874b2b65fe3225287aef853b27f79251db4dae155721018c69f30e272d9cdd4a4f97db30ca93f63bc08e270019888edb6 SHA512 7320a5c9111908d402fbb0c12a49eb359a6db645c0c86839793ebb1a5b75eaca7c85eb96851f3a0b4a68a2f06363c8189555afd4f1048a4a41447370eddd7e6a
+DIST SDL2_image-2.0.5.tar.gz 11736518 BLAKE2B 8009fc4ff76d8f8f4093c02304329218e1d8b7d6fd9c747387f239bc6ee09133f8f3faee0005267ce29c083a6bf4ddcf8db72f502ea047f7288ec57ebbb16380 SHA512 77e743d3f32707e015b290c1379ae3c7d7a3fe265995713267f0d0ec6517de4808f0de9890b5ab28445941af5bc9fbff346620629e0d7d7e9f365262cab05ee7

diff --git a/media-libs/sdl2-image/sdl2-image-2.0.5.ebuild b/media-libs/sdl2-image/sdl2-image-2.0.5.ebuild
new file mode 100644 (file)
index 0000000..7563b0a
--- /dev/null
+++ b/media-libs/sdl2-image/sdl2-image-2.0.5.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit multilib multilib-minimal
+
+MY_P="SDL2_image-${PV}"
+DESCRIPTION="Image file loading library"
+HOMEPAGE="http://www.libsdl.org/projects/SDL_image/"
+SRC_URI="http://www.libsdl.org/projects/SDL_image/release/${MY_P}.tar.gz"
+
+LICENSE="ZLIB"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="gif jpeg png static-libs tiff webp"
+
+RDEPEND="
+       >=media-libs/libsdl2-2.0.9[${MULTILIB_USEDEP}]
+       >=sys-libs/zlib-1.2.8-r1[${MULTILIB_USEDEP}]
+       png? ( >=media-libs/libpng-1.6.10:0[${MULTILIB_USEDEP}] )
+       jpeg? ( >=virtual/jpeg-0-r2:0[${MULTILIB_USEDEP}] )
+       tiff? ( >=media-libs/tiff-3.9.7-r1:0[${MULTILIB_USEDEP}] )
+       webp? ( >=media-libs/libwebp-0.3.0[${MULTILIB_USEDEP}] )"
+DEPEND=${RDEPEND}
+
+S="${WORKDIR}/${MY_P}"
+
+multilib_src_configure() {
+       local myeconfargs=(
+               $(use_enable static-libs static)
+               --disable-sdltest
+               --enable-bmp
+               $(use_enable gif)
+               $(use_enable jpeg jpg)
+               --disable-jpg-shared
+               --enable-lbm
+               --enable-pcx
+               $(use_enable png)
+               --disable-png-shared
+               --enable-pnm
+               --enable-tga
+               $(use_enable tiff tif)
+               --disable-tif-shared
+               --enable-xcf
+               --enable-xpm
+               --enable-xv
+               $(use_enable webp)
+               --disable-webp-shared
+       )
+       ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
+}
+
+multilib_src_install() {
+       emake DESTDIR="${D}" install
+       multilib_is_native_abi && newbin .libs/showimage$(get_exeext) showimage2$(get_exeext)
+}
+
+multilib_src_install_all() {
+       dodoc {CHANGES,README}.txt
+       find "${ED}" -type f -name "*.la" -delete || die
+}