sys-apps/moreutils: try to make sure $EDITOR is valid for vipe

bug #604630

diff --git a/sys-apps/moreutils/moreutils-0.60-r1.ebuild b/sys-apps/moreutils/moreutils-0.60-r1.ebuild
new file mode 100644 (file)
index 0000000..130cf81
--- /dev/null
+++ b/sys-apps/moreutils/moreutils-0.60-r1.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+inherit toolchain-funcs
+
+DESCRIPTION="a collection of tools that nobody thought to write when Unix was young"
+HOMEPAGE="http://joeyh.name/code/moreutils/"
+#SRC_URI="mirror://debian/pool/main/${PN:0:1}/${PN}/${PN}_${PV}.orig.tar.gz"
+SRC_URI="https://dev.gentoo.org/~radhermit/dist/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~hppa ~ppc ~ppc64 ~x86 ~x86-linux"
+IUSE="+doc +perl"
+
+RDEPEND="
+       perl? (
+               dev-lang/perl
+               dev-perl/IPC-Run
+               dev-perl/Time-Duration
+               dev-perl/TimeDate
+       )"
+DEPEND="
+       app-admin/eselect
+       doc? (
+               dev-lang/perl
+               >=app-text/docbook2X-0.8.8-r2
+               app-text/docbook-xml-dtd:4.4
+       )"
+
+src_prepare() {
+       # don't build manpages
+       if ! use doc ; then
+               sed -i -e '/^all:/s/$(MANS)//' -e '/man1/d' Makefile || die
+       fi
+
+       # don't install perl scripts
+       if ! use perl ; then
+               sed -i -e '/PERLSCRIPTS/d' Makefile || die
+       fi
+
+       default
+}
+
+src_compile() {
+       tc-export CC
+       emake CFLAGS="${CFLAGS}" DOCBOOK2XMAN=docbook2man.pl PREFIX="${EPREFIX}/usr"
+}
+
+src_install() {
+       emake DESTDIR="${D}" PREFIX="${EPREFIX}/usr" INSTALL_BIN=install install
+
+       # sys-process is more advanced than parallel from moreutils, rename it
+       if use doc; then
+               mv "${ED}"usr/share/man/man1/{,${PN}_}parallel.1 || die
+       fi
+       mv "${ED}"usr/bin/{,${PN}_}parallel || die
+}
+
+pkg_postinst() {
+       # try to make sure $EDITOR is valid for vipe (bug #604630)
+       eselect editor update
+}