dev-libs/zziplib: EAPI=5; convert to python-single-r1

Package-Manager: portage-2.2.26

diff --git a/dev-libs/zziplib/zziplib-0.13.62-r1.ebuild b/dev-libs/zziplib/zziplib-0.13.62-r1.ebuild
new file mode 100644 (file)
index 0000000..910da39
--- /dev/null
+++ b/dev-libs/zziplib/zziplib-0.13.62-r1.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+PYTHON_COMPAT=( python2_7 )
+inherit libtool eutils flag-o-matic python-single-r1
+
+DESCRIPTION="Lightweight library used to easily extract data from files archived in a single zip file"
+HOMEPAGE="http://zziplib.sourceforge.net/"
+SRC_URI="mirror://sourceforge/zziplib/${P}.tar.bz2"
+
+LICENSE="|| ( LGPL-2.1 MPL-1.1 )"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="doc sdl static-libs test"
+
+RDEPEND="sys-libs/zlib
+       sdl? ( >=media-libs/libsdl-1.2.6 )"
+DEPEND="${RDEPEND}
+       ${PYTHON_DEPS}
+       virtual/pkgconfig
+       test? ( app-arch/zip )"
+
+pkg_setup() {
+       python-single-r1_pkg_setup
+}
+
+src_prepare() {
+       epatch "${FILESDIR}"/${PN}-0.13.49-SDL-test.patch
+
+       python_fix_shebang .
+
+       # workaround AX_CREATE_PKGCONFIG_INFO bug #353195
+       sed -i \
+               -e '/ax_create_pkgconfig_ldflags/s:$LDFLAGS::' \
+               -e '/ax_create_pkgconfig_cppflags/s:$CPPFLAGS::' \
+               configure || die
+
+       # zziplib tries to install backwards compat symlinks we dont want
+       sed -i -e '/^zzip-postinstall:/s|$|\ndisable-this:|' Makefile.in || die
+       sed -i -e '/^install-exec-hook:/s|$|\ndisable-this:|' zzip/Makefile.in || die
+
+       elibtoolize
+
+       # Do an out-of-tree build as their configure will do it automatically
+       # otherwise and that can lead to funky errors. #492816
+       mkdir -p build
+}
+
+src_configure() {
+       cd "${S}"/build
+
+       append-flags -fno-strict-aliasing # bug reported upstream
+       export ac_cv_path_XMLTO= # man pages are bundled in .tar's
+
+       # Disable aclocal probing as the default path works #449156
+       ECONF_SOURCE=${S} \
+       ACLOCAL=true \
+       econf \
+               $(use_enable sdl) \
+               $(use_enable static-libs static)
+       MAKEOPTS+=' -C build'
+}
+
+src_test() {
+       # need this because `make test` will always return true
+       # tests fail with -j > 1 (bug #241186)
+       emake -j1 check
+}
+
+src_install() {
+       default
+       # fowners fails when we don't have enough permissions (Prefix)
+       if [[ ${EUID} == 0 ]] ; then
+               fowners -R root /usr/share/man #321975
+       fi
+
+       prune_libtool_files
+
+       if use doc ; then
+               dohtml -r docs/*
+       fi
+}