net-misc/remmina: bump to 1.4.3

Package-Manager: Portage-2.3.99, Repoman-2.3.22
Signed-off-by: Ben Kohler <bkohler@gentoo.org>

diff --git a/net-misc/remmina/Manifest b/net-misc/remmina/Manifest
index d427ec6954b9f11a09ba94c51306d6a1af792508..76dfeb27da4a7af8b4c093d645292caf3b81a9fd 100644 (file)
--- a/net-misc/remmina/Manifest
+++ b/net-misc/remmina/Manifest
@@ -4,3 +4,4 @@ DIST Remmina-v1.3.6.tar.gz 1538166 BLAKE2B f3fc60df2a1a31bd5aae7d8de2d85cd579fa4
 DIST Remmina-v1.3.9.tar.gz 1627404 BLAKE2B 4077b38e987a93f71f96597784949522659def04ad0d2ab05c72bebb94a3bbf2c2a222828965aaf76b0273a378950b5dd0e7acdb7543f0d6c7f3220d16eb281c SHA512 f87d30d30d6d9692f60cd27336ac0059a4374125b231cdf1e3710785b08fc77722112ea48e5717958b03fc5784abb9fcd86aa5a427c4d634cb3f2be1aac41945
 DIST Remmina-v1.4.1.tar.gz 1662456 BLAKE2B 17bc53459e2073c1df3a53963ab9775ab61d41904e592177c815bba9cf74d586152bf5c3af6fd2430c1e8d3e0203747f2d4e13093fdc343bcb9e4ebafaf50046 SHA512 90e78cc488d3d695373043ce2f7db6626e5a92f284aaa9e81a6683f4e3a1b7b2f025eff3ce456b98a180b2afc2419da76daed95dd164692c15c2a2219a354397
 DIST Remmina-v1.4.2.tar.gz 1700893 BLAKE2B ebac1337eaa9af29b09c6be4bcc9093b02ac96fad4480f06656a9cf21e6b805651bfbdd1361ef605334ab6bfc4ffbd4b6f5360f44fa9c11b0bc8189078ecf35e SHA512 50c8d866e0a995f84f31d2c0b881117e2af329b8e661de5c1472201c250fb3482471d16f2532c2915ff59d6cd912f490839b7e8cd267aad8f9140a915a518e41
+DIST Remmina-v1.4.3.tar.gz 1705751 BLAKE2B 4d49b5d5da4017cc1870a5e37a73db767862997cffdd58b080ab5707eeb293eed7e756ca974a4f4922bb9417e94610fe07b1e774f5ad7e269e797362ff264e83 SHA512 9f555f9ff60e2a136f6379a0f2828d091aa972dcff7ebd09eaf1834dc10f506d218e5cb6856c17f625c1040a11240da2ed5ebe9f4fe32a083494cfcbbdef1a41

diff --git a/net-misc/remmina/remmina-1.4.3.ebuild b/net-misc/remmina/remmina-1.4.3.ebuild
new file mode 100644 (file)
index 0000000..8eab2f1
--- /dev/null
+++ b/net-misc/remmina/remmina-1.4.3.ebuild
@@ -0,0 +1,98 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit cmake-utils eutils gnome2-utils xdg-utils
+
+MY_P="${PN^}-v${PV}"
+
+DESCRIPTION="A GTK+ RDP, SPICE, VNC, XDMCP and SSH client"
+HOMEPAGE="https://remmina.org/"
+SRC_URI="https://gitlab.com/Remmina/Remmina/-/archive/v${PV}/${MY_P}.tar.gz"
+
+LICENSE="GPL-2+-with-openssl-exception"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="ayatana crypt cups examples gnome-keyring kwallet libressl nls spice ssh rdp telepathy vnc webkit zeroconf"
+
+CDEPEND="
+       dev-libs/glib:2
+       dev-libs/json-glib
+       dev-libs/libsodium:=
+       net-libs/libsoup
+       x11-libs/gdk-pixbuf
+       x11-libs/gtk+:3
+       x11-libs/libX11
+       x11-libs/libxkbfile
+       ayatana? ( dev-libs/libappindicator:3 )
+       crypt? ( dev-libs/libgcrypt:0= )
+       rdp? ( >=net-misc/freerdp-2.0.0_rc4_p1129
+               <net-misc/freerdp-3
+               cups? ( net-print/cups:= ) )
+       gnome-keyring? ( app-crypt/libsecret )
+       kwallet? ( kde-frameworks/kwallet )
+       !libressl? ( dev-libs/openssl:0= )
+       libressl? ( dev-libs/libressl:0= )
+       spice? ( net-misc/spice-gtk[gtk3] )
+       ssh? ( net-libs/libssh:0=[sftp]
+               x11-libs/vte:2.91 )
+       telepathy? ( net-libs/telepathy-glib )
+       vnc? ( net-libs/libvncserver[jpeg] )
+       webkit? ( net-libs/webkit-gtk:4 )
+       zeroconf? ( || ( >=net-dns/avahi-0.8-r2[dbus,gtk] <net-dns/avahi-0.8-r2[dbus,gtk3] ) )
+"
+DEPEND="${CDEPEND}
+       dev-util/intltool
+       virtual/pkgconfig
+       nls? ( sys-devel/gettext )
+"
+RDEPEND="${CDEPEND}
+       virtual/freedesktop-icon-theme
+"
+
+DOCS=( AUTHORS CHANGELOG.md README.md THANKS.md )
+
+S="${WORKDIR}/${MY_P}"
+
+src_configure() {
+       local mycmakeargs=(
+               -DWITH_APPINDICATOR=$(usex ayatana)
+               -DWITH_GCRYPT=$(usex crypt)
+               -DWITH_EXAMPLES=$(usex examples)
+               -DWITH_LIBSECRET=$(usex gnome-keyring)
+               -DWITH_KF5WALLET=$(usex kwallet)
+               -DWITH_GETTEXT=$(usex nls)
+               -DWITH_TRANSLATIONS=$(usex nls)
+               -DWITH_FREERDP=$(usex rdp)
+               -DWITH_CUPS=$(usex cups)
+               -DWITH_SPICE=$(usex spice)
+               -DWITH_LIBSSH=$(usex ssh)
+               -DWITH_VTE=$(usex ssh)
+               -DWITH_TELEPATHY=$(usex telepathy)
+               -DWITH_LIBVNCSERVER=$(usex vnc)
+               -DWITH_WWW=$(usex webkit)
+               -DWITH_AVAHI=$(usex zeroconf)
+               -DWITH_ICON_CACHE=OFF
+               -DWITH_UPDATE_DESKTOP_DB=OFF
+       )
+       cmake-utils_src_configure
+}
+
+pkg_postinst() {
+       gnome2_icon_cache_update
+       xdg_mimeinfo_database_update
+       xdg_desktop_database_update
+
+       elog "To get additional features, some optional runtime dependencies"
+       elog "may be installed:"
+       elog ""
+       optfeature "encrypted VNC connections" net-libs/libvncserver[gcrypt]
+       optfeature "XDMCP support" x11-base/xorg-server[xephyr]
+}
+
+pkg_postrm() {
+       gnome2_icon_cache_update
+       xdg_mimeinfo_database_update
+       xdg_desktop_database_update
+}