media-libs/libtgvoip: bump to new snapshot

patch merged upstream

Package-Manager: Portage-2.3.94, Repoman-2.3.21
Signed-off-by: Georgy Yakovlev <gyakovlev@gentoo.org>

diff --git a/media-libs/libtgvoip/Manifest b/media-libs/libtgvoip/Manifest
index fc9a3576968a3a9cadfcb37ee3ae8ee6b6bbcffe..8511833b5355dbef601bf36e4bbc774a7015c29a 100644 (file)
--- a/media-libs/libtgvoip/Manifest
+++ b/media-libs/libtgvoip/Manifest
@@ -1 +1,2 @@
 DIST libtgvoip-2.4.4_p20200212.tar.gz 1481831 BLAKE2B 5c6b4ecee4d8daf31f52db1070431cb6caee324d58a20207405ebcd2b275a07c57fa524f3f29e8aaa05e50451730d34ad47bb94a180e3ac8a169dac9979582be SHA512 5da722244d66d3793439e0d3132046f1bb7fa8a56941bcac7779e3779f0c8f517fb5a8f3af546e31d16d4f8deedb9bf7a2d694194fef76bbce233bf1ed6579c3
+DIST libtgvoip-2.4.4_p20200301.tar.gz 1481876 BLAKE2B cb589eb5c1aacae92f2a6701fed727807f0527320276cd440754052469bae99d613ba3eb5f5166c169d9d0ee7eb77913e98b196f2269bb0a234bee8eed251ab1 SHA512 8d7e540e62447cfaf3e0ef98a2c3c0e9e16019299abd9e384f488d3f34b7efb750c3174175c287c2b520ebec649df55055bfca9736617c6adc33709c25a0cf0f

diff --git a/media-libs/libtgvoip/libtgvoip-2.4.4_p20200301.ebuild b/media-libs/libtgvoip/libtgvoip-2.4.4_p20200301.ebuild
new file mode 100644 (file)
index 0000000..006e682
--- /dev/null
+++ b/media-libs/libtgvoip/libtgvoip-2.4.4_p20200301.ebuild
@@ -0,0 +1,52 @@
+# Copyright 2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools
+
+EGIT_COMMIT="e422d2a80546a32ab7166a9b1058bacfc5daeefc"
+
+DESCRIPTION="VoIP library for Telegram clients"
+HOMEPAGE="https://github.com/telegramdesktop/libtgvoip"
+SRC_URI="https://github.com/telegramdesktop/libtgvoip/archive/${EGIT_COMMIT}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Unlicense"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc64"
+IUSE="+alsa +dsp libressl pulseaudio"
+
+DEPEND="
+       !libressl? ( dev-libs/openssl:0= )
+       libressl? ( dev-libs/libressl:0= )
+       media-libs/opus:=
+       alsa? ( media-libs/alsa-lib )
+       pulseaudio? ( media-sound/pulseaudio )
+"
+RDEPEND="${DEPEND}"
+BDEPEND=""
+
+REQUIRED_USE="|| ( alsa pulseaudio )"
+
+S="${WORKDIR}/${PN}-${EGIT_COMMIT}"
+
+src_prepare() {
+       default
+       eautoreconf
+}
+
+src_configure() {
+       local myconf=(
+               --disable-static
+               $(use_enable dsp)
+               $(use_with alsa)
+               $(use_with pulseaudio pulse)
+       )
+
+       econf "${myconf[@]}"
+}
+
+src_install() {
+       default
+       find "${D}" -name '*.la' -delete || die
+}