app-i18n/pology: EAPI-7, use kde.org, cmake.eclass, disable epydoc

A lot has happened since this was last touched, unfortunately no py3. Yet.
Upstream repository switched to git.

Fix doc install dir.
Run python_optimize.

Bug: https://bugs.gentoo.org/707036
Package-Manager: Portage-2.3.86, Repoman-2.3.20
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

diff --git a/app-i18n/pology/pology-9999.ebuild b/app-i18n/pology/pology-9999.ebuild
index a1c06c9a1711ca72ec2eb8f5aec9ac1d09ba6f7a..1670d22e95effec513f47f0e8d79d02a8ea27535 100644 (file)
--- a/app-i18n/pology/pology-9999.ebuild
+++ b/app-i18n/pology/pology-9999.ebuild
@@ -1,61 +1,67 @@
-# Copyright 1999-2018 Gentoo Foundation
+# Copyright 1999-2020 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=6
+EAPI=7
 
-ESVN_REPO_URI="svn://anonsvn.kde.org/home/kde/trunk/l10n-support/pology"
 PYTHON_COMPAT=( python2_7 )
-
-[[ ${PV} == 9999 ]] && VCS_ECLASS="subversion"
-
-inherit python-single-r1 cmake-utils bash-completion-r1 ${VCS_ECLASS}
-unset VCS_ECLASS
+inherit bash-completion-r1 cmake kde.org python-single-r1
 
 DESCRIPTION="A framework for custom processing of PO files"
 HOMEPAGE="http://pology.nedohodnik.net"
-[[ ${PV} == 9999 ]] || SRC_URI="http://pology.nedohodnik.net//release/${P}.tar.bz2"
+
+if [[ ${KDE_BUILD_TYPE} = release ]]; then
+       SRC_URI="http://pology.nedohodnik.net/release/${P}.tar.bz2"
+       KEYWORDS="~amd64 ~x86"
+fi
 
 LICENSE="GPL-3"
 SLOT="0"
-[[ ${PV} == 9999 ]] || \
-KEYWORDS="~amd64 ~x86"
 IUSE=""
 
-RDEPEND="
-       dev-libs/libxslt
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+BDEPEND="
+       app-text/docbook-xsl-stylesheets
+       app-text/docbook-xml-dtd:4.5
+"
+RDEPEND="${PYTHON_DEPS}
        dev-libs/libxml2
+       dev-libs/libxslt
        dev-python/dbus-python[${PYTHON_USEDEP}]
        sys-devel/gettext
-       ${PYTHON_DEPS}
-"
-DEPEND="${RDEPEND}
-       app-text/docbook-xsl-stylesheets
-       app-text/docbook-xml-dtd:4.5
-       dev-python/epydoc[${PYTHON_USEDEP}]
 "
-
-REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+DEPEND="${RDEPEND}"
 
 # Magic on python parsing makes it impossible to make it parallel safe
 MAKEOPTS+=" -j1"
 
 src_prepare() {
-       cmake-utils_src_prepare
+       cmake_src_prepare
+       sed -e "/DOC_INSTALL_DIR/s/^/#DONT/" -i CMakeLists.txt || die
        python_fix_shebang .
 }
 
+src_configure() {
+       local mycmakeargs=(
+               -DDOC_INSTALL_DIR="${EPREFIX}"/usr/share/doc/${PF}
+               -DCMAKE_DISABLE_FIND_PACKAGE_Epydoc=ON
+       )
+       cmake_src_configure
+}
+
 src_install() {
-       cmake-utils_src_install
+       cmake_src_install
+       python_optimize
 
        dosym ../../../pology/syntax/kate/synder.xml /usr/share/apps/katepart/syntax/synder.xml
 
        newbashcomp "${ED}"/usr/share/pology/completion/bash/pology posieve
        bashcomp_alias {posieve,poediff}{,.py}
 
-       einfo "You should also consider following packages to install:"
-       einfo "    app-text/aspell"
-       einfo "    app-text/hunspell"
-       einfo "    dev-vcs/git"
-       einfo "    dev-vcs/subversion"
-       einfo "    sci-misc/apertium"
+       elog "You should also consider following packages to install:"
+       elog "    app-text/aspell"
+       elog "    app-text/hunspell"
+       elog "    dev-vcs/git"
+       elog "    dev-vcs/subversion"
+       elog "    sci-misc/apertium"
 }