dev-util/conan: update to 1.19.2 (#696404)

Enabling tests (#692036)

Closes: https://bugs.gentoo.org/692036
Closes: https://bugs.gentoo.org/696404
Signed-off-by: Azamat H. Hackimov <azamat.hackimov@gmail.com>
Package-Manager: Portage-2.3.76, Repoman-2.3.16
Closes: https://github.com/gentoo/gentoo/pull/13422
Signed-off-by: Joonas Niilola <juippis@gentoo.org>

diff --git a/dev-util/conan/Manifest b/dev-util/conan/Manifest
index 17606e3fa3f46e549ba51e567c5de9c3f6dcf2dd..1c9cdc17e7562bf1edee0e899d5d54cf23c539a8 100644 (file)
--- a/dev-util/conan/Manifest
+++ b/dev-util/conan/Manifest
@@ -1 +1,2 @@
 DIST conan-1.18.1.tar.gz 532813 BLAKE2B d4c8ec62100b8c4038f9bef8338aa0afccc38ab39d8d953c41934efc43d6ba8e5abda1438e3f8c3f4bba4b770b871a1afc5ef19749771a55873b35f28a427b1b SHA512 f9c4c4cb768c3f015a84adb3d4926cf91a372a8dae6655df9396b645c24c8694f47795064c0e93ee799864d19f6f77983da0a1679ad511d8f11702250ae95124
+DIST conan-1.19.2.tar.gz 944360 BLAKE2B 190cc2a7dbe25420ae1a6b46705078301cdf1deea2b4be3d1244ade84d27250688e2c26cd5d172d4dab68557d758a2afcfebf37c323e42f0b4514455488903d8 SHA512 e9b868561465bda28314813d4114cb2b6b97440f7683c4c91911ed51b8cb06675b37807c28aaed62d5f7b470ce9040929ad61e0e148c04b0fdba7300cb633b5d

diff --git a/dev-util/conan/conan-1.19.2.ebuild b/dev-util/conan/conan-1.19.2.ebuild
new file mode 100644 (file)
index 0000000..d635417
--- /dev/null
+++ b/dev-util/conan/conan-1.19.2.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{5,6} )
+PYTHON_REQ_USE="sqlite"
+
+inherit distutils-r1
+
+DESCRIPTION="Distributed C/C++ package manager"
+HOMEPAGE="https://conan.io/"
+SRC_URI="https://github.com/conan-io/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="test"
+
+# overly strict requirements?
+# https://github.com/conan-io/conan/blob/develop/conans/requirements.txt
+# https://github.com/conan-io/conan/blob/develop/conans/requirements_server.txt
+RDEPEND="
+       >=dev-python/astroid-1.6.5[${PYTHON_USEDEP}]
+       >=dev-python/bottle-0.12.8[${PYTHON_USEDEP}]
+       >=dev-python/colorama-0.3.3[${PYTHON_USEDEP}]
+       >=dev-python/deprecation-2.0[${PYTHON_USEDEP}]
+       >=dev-python/distro-1.0.2[${PYTHON_USEDEP}]
+       >=dev-python/fasteners-0.14.1[${PYTHON_USEDEP}]
+       >=dev-python/future-0.16.0[${PYTHON_USEDEP}]
+       >=dev-python/jinja-2.10.1[${PYTHON_USEDEP}]
+       >=dev-python/node-semver-0.6.1[${PYTHON_USEDEP}]
+       >=dev-python/patch-1.16[${PYTHON_USEDEP}]
+       >=dev-python/pluginbase-0.5[${PYTHON_USEDEP}]
+       >=dev-python/pygments-2.0[${PYTHON_USEDEP}]
+       >=dev-python/pyjwt-1.4[${PYTHON_USEDEP}]
+       >=dev-python/pylint-2.3.1[${PYTHON_USEDEP}]
+       >=dev-python/python-dateutil-2.7.0[${PYTHON_USEDEP}]
+       >=dev-python/pyyaml-5.1[${PYTHON_USEDEP}]
+       >=dev-python/requests-2.8.1[${PYTHON_USEDEP}]
+       >=dev-python/six-1.10[${PYTHON_USEDEP}]
+       >=dev-python/tqdm-4.28.1[${PYTHON_USEDEP}]
+       >=dev-python/typed-ast-1.1.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+       test? (
+               dev-lang/go
+               >=dev-python/mock-1.3.0[${PYTHON_USEDEP}]
+               >=dev-python/nose-1.3.7[${PYTHON_USEDEP}]
+               >=dev-python/parameterized-0.6.3[${PYTHON_USEDEP}]
+               >=dev-python/webtest-2.0.18[${PYTHON_USEDEP}]
+               dev-util/cmake
+       )
+"
+
+src_prepare() {
+       default
+       # Fix strict dependencies
+       sed -i \
+               -e "s:patch==1.16:patch>=1.16:g" \
+               -e "s:node-semver==0.6.1:node-semver>=0.6.1:g" \
+               -e "s:future==0.16.0:future>=0.16.0:g" \
+               conans/requirements.txt || die
+}
+
+python_test() {
+       nosetests -v conans.test \
+               -e test_ftp.* -e modify_values_test.* -e test_pkg_config_path.* \
+               -e rpath_optin_test -e test_variables -e system_package_tool_installed_test \
+               -e virtualbuildenv_test -e scm_test -e test_git_shallow -e tools_test \
+               -e test_environment_nested -e devflow_test -e shared_chain_test \
+               -A "not rest_api and not local_bottle" || die
+}