net-libs/libssh: add libressl support

diff --git a/net-libs/libssh/libssh-0.7.1-r1.ebuild b/net-libs/libssh/libssh-0.7.1-r1.ebuild
new file mode 100644 (file)
index 0000000..52da66a
--- /dev/null
+++ b/net-libs/libssh/libssh-0.7.1-r1.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+MY_P=${PN}-${PV/_rc/rc}
+inherit eutils cmake-multilib multilib
+
+DESCRIPTION="Access a working SSH implementation by means of a library"
+HOMEPAGE="http://www.libssh.org/"
+SRC_URI="https://red.libssh.org/attachments/download/154/${MY_P}.tar.xz -> ${P}.tar.xz"
+
+LICENSE="LGPL-2.1"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
+SLOT="0/4" # subslot = soname major version
+IUSE="debug doc examples gcrypt gssapi libressl pcap +sftp ssh1 server static-libs test zlib"
+# Maintainer: check IUSE-defaults at DefineOptions.cmake
+
+RDEPEND="
+       zlib? ( >=sys-libs/zlib-1.2.8-r1[${MULTILIB_USEDEP}] )
+       !gcrypt? (
+               !libressl? ( >=dev-libs/openssl-1.0.1h-r2:0[${MULTILIB_USEDEP}] )
+               libressl? ( dev-libs/libressl[${MULTILIB_USEDEP}] )
+       )
+       gcrypt? ( >=dev-libs/libgcrypt-1.5.3:0[${MULTILIB_USEDEP}] )
+       gssapi? ( >=virtual/krb5-0-r1[${MULTILIB_USEDEP}] )
+"
+DEPEND="${RDEPEND}
+       doc? ( app-doc/doxygen )
+       test? ( >=dev-util/cmocka-0.3.1[${MULTILIB_USEDEP}] )
+"
+
+DOCS=( AUTHORS README ChangeLog )
+
+S=${WORKDIR}/${MY_P}
+
+PATCHES=(
+       "${FILESDIR}"/${PN}-0.5.0-tests.patch
+)
+
+src_prepare() {
+       # just install the examples do not compile them
+       sed -i \
+               -e '/add_subdirectory(examples)/s/^/#DONOTWANT/' \
+               CMakeLists.txt || die
+
+       cmake-utils_src_prepare
+}
+
+multilib_src_configure() {
+       local mycmakeargs=(
+               $(cmake-utils_use_with debug DEBUG_CALLTRACE)
+               $(cmake-utils_use_with debug DEBUG_CRYPTO)
+               $(cmake-utils_use_with gcrypt)
+               $(cmake-utils_use_with gssapi)
+               $(cmake-utils_use_with pcap)
+               $(cmake-utils_use_with server)
+               $(cmake-utils_use_with sftp)
+               $(cmake-utils_use_with ssh1)
+               $(cmake-utils_use_with static-libs STATIC_LIB)
+               $(cmake-utils_use_with test STATIC_LIB)
+               $(cmake-utils_use_with test TESTING)
+               $(cmake-utils_use_with zlib)
+       )
+
+       cmake-utils_src_configure
+}
+
+multilib_src_compile() {
+       cmake-utils_src_compile
+       multilib_is_native_abi && use doc && cmake-utils_src_compile doc
+}
+
+multilib_src_install() {
+       cmake-utils_src_install
+
+       multilib_is_native_abi && use doc && dohtml -r doc/html/.
+
+       use static-libs || rm -f "${D}"/usr/$(get_libdir)/libssh{,_threads}.a
+}
+
+multilib_src_install_all() {
+       einstalldocs
+
+       if use examples; then
+               docinto examples
+               dodoc examples/*.{c,h,cpp}
+       fi
+}

diff --git a/net-libs/libssh/libssh-9999.ebuild b/net-libs/libssh/libssh-9999.ebuild
index 7fcefa90930717f84a0f9b1204938483b9356523..b76736e13ce12f0d7422ecc707400d90e4b0e9a7 100644 (file)
--- a/net-libs/libssh/libssh-9999.ebuild
+++ b/net-libs/libssh/libssh-9999.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2014 Gentoo Foundation
+# Copyright 1999-2015 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 # $Id$
 
@@ -13,12 +13,15 @@ EGIT_REPO_URI="git://git.libssh.org/projects/libssh.git"
 LICENSE="LGPL-2.1"
 KEYWORDS=""
 SLOT="0"
-IUSE="debug doc examples gcrypt gssapi pcap +sftp ssh1 server static-libs test zlib"
+IUSE="debug doc examples gcrypt gssapi libressl pcap +sftp ssh1 server static-libs test zlib"
 # Maintainer: check IUSE-defaults at DefineOptions.cmake
 
 RDEPEND="
        zlib? ( >=sys-libs/zlib-1.2.8-r1[${MULTILIB_USEDEP}] )
-       !gcrypt? ( >=dev-libs/openssl-1.0.1h-r2[${MULTILIB_USEDEP}] )
+       !gcrypt? (
+               !libressl? ( >=dev-libs/openssl-1.0.1h-r2:0[${MULTILIB_USEDEP}] )
+               libressl? ( dev-libs/libressl[${MULTILIB_USEDEP}] )
+       )
        gcrypt? ( >=dev-libs/libgcrypt-1.5.3:0[${MULTILIB_USEDEP}] )
        gssapi? ( >=virtual/krb5-0-r1[${MULTILIB_USEDEP}] )
 "