dev-python/google-auth: 1.14.3-r1 revbump for test deps

Drop ~arm ~arm64 keywords due to the added
dev-python/moto[${PYTHON_USEDEP}] dependency.

Bug: https://bugs.gentoo.org/723554
Bug: https://bugs.gentoo.org/723912
Package-Manager: Portage-2.3.99, Repoman-2.3.22
Signed-off-by: Zac Medico <zmedico@gentoo.org>

diff --git a/dev-python/google-auth/google-auth-1.14.3-r1.ebuild b/dev-python/google-auth/google-auth-1.14.3-r1.ebuild
new file mode 100644 (file)
index 0000000..91fe626
--- /dev/null
+++ b/dev-python/google-auth/google-auth-1.14.3-r1.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+
+inherit distutils-r1
+
+DESCRIPTION="Google Authentication Library"
+HOMEPAGE="https://github.com/GoogleCloudPlatform/google-auth-library-python https://pypi.org/project/google-auth/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+       dev-python/namespace-google[${PYTHON_USEDEP}]
+       >=dev-python/pyasn1-0.1.7[${PYTHON_USEDEP}]
+       >=dev-python/pyasn1-modules-0.2.1[${PYTHON_USEDEP}]
+       >=dev-python/rsa-3.1.4[${PYTHON_USEDEP}]
+       >=dev-python/six-1.9.0[${PYTHON_USEDEP}]
+       >=dev-python/cachetools-2.0.0[${PYTHON_USEDEP}]
+       "
+DEPEND="${RDEPEND}
+       test? (
+               dev-python/cryptography[${PYTHON_USEDEP}]
+               dev-python/flask[${PYTHON_USEDEP}]
+               dev-python/freezegun[${PYTHON_USEDEP}]
+               dev-python/mock[${PYTHON_USEDEP}]
+               dev-python/moto[${PYTHON_USEDEP}]
+               dev-python/pyopenssl[${PYTHON_USEDEP}]
+               dev-python/pytest[${PYTHON_USEDEP}]
+               dev-python/pytest-localserver[${PYTHON_USEDEP}]
+               dev-python/oauth2client[${PYTHON_USEDEP}]
+               dev-python/requests[${PYTHON_USEDEP}]
+       )"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+       # delete stray files included in the tarball
+       find "${S}"/tests -name '*.pyc' -delete || die
+       distutils-r1_src_prepare
+}
+
+python_install_all() {
+       distutils-r1_python_install_all
+       find "${ED}" -name '*.pth' -delete || die
+}