+++ /dev/null
-# Copyright 1999-2011 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/ffmpeg/ffmpeg-0.9.ebuild,v 1.4 2011/12/17 14:08:12 aballier Exp $
-
-EAPI="4"
-
-SCM=""
-if [ "${PV#9999}" != "${PV}" ] ; then
- SCM="git-2"
- EGIT_REPO_URI="git://git.videolan.org/ffmpeg.git"
-fi
-
-inherit eutils flag-o-matic multilib toolchain-funcs ${SCM}
-
-DESCRIPTION="Complete solution to record, convert and stream audio and video. Includes libavcodec."
-HOMEPAGE="http://ffmpeg.org/"
-if [ "${PV#9999}" != "${PV}" ] ; then
- SRC_URI=""
-elif [ "${PV%_p*}" != "${PV}" ] ; then # Snapshot
- SRC_URI="mirror://gentoo/${P}.tar.bz2"
-else # Release
- SRC_URI="http://ffmpeg.org/releases/${P/_/-}.tar.bz2"
-fi
-FFMPEG_REVISION="${PV#*_p}"
-
-LICENSE="GPL-2 amr? ( GPL-3 ) encode? ( aac? ( GPL-3 ) )"
-SLOT="0"
-if [ "${PV#9999}" = "${PV}" ] ; then
- KEYWORDS="~amd64 ~hppa ~x86-fbsd"
-fi
-IUSE="
- aac aacplus alsa amr ass bindist +bzip2 cdio celt cpudetection debug dirac doc
- +encode faac frei0r gnutls gsm +hardcoded-tables ieee1394 jack jpeg2k libv4l
- modplug mp3 network openal openssl oss pic pulseaudio +qt-faststart rtmp
- schroedinger sdl speex static-libs test theora threads truetype v4l vaapi
- vdpau vorbis vpx X x264 xvid +zlib
- "
-
-# String for CPU features in the useflag[:configure_option] form
-# if :configure_option isn't set, it will use 'useflag' as configure option
-CPU_FEATURES="3dnow:amd3dnow 3dnowext:amd3dnowext altivec avx mmx mmxext:mmx2 ssse3 vis neon iwmmxt"
-
-for i in ${CPU_FEATURES}; do
- IUSE="${IUSE} ${i%:*}"
-done
-
-RDEPEND="
- alsa? ( media-libs/alsa-lib )
- amr? ( media-libs/opencore-amr )
- ass? ( media-libs/libass )
- bzip2? ( app-arch/bzip2 )
- cdio? ( dev-libs/libcdio )
- celt? ( >=media-libs/celt-0.11.1 )
- dirac? ( media-video/dirac )
- encode? (
- aac? ( media-libs/vo-aacenc )
- aacplus? ( media-libs/libaacplus )
- amr? ( media-libs/vo-amrwbenc )
- faac? ( media-libs/faac )
- mp3? ( >=media-sound/lame-3.98.3 )
- theora? ( >=media-libs/libtheora-1.1.1[encode] media-libs/libogg )
- vorbis? ( media-libs/libvorbis media-libs/libogg )
- x264? ( >=media-libs/x264-0.0.20111017 )
- xvid? ( >=media-libs/xvid-1.1.0 )
- )
- frei0r? ( media-plugins/frei0r-plugins )
- gnutls? ( net-libs/gnutls )
- gsm? ( >=media-sound/gsm-1.0.12-r1 )
- ieee1394? ( media-libs/libdc1394 sys-libs/libraw1394 )
- jack? ( media-sound/jack-audio-connection-kit )
- jpeg2k? ( >=media-libs/openjpeg-1.3-r2 )
- libv4l? ( media-libs/libv4l )
- modplug? ( media-libs/libmodplug )
- openal? ( >=media-libs/openal-1.1 )
- pulseaudio? ( media-sound/pulseaudio )
- rtmp? ( >=media-video/rtmpdump-2.2f )
- sdl? ( >=media-libs/libsdl-1.2.13-r1[audio,video] )
- schroedinger? ( media-libs/schroedinger )
- speex? ( >=media-libs/speex-1.2_beta3 )
- truetype? ( media-libs/freetype:2 )
- vaapi? ( >=x11-libs/libva-0.32 )
- vdpau? ( x11-libs/libvdpau )
- vpx? ( >=media-libs/libvpx-0.9.6 )
- X? ( x11-libs/libX11 x11-libs/libXext x11-libs/libXfixes )
- zlib? ( sys-libs/zlib )
- !media-video/qt-faststart
-"
-
-DEPEND="${RDEPEND}
- >=sys-devel/make-3.81
- dirac? ( dev-util/pkgconfig )
- doc? ( app-text/texi2html )
- gnutls? ( dev-util/pkgconfig )
- ieee1394? ( dev-util/pkgconfig )
- libv4l? ( dev-util/pkgconfig )
- mmx? ( dev-lang/yasm )
- rtmp? ( dev-util/pkgconfig )
- schroedinger? ( dev-util/pkgconfig )
- test? ( net-misc/wget )
- truetype? ( dev-util/pkgconfig )
- v4l? ( sys-kernel/linux-headers )
-"
-# faac is license-incompatible with ffmpeg
-REQUIRED_USE="bindist? ( encode? ( !faac !aacplus ) !openssl )
- libv4l? ( v4l )
- test? ( encode zlib )"
-
-S=${WORKDIR}/${P/_/-}
-
-src_prepare() {
- if [ "${PV%_p*}" != "${PV}" ] ; then # Snapshot
- export revision=git-N-${FFMPEG_REVISION}
- fi
-}
-
-src_configure() {
- local myconf="${EXTRA_FFMPEG_CONF}"
- # Set to --enable-version3 if (L)GPL-3 is required
- local version3=""
-
- # enabled by default
- for i in debug doc network vaapi vdpau zlib; do
- use ${i} || myconf="${myconf} --disable-${i}"
- done
- use bzip2 || myconf="${myconf} --disable-bzlib"
- use sdl || myconf="${myconf} --disable-ffplay"
-
- use cpudetection && myconf="${myconf} --enable-runtime-cpudetect"
- use openssl && myconf="${myconf} --enable-openssl --enable-nonfree"
- use gnutls && myconf="${myconf} --enable-gnutls"
-
- # Encoders
- if use encode
- then
- use mp3 && myconf="${myconf} --enable-libmp3lame"
- use aac && { myconf="${myconf} --enable-libvo-aacenc" ; version3=" --enable-version3" ; }
- use amr && { myconf="${myconf} --enable-libvo-amrwbenc" ; version3=" --enable-version3" ; }
- for i in theora vorbis x264 xvid; do
- use ${i} && myconf="${myconf} --enable-lib${i}"
- done
- use aacplus && myconf="${myconf} --enable-libaacplus --enable-nonfree"
- use faac && myconf="${myconf} --enable-libfaac --enable-nonfree"
- else
- myconf="${myconf} --disable-encoders"
- fi
-
- # libavdevice options
- use cdio && myconf="${myconf} --enable-libcdio"
- use ieee1394 && myconf="${myconf} --enable-libdc1394"
- use openal && myconf="${myconf} --enable-openal"
- # Indevs
- # v4l1 is gone since linux-headers-2.6.38
- myconf="${myconf} --disable-indev=v4l"
- use v4l || myconf="${myconf} --disable-indev=v4l2"
- for i in alsa oss jack ; do
- use ${i} || myconf="${myconf} --disable-indev=${i}"
- done
- use X && myconf="${myconf} --enable-x11grab"
- use pulseaudio && myconf="${myconf} --enable-libpulse"
- use libv4l && myconf="${myconf} --enable-libv4l2"
- # Outdevs
- for i in alsa oss sdl ; do
- use ${i} || myconf="${myconf} --disable-outdev=${i}"
- done
- # libavfilter options
- use frei0r && myconf="${myconf} --enable-frei0r"
- use truetype && myconf="${myconf} --enable-libfreetype"
- use ass && myconf="${myconf} --enable-libass"
-
- # Threads; we only support pthread for now but ffmpeg supports more
- use threads && myconf="${myconf} --enable-pthreads"
-
- # Decoders
- use amr && { myconf="${myconf} --enable-libopencore-amrwb --enable-libopencore-amrnb" ; version3=" --enable-version3" ; }
- for i in celt gsm dirac modplug rtmp schroedinger speex vpx; do
- use ${i} && myconf="${myconf} --enable-lib${i}"
- done
- use jpeg2k && myconf="${myconf} --enable-libopenjpeg"
-
- # CPU features
- for i in ${CPU_FEATURES}; do
- use ${i%:*} || myconf="${myconf} --disable-${i#*:}"
- done
- if use pic ; then
- myconf="${myconf} --enable-pic"
- # disable asm code if PIC is required
- # as the provided asm decidedly is not PIC for x86.
- use x86 && myconf="${myconf} --disable-asm"
- fi
-
- # Try to get cpu type based on CFLAGS.
- # Bug #172723
- # We need to do this so that features of that CPU will be better used
- # If they contain an unknown CPU it will not hurt since ffmpeg's configure
- # will just ignore it.
- for i in $(get-flag march) $(get-flag mcpu) $(get-flag mtune) ; do
- [ "${i}" = "native" ] && i="host" # bug #273421
- myconf="${myconf} --cpu=${i}"
- break
- done
-
- # Mandatory configuration
- myconf="
- --enable-gpl
- ${version3}
- --enable-postproc
- --enable-avfilter
- --disable-stripping
- ${myconf}"
-
- # cross compile support
- if tc-is-cross-compiler ; then
- myconf="${myconf} --enable-cross-compile --arch=$(tc-arch-kernel) --cross-prefix=${CHOST}-"
- case ${CHOST} in
- *freebsd*)
- myconf="${myconf} --target-os=freebsd"
- ;;
- mingw32*)
- myconf="${myconf} --target-os=mingw32"
- ;;
- *linux*)
- myconf="${myconf} --target-os=linux"
- ;;
- esac
- fi
-
- # Misc stuff
- use hardcoded-tables && myconf="${myconf} --enable-hardcoded-tables"
-
- cd "${S}"
- ./configure \
- --prefix="${EPREFIX}/usr" \
- --libdir="${EPREFIX}/usr/$(get_libdir)" \
- --shlibdir="${EPREFIX}/usr/$(get_libdir)" \
- --mandir="${EPREFIX}/usr/share/man" \
- --enable-shared \
- --cc="$(tc-getCC)" \
- --optflags="${CFLAGS}" \
- --extra-cflags="${CFLAGS}" \
- --extra-cxxflags="${CXXFLAGS}" \
- $(use_enable static-libs static) \
- ${myconf} || die
-}
-
-src_compile() {
- #252269
- emake version.h
- emake
-
- if use qt-faststart; then
- tc-export CC
- emake -C tools qt-faststart
- fi
-}
-
-src_install() {
- emake DESTDIR="${D}" install install-man
-
- dodoc Changelog README INSTALL
- dodoc -r doc/*
-
- if use qt-faststart; then
- dobin tools/qt-faststart
- fi
-}
-
-src_test() {
- LD_LIBRARY_PATH="${S}/libpostproc:${S}/libswscale:${S}/libswresample:${S}/libavcodec:${S}/libavdevice:${S}/libavfilter:${S}/libavformat:${S}/libavutil" \
- emake fate
-}
+++ /dev/null
-# Copyright 1999-2011 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/vlc/vlc-1.1.12.ebuild,v 1.8 2011/12/06 12:29:01 aballier Exp $
-
-EAPI="3"
-
-SCM=""
-if [ "${PV%9999}" != "${PV}" ] ; then
- SCM=git
- EGIT_BOOTSTRAP="bootstrap"
- EGIT_BRANCH=master
- EGIT_PROJECT=${P}
- if [ "${PV%.9999}" != "${PV}" ] ; then
- EGIT_REPO_URI="git://git.videolan.org/vlc/vlc-${PV%.9999}.git"
- else
- EGIT_REPO_URI="git://git.videolan.org/vlc.git"
- fi
-fi
-
-inherit eutils multilib autotools toolchain-funcs gnome2 nsplugins qt4 flag-o-matic ${SCM}
-
-MY_PV="${PV/_/-}"
-MY_PV="${MY_PV/-beta/-test}"
-MY_P="${PN}-${MY_PV}"
-VLC_SNAPSHOT_TIME="0013"
-
-PATCHLEVEL="99"
-DESCRIPTION="VLC media player - Video player and streamer"
-HOMEPAGE="http://www.videolan.org/vlc/"
-if [ "${PV%9999}" != "${PV}" ] ; then # Live ebuild
- SRC_URI=""
-elif [[ "${P}" == *_alpha* ]]; then # Snapshots taken from nightlies.videolan.org
- SRC_URI="http://nightlies.videolan.org/build/source/trunk-${PV/*_alpha/}-${VLC_SNAPSHOT_TIME}/${PN}-snapshot-${PV/*_alpha/}.tar.bz2"
- MY_P="${P/_alpha*/}-git"
-elif [[ "${MY_P}" == "${P}" ]]; then
- SRC_URI="http://download.videolan.org/pub/videolan/${PN}/${PV}/${P}.tar.bz2"
-else
- SRC_URI="http://download.videolan.org/pub/videolan/testing/${MY_P}/${MY_P}.tar.bz2"
-fi
-
-SRC_URI="${SRC_URI}
- mirror://gentoo/${PN}-patches-${PATCHLEVEL}.tar.bz2"
-
-LICENSE="GPL-2"
-SLOT="0"
-
-if [ "${PV%9999}" = "${PV}" ] ; then
- KEYWORDS="alpha amd64 ~arm ppc ppc64 sparc x86 ~x86-fbsd"
-else
- KEYWORDS=""
-fi
-IUSE="a52 aac aalib alsa altivec atmo avahi bidi cdda cddb dbus dc1394
- debug dirac directfb dts dvb dvd elibc_glibc fbcon fluidsynth +ffmpeg flac fontconfig
- +gcrypt ggi gme gnome gnutls httpd id3tag ieee1394 jack kate kde libass libcaca
- libnotify libproxy libtiger libv4l libv4l2 lirc live lua matroska mmx
- modplug mp3 mpeg mtp musepack ncurses nsplugin ogg opengl optimisememory oss
- png projectm pulseaudio pvr +qt4 remoteosd rtsp run-as-root samba
- schroedinger sdl sdl-image shine shout skins speex sqlite sse stream
- svg svga taglib theora truetype twolame udev upnp v4l vaapi vcdx vlm
- vorbis win32codecs wma-fixed +X x264 +xcb xml xosd xv zvbi"
-
-RDEPEND="
- || ( >=sys-libs/zlib-1.2.5.1-r2[minizip] <sys-libs/zlib-1.2.5.1-r1 )
- >=media-libs/libdvbpsi-0.1.6
- a52? ( >=media-libs/a52dec-0.7.4-r3 )
- aalib? ( media-libs/aalib x11-libs/libX11 )
- aac? ( >=media-libs/faad2-2.6.1 )
- alsa? ( >=media-libs/alsa-lib-1.0.23 )
- avahi? ( >=net-dns/avahi-0.6[dbus] )
- bidi? ( >=dev-libs/fribidi-0.10.4 )
- cdda? ( cddb? ( >=media-libs/libcddb-1.2.0 ) )
- dbus? ( >=sys-apps/dbus-1.0.2 )
- dc1394? ( >=sys-libs/libraw1394-2.0.1 >=media-libs/libdc1394-2.0.2 )
- dirac? ( >=media-video/dirac-0.10.0 )
- directfb? ( dev-libs/DirectFB sys-libs/zlib )
- dts? ( media-libs/libdca )
- dvd? ( media-libs/libdvdread >=media-libs/libdvdnav-0.1.9 )
- elibc_glibc? ( >=sys-libs/glibc-2.8 )
- ffmpeg? ( virtual/ffmpeg )
- flac? ( media-libs/libogg >=media-libs/flac-1.1.2 )
- fluidsynth? ( media-sound/fluidsynth )
- fontconfig? ( media-libs/fontconfig )
- gcrypt? ( >=dev-libs/libgcrypt-1.2.0 )
- ggi? ( media-libs/libggi )
- gme? ( media-libs/game-music-emu )
- gnome? ( gnome-base/gnome-vfs )
- gnutls? ( >=net-libs/gnutls-1.7.4 >=dev-libs/libgcrypt-1.2.0 )
- id3tag? ( media-libs/libid3tag sys-libs/zlib )
- ieee1394? ( >=sys-libs/libraw1394-2.0.1 >=sys-libs/libavc1394-0.5.3 )
- jack? ( >=media-sound/jack-audio-connection-kit-0.99.0-r1 )
- kate? ( >=media-libs/libkate-0.1.1 )
- libass? ( >=media-libs/libass-0.9.6 media-libs/fontconfig )
- libcaca? ( >=media-libs/libcaca-0.99_beta14 )
- libnotify? ( x11-libs/libnotify x11-libs/gtk+:2 )
- libproxy? ( net-libs/libproxy )
- libtiger? ( media-libs/libtiger )
- lirc? ( app-misc/lirc )
- live? ( >=media-plugins/live-2008.07.06 )
- lua? ( >=dev-lang/lua-5.1 )
- matroska? ( >=dev-libs/libebml-0.7.6 >=media-libs/libmatroska-0.8.0 )
- modplug? ( >=media-libs/libmodplug-0.8.8.1 )
- mp3? ( media-libs/libmad )
- mpeg? ( >=media-libs/libmpeg2-0.3.2 )
- mtp? ( >=media-libs/libmtp-1.0.0 )
- musepack? ( >=media-sound/musepack-tools-444 )
- ncurses? ( sys-libs/ncurses )
- nsplugin? ( >=net-libs/xulrunner-1.9.2 x11-libs/libXpm x11-libs/libXt x11-libs/libxcb x11-libs/xcb-util )
- ogg? ( media-libs/libogg )
- opengl? ( virtual/opengl || ( >=x11-libs/libX11-1.3.99.901 <x11-libs/libX11-1.3.99.901[xcb] ) )
- png? ( media-libs/libpng sys-libs/zlib )
- projectm? ( media-libs/libprojectm )
- pulseaudio? ( || ( >=media-sound/pulseaudio-0.9.22
- ( >=media-sound/pulseaudio-0.9.11 x11-libs/libX11 ) ) )
- qt4? ( x11-libs/qt-gui:4 x11-libs/qt-core:4 x11-libs/libX11 )
- remoteosd? ( >=dev-libs/libgcrypt-1.2.0 )
- samba? ( || ( >=net-fs/samba-3.4.6[smbclient] <net-fs/samba-3.4 ) )
- schroedinger? ( >=media-libs/schroedinger-1.0.10 )
- sdl? ( >=media-libs/libsdl-1.2.8 x11-libs/libX11
- sdl-image? ( media-libs/sdl-image sys-libs/zlib ) )
- shout? ( media-libs/libshout )
- skins? (
- x11-libs/qt-gui:4 x11-libs/qt-core:4
- x11-libs/libXext x11-libs/libX11
- media-libs/freetype media-fonts/dejavu
- )
- speex? ( media-libs/speex )
- sqlite? ( >=dev-db/sqlite-3.6.0:3 )
- svg? ( >=gnome-base/librsvg-2.9.0 )
- svga? ( media-libs/svgalib )
- taglib? ( >=media-libs/taglib-1.5 sys-libs/zlib )
- theora? ( >=media-libs/libtheora-1.0_beta3 )
- truetype? ( media-libs/freetype virtual/ttf-fonts
- !fontconfig? ( media-fonts/dejavu ) )
- twolame? ( media-sound/twolame )
- udev? ( >=sys-fs/udev-142 )
- upnp? ( net-libs/libupnp )
- v4l? (
- libv4l2? ( media-libs/libv4l )
- libv4l? ( media-libs/libv4l )
- )
- vaapi? ( x11-libs/libva virtual/ffmpeg )
- vcdx? ( >=dev-libs/libcdio-0.78.2 >=media-video/vcdimager-0.7.22 )
- vorbis? ( media-libs/libvorbis )
- win32codecs? ( media-libs/win32codecs )
- X? ( x11-libs/libX11 )
- x264? ( >=media-libs/x264-0.0.20090923 )
- xcb? ( x11-libs/libxcb x11-libs/xcb-util )
- xml? ( dev-libs/libxml2 )
- xosd? ( x11-libs/xosd )
- zvbi? ( >=media-libs/zvbi-0.2.25 )
- "
-
-DEPEND="${RDEPEND}
- !!<=media-video/vlc-1.0.99999
- alsa? ( >=media-sound/alsa-headers-1.0.23 )
- dvb? ( sys-kernel/linux-headers )
- kde? ( >=kde-base/kdelibs-4 )
- v4l? ( >=sys-kernel/linux-headers-2.6.25 )
- xcb? ( x11-proto/xproto )
- dev-util/pkgconfig"
-
-S="${WORKDIR}/${MY_P}"
-
-# Displays a warning if the first use flag is set but the second is not
-vlc_use_needs() {
- use $1 && use !$2 && ewarn "USE=$1 requires $2, $1 will be disabled."
-}
-
-# Notify the user that some useflag have been forced on
-vlc_use_force() {
- use $1 && use !$2 && ewarn "USE=$1 requires $2, $2 will be enabled."
-}
-
-# Use when $1 depends strictly on $2
-# if use $1 then enable $2
-vlc_use_enable_force() {
- use $1 && echo "--enable-$2"
-}
-
-pkg_setup() {
- # Useflags we need to forcefuly enable
- vlc_use_force remoteosd gcrypt
- vlc_use_force gnutls gcrypt
- vlc_use_force skins truetype
- vlc_use_force skins qt4
- vlc_use_force vlm stream
- vlc_use_force vaapi ffmpeg
- vlc_use_force nsplugin xcb
- has_version '<media-sound/pulseaudio-0.9.22' && vlc_use_force pulseaudio X
- vlc_use_force sdl X
- vlc_use_force aalib X
-
- # Useflags that will be automagically discarded if deps are not met
- vlc_use_needs bidi truetype
- vlc_use_needs cddb cdda
- vlc_use_needs fontconfig truetype
- vlc_use_needs libv4l2 v4l
- vlc_use_needs libv4l v4l
- vlc_use_needs libtiger kate
- vlc_use_needs xv xcb
-
- if use qt4 || use skins ; then
- qt4_pkg_setup
- else
- ewarn "You have disabled the qt4 useflag, ${PN} will not have any"
- ewarn "graphical interface. Maybe that is not what you want..."
- fi
-}
-
-src_unpack() {
- unpack ${A}
- if [ "${PV%9999}" != "${PV}" ] ; then
- git_src_unpack
- fi
-}
-
-src_prepare() {
- if [ "${PV%9999}" != "${PV}" ] ; then
- git_src_prepare
- fi
- # Make it build with libtool 1.5
- rm -f m4/lt* m4/libtool.m4
-
- EPATCH_SUFFIX="patch" epatch "${WORKDIR}/patches"
- eautoreconf
-}
-
-src_configure() {
-
- # It would fail if -fforce-addr is used due to too few registers...
- use x86 && filter-flags -fforce-addr
-
- econf \
- $(use_enable a52) \
- $(use_enable aalib aa) \
- $(use_enable aac faad) \
- $(use_enable alsa) \
- $(use_enable altivec) \
- --disable-asademux \
- $(use_enable atmo) \
- $(use_enable avahi bonjour) \
- $(use_enable bidi fribidi) \
- $(use_enable cdda vcd) \
- $(use_enable cddb libcddb) \
- $(use_enable dbus) $(use_enable dbus dbus-control) \
- $(use_enable dirac) \
- $(use_enable directfb) \
- $(use_enable dc1394) \
- $(use_enable debug) \
- $(use_enable dts dca) \
- $(use_enable dvb) \
- $(use_enable dvd dvdread) $(use_enable dvd dvdnav) \
- $(use_enable fbcon fb) \
- $(use_enable ffmpeg avcodec) $(use_enable ffmpeg avformat) $(use_enable ffmpeg swscale) $(use_enable ffmpeg postproc) \
- $(use_enable flac) \
- $(use_enable fluidsynth) \
- $(use_enable fontconfig) \
- $(use_enable ggi) \
- $(use_enable gme) \
- $(use_enable gnome gnomevfs) \
- $(use_enable gnutls) \
- $(use_enable httpd) \
- $(use_enable id3tag) \
- $(use_enable ieee1394 dv) \
- $(use_enable jack) \
- $(use_enable kate) \
- $(use_with kde kde-solid) \
- $(use_enable libass) \
- $(use_enable libcaca caca) \
- $(use_enable gcrypt libgcrypt) \
- $(use_enable libnotify notify) \
- $(use_enable libproxy) \
- --disable-libtar \
- $(use_enable libtiger tiger) \
- $(use_enable libv4l) \
- $(use_enable libv4l2) \
- $(use_enable lirc) \
- $(use_enable live live555) \
- $(use_enable lua) \
- $(use_enable matroska mkv) \
- $(use_enable mmx) \
- $(use_enable modplug mod) \
- $(use_enable mp3 mad) \
- $(use_enable mpeg libmpeg2) \
- $(use_enable mtp) \
- $(use_enable musepack mpc) \
- $(use_enable ncurses) \
- $(use_enable nsplugin mozilla) --with-mozilla-pkg=libxul \
- $(use_enable ogg) \
- $(use_enable opengl glx) $(use_enable opengl) \
- $(use_enable optimisememory optimize-memory) \
- $(use_enable oss) \
- $(use_enable png) \
- --disable-portaudio \
- $(use_enable projectm) \
- $(use_enable pulseaudio pulse) \
- $(use_enable pvr) \
- $(use_enable qt4) \
- $(use_enable remoteosd) \
- $(use_enable rtsp realrtsp) \
- $(use_enable run-as-root) \
- $(use_enable samba smb) \
- $(use_enable schroedinger) \
- $(use_enable sdl) \
- $(use_enable sdl-image) \
- $(use_enable shine) \
- $(use_enable shout) \
- $(use_enable skins skins2) \
- $(use_enable speex) \
- $(use_enable sqlite) \
- $(use_enable sse) \
- $(use_enable stream sout) \
- $(use_enable svg) \
- $(use_enable svga svgalib) \
- $(use_enable taglib) \
- $(use_enable theora) \
- $(use_enable truetype freetype) \
- $(use_enable twolame) \
- $(use_enable udev) \
- $(use_enable upnp) \
- --disable-v4l \
- $(use_enable v4l v4l2) \
- $(use_enable vcdx) \
- $(use_enable vaapi libva) \
- $(use_enable vlm) \
- $(use_enable vorbis) \
- $(use_enable win32codecs loader) \
- $(use_enable wma-fixed) \
- $(use_with X x) \
- $(use_enable x264) \
- $(use_enable xcb) \
- $(use_enable xml libxml2) \
- $(use_enable xosd) \
- $(use_enable xv xvideo) \
- $(use_enable zvbi) $(use_enable !zvbi telx) \
- --disable-snapshot \
- --disable-growl \
- --disable-optimizations \
- --enable-fast-install \
- $(vlc_use_enable_force vlm sout) \
- $(vlc_use_enable_force skins qt4) \
- $(vlc_use_enable_force skins freetype) \
- $(vlc_use_enable_force remoteosd libgcrypt) \
- $(vlc_use_enable_force gnutls libgcrypt) \
- $(vlc_use_enable_force vaapi avcodec) \
- $(vlc_use_enable_force nsplugin xcb) \
- $(has_version '<media-sound/pulseaudio-0.9.22' && use pulseaudio && echo '--with-x') \
- $(use sdl && echo '--with-x') \
- $(use aalib && echo '--with-x')
-}
-
-src_install() {
- emake DESTDIR="${D}" install || die "make install failed"
-
- dodoc AUTHORS HACKING THANKS NEWS README \
- doc/fortunes.txt doc/intf-vcd.txt
-
- rm -rf "${D}/usr/share/doc/vlc" \
- "${D}"/usr/share/vlc/vlc{16x16,32x32,48x48,128x128}.{png,xpm,ico}
-
- if use nsplugin; then
- dodir "/usr/$(get_libdir)/${PLUGINS_DIR}"
- mv "${D}"/usr/$(get_libdir)/mozilla/plugins/* \
- "${D}/usr/$(get_libdir)/${PLUGINS_DIR}/"
- fi
-
- use skins || rm -rf "${D}/usr/share/vlc/skins2"
-}
-
-pkg_postinst() {
- gnome2_pkg_postinst
-
- if [ "$ROOT" = "/" ] && [ -x "/usr/$(get_libdir)/vlc/vlc-cache-gen" ] ; then
- einfo "Running /usr/$(get_libdir)/vlc/vlc-cache-gen on /usr/$(get_libdir)/vlc/plugins/"
- "/usr/$(get_libdir)/vlc/vlc-cache-gen" -f "/usr/$(get_libdir)/vlc/plugins/"
- else
- ewarn "We cannot run vlc-cache-gen (most likely ROOT!=/)"
- ewarn "Please run /usr/$(get_libdir)/vlc/vlc-cache-gen manually"
- ewarn "If you do not do it, vlc will take a long time to load."
- fi
-}
projects / gentoo.git / commitdiff