gnome-extra/nm-applet: bump to 1.8.24

Closes: https://bugs.gentoo.org/695190
Package-Manager: Portage-2.3.69, Repoman-2.3.12
Signed-off-by: Mart Raudsepp <leio@gentoo.org>

diff --git a/gnome-extra/nm-applet/Manifest b/gnome-extra/nm-applet/Manifest
index 71f58ae741bb9dd02d35485ea104534e93ca28a2..35d9cc5d4cb5af49187a201b81745a56704d4719 100644 (file)
--- a/gnome-extra/nm-applet/Manifest
+++ b/gnome-extra/nm-applet/Manifest
@@ -1 +1,2 @@
 DIST network-manager-applet-1.8.22.tar.xz 2058500 BLAKE2B e4b31ea3dfe91f07a61b7dd4c34521bc4fc2d7a1b7e5649690336cce0c425d57128ff8011b18a6505893982bfd81170eb8239b9e83de6f91afa11190cfac3b4d SHA512 d2f679a67b79b011762f9249798c5a4ccad3d0fdd01d8d45956a65ab75398ccc07167fc5452748a12294315f729b10115edcb9f11e05475bb0b15b2ade638dd3
+DIST network-manager-applet-1.8.24.tar.xz 2062132 BLAKE2B fed75ab78e05b59a4f20c7570b84ac6fe3dd2cf6f8ad060f6c65bc9e2a32e29d295fc919de1037ba30c2609d35079dccb3f625ffc019150c9c69cfa94388e2c8 SHA512 76e914ec4f2e6eadd21ccc3e1f613fb97cb72d9551730a1dc09454177365dcaa2cdeea4b855c53732ad6a22cfa5e62e03f09fc8b04a277ce213dcf8c3beaf77c

diff --git a/gnome-extra/nm-applet/nm-applet-1.8.24.ebuild b/gnome-extra/nm-applet/nm-applet-1.8.24.ebuild
new file mode 100644 (file)
index 0000000..d0eddf1
--- /dev/null
+++ b/gnome-extra/nm-applet/nm-applet-1.8.24.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+GNOME2_LA_PUNT="yes"
+GNOME_ORG_MODULE="network-manager-applet"
+
+inherit gnome2
+
+DESCRIPTION="GNOME applet for NetworkManager"
+HOMEPAGE="https://wiki.gnome.org/Projects/NetworkManager"
+
+LICENSE="GPL-2+"
+SLOT="0"
+IUSE="ayatana +introspection +gcr +modemmanager selinux teamd"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+RDEPEND="
+       >=app-crypt/libsecret-0.18
+       >=dev-libs/glib-2.38:2[dbus]
+       >=dev-libs/dbus-glib-0.88
+       >=sys-apps/dbus-1.4.1
+       >=sys-auth/polkit-0.96-r1
+       >=x11-libs/gtk+-3.10:3[introspection?]
+       >=x11-libs/libnotify-0.7.0
+
+       app-text/iso-codes
+       >=net-misc/networkmanager-1.7:=[introspection?,modemmanager?,teamd?]
+       net-misc/mobile-broadband-provider-info
+
+       ayatana? (
+               dev-libs/libappindicator:3
+               >=dev-libs/libdbusmenu-16.04.0 )
+       introspection? ( >=dev-libs/gobject-introspection-0.9.6:= )
+       virtual/freedesktop-icon-theme
+       virtual/libgudev:=
+       gcr? ( >=app-crypt/gcr-3.14:=[gtk] )
+       modemmanager? ( net-misc/modemmanager )
+       selinux? ( sys-libs/libselinux )
+       teamd? ( >=dev-libs/jansson-2.7 )
+"
+DEPEND="${RDEPEND}
+       >=dev-util/gtk-doc-am-1.0
+       >=sys-devel/gettext-0.18
+       virtual/pkgconfig
+"
+
+PDEPEND="virtual/notification-daemon" #546134
+
+src_configure() {
+       local myconf=(
+               --with-appindicator=$(usex ayatana ubuntu no)
+               --with-libnm-gtk
+               --without-libnma-gtk4
+               --disable-lto
+               --disable-ld-gc
+               --disable-more-warnings
+               --disable-static
+               --localstatedir=/var
+               $(use_enable introspection)
+               $(use_with gcr)
+               $(use_with modemmanager wwan)
+               $(use_with selinux)
+               $(use_with teamd team)
+       )
+       gnome2_src_configure "${myconf[@]}"
+}