dev-vcs/git-lfs: Initial import, bug #548080

Package-Manager: Portage-2.3.3, Repoman-2.3.1

diff --git a/dev-vcs/git-lfs/Manifest b/dev-vcs/git-lfs/Manifest
new file mode 100644 (file)
index 0000000..4cefe23
--- /dev/null
+++ b/dev-vcs/git-lfs/Manifest
@@ -0,0 +1 @@
+DIST git-lfs-1.5.6.tar.gz 604139 SHA256 4efbc806cde1ea6ab4e1d61db3e1f6939796fd53bf6e9c94ac564610147ea5cd SHA512 f5f2da9ac44647335b25cad3104027cf5476e25ef9763019744123f9e1ef81edadbf5b08a146b8070487b32a18aa202c799f910aee6f2f0144ca411ad6d7cfd2 WHIRLPOOL 2f785abffc917a322fe59f4354980d5f565572620569b9b53e85ecdf84b5d7ad407ced8853c897814daa816cac6efd1f85c9098cae9fe48b179cd3381c5f840d

diff --git a/dev-vcs/git-lfs/git-lfs-1.5.6.ebuild b/dev-vcs/git-lfs/git-lfs-1.5.6.ebuild
new file mode 100644 (file)
index 0000000..2893dfb
--- /dev/null
+++ b/dev-vcs/git-lfs/git-lfs-1.5.6.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+EGO_PN="github.com/git-lfs/${PN}"
+
+if [[ ${PV} == *9999 ]]; then
+       inherit golang-vcs
+else
+       SRC_URI="https://${EGO_PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+       KEYWORDS="~amd64"
+       inherit golang-vcs-snapshot
+fi
+
+DESCRIPTION="command line extension and specification for managing large files with Git"
+HOMEPAGE="https://git-lfs.github.com/"
+
+LICENSE="MIT BSD BSD-2 BSD-4 Apache-2.0"
+SLOT="0"
+IUSE="+doc"
+
+DEPEND="doc? ( app-text/ronn )"
+RDEPEND="dev-vcs/git"
+
+S="${WORKDIR}/${P}/src/${EGO_PN}"
+
+src_compile() {
+       # can't use golang-build_src_compile for go generate
+       # and others steps executed by build.go
+       GOPATH="${WORKDIR}/${P}:$(get_golibdir_gopath)" \
+       go run script/*.go -cmd build || die "build failed"
+
+       if use doc; then
+               ronn docs/man/*.ronn || die "man building failed"
+       fi
+}
+
+src_install() {
+       dobin bin/git-lfs
+
+       use doc && doman docs/man/*.1
+}

diff --git a/dev-vcs/git-lfs/metadata.xml b/dev-vcs/git-lfs/metadata.xml
new file mode 100644 (file)
index 0000000..d396d1b
--- /dev/null
+++ b/dev-vcs/git-lfs/metadata.xml
@@ -0,0 +1,8 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+       <maintainer type="person">
+               <email>mudler@gentoo.org</email>
+               <name>Ettore Di Giacinto</name>
+       </maintainer>
+</pkgmetadata>