x11-terms/kitty: update to EAPI 7 and fix BDEPEND

Signed-off-by: Tim Harder <radhermit@gentoo.org>

diff --git a/x11-terms/kitty/kitty-0.14.6-r1.ebuild b/x11-terms/kitty/kitty-0.14.6-r1.ebuild
new file mode 100644 (file)
index 0000000..8fa3a58
--- /dev/null
+++ b/x11-terms/kitty/kitty-0.14.6-r1.ebuild
@@ -0,0 +1,108 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6,7} )
+
+inherit python-single-r1 toolchain-funcs xdg
+
+if [[ ${PV} == "9999" ]] ; then
+       EGIT_REPO_URI="https://github.com/kovidgoyal/kitty.git"
+       inherit git-r3
+else
+       SRC_URI="https://github.com/kovidgoyal/kitty/releases/download/v${PV}/${P}.tar.xz"
+       KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="A modern, hackable, featureful, OpenGL-based terminal emulator"
+HOMEPAGE="https://github.com/kovidgoyal/kitty"
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="debug doc imagemagick wayland"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+COMMON_DEPS="
+       ${PYTHON_DEPS}
+       >=media-libs/harfbuzz-1.5.0:=
+       sys-apps/dbus
+       sys-libs/zlib
+       media-libs/libcanberra
+       media-libs/libpng:0=
+       media-libs/freetype:2
+       media-libs/fontconfig
+       x11-libs/libXcursor
+       x11-libs/libXrandr
+       x11-libs/libXi
+       x11-libs/libXinerama
+       x11-libs/libxkbcommon[X]
+       x11-libs/libxcb[xkb]
+       wayland? (
+               dev-libs/wayland
+               >=dev-libs/wayland-protocols-1.17
+       )
+"
+RDEPEND="
+       ${COMMON_DEPS}
+       imagemagick? ( virtual/imagemagick-tools )
+"
+DEPEND="${RDEPEND}
+       media-libs/mesa[X(+)]
+       sys-libs/ncurses
+"
+[[ ${PV} == *9999 ]] && DEPEND+=" >=dev-python/sphinx-1.7[${PYTHON_USEDEP}]"
+BDEPEND="virtual/pkgconfig"
+
+PATCHES=(
+       "${FILESDIR}"/${PN}-0.14.4-flags.patch
+       "${FILESDIR}"/${PN}-0.14.4-svg-icon.patch
+)
+
+src_prepare() {
+       default
+
+       # disable wayland as required
+       if ! use wayland; then
+               sed -i "/'x11 wayland'/s/ wayland//" setup.py || die
+       fi
+
+       # respect doc dir
+       sed -i "/htmldir =/s/appname/'${PF}'/" setup.py
+
+       tc-export CC
+}
+
+doecho() {
+       echo "$@"
+       "$@" || die
+}
+
+src_compile() {
+       doecho "${EPYTHON}" setup.py \
+               --verbose $(usex debug --debug "") \
+               --libdir-name $(get_libdir) \
+               linux-package
+}
+
+src_test() {
+       export KITTY_CONFIG_DIRECTORY=${T}
+       "${EPYTHON}" test.py || die
+}
+
+src_install() {
+       mkdir -p "${ED}"/usr || die
+       cp -r linux-package/* "${ED}/usr" || die
+       python_fix_shebang "${ED}"
+
+       if ! use doc; then
+               rm -r "${ED}"/usr/share/doc || die
+       fi
+}
+
+pkg_postinst() {
+       xdg_icon_cache_update
+}
+
+pkg_postrm() {
+       xdg_icon_cache_update
+}

diff --git a/x11-terms/kitty/kitty-9999.ebuild b/x11-terms/kitty/kitty-9999.ebuild
index c51e3ffd52d4e3771b51272a016b37f60ae275f9..1d1a09c24c6bb3e5238c0968e2dd3fef27e047a7 100644 (file)
--- a/x11-terms/kitty/kitty-9999.ebuild
+++ b/x11-terms/kitty/kitty-9999.ebuild
@@ -1,10 +1,10 @@
 # Copyright 1999-2019 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=6
+EAPI=7
 PYTHON_COMPAT=( python3_{6,7} )
 
-inherit python-single-r1 toolchain-funcs gnome2-utils
+inherit python-single-r1 toolchain-funcs xdg
 
 if [[ ${PV} == "9999" ]] ; then
        EGIT_REPO_URI="https://github.com/kovidgoyal/kitty.git"
@@ -49,9 +49,9 @@ RDEPEND="
 DEPEND="${RDEPEND}
        media-libs/mesa[X(+)]
        sys-libs/ncurses
-       virtual/pkgconfig
 "
 [[ ${PV} == *9999 ]] && DEPEND+=" >=dev-python/sphinx-1.7[${PYTHON_USEDEP}]"
+BDEPEND="virtual/pkgconfig"
 
 PATCHES=(
        "${FILESDIR}"/${P}-flags.patch
@@ -90,8 +90,8 @@ src_test() {
 }
 
 src_install() {
-       mkdir -p "${ED}"usr || die
-       cp -r linux-package/* "${ED}usr" || die
+       mkdir -p "${ED}"/usr || die
+       cp -r linux-package/* "${ED}/usr" || die
        python_fix_shebang "${ED}"
 
        if ! use doc; then
@@ -100,9 +100,9 @@ src_install() {
 }
 
 pkg_postinst() {
-       gnome2_icon_cache_update
+       xdg_icon_cache_update
 }
 
 pkg_postrm() {
-       gnome2_icon_cache_update
+       xdg_icon_cache_update
 }