dev-libs/xmlsec: Bump to version 1.2.29

Package-Manager: Portage-2.3.77, Repoman-2.3.17
Signed-off-by: Lars Wendler <polynomial-c@gentoo.org>

diff --git a/dev-libs/xmlsec/Manifest b/dev-libs/xmlsec/Manifest
index 80e759b5df256be1c7acd4ef0ac63c35a06447c4..ae0c9a29b072dabc95e365b13e4d5e32d11a0d18 100644 (file)
--- a/dev-libs/xmlsec/Manifest
+++ b/dev-libs/xmlsec/Manifest
@@ -1 +1,2 @@
 DIST xmlsec1-1.2.28.tar.gz 1995599 BLAKE2B 5d90646d9a72024856da2638adb6d0d00d5142f8d3eaa5b12a993e2e6ae78ad49aab69822ebe331191bf1fc5b98431b85e113545aec84e2bb7d5c5add9028df0 SHA512 17fa59e4ffee5e024caa4895e8ed21d1435f14e3a37d0ed781b1dd216333ae3b6099c460efd45d4a8097d0202522150b7b0ad543b47c1596d8473b6922270480
+DIST xmlsec1-1.2.29.tar.gz 1989360 BLAKE2B a0057ddf2d641745933f8d788c5358b4bb17892ed175ef11a9041a34ff1f91d0ffe6cb90316308805b5bc2157b9c2e211b37731ff8cfc7723a85f349543aa7a6 SHA512 07c3012179da4392f0a9d41a51ed51d692ca8b491310488b955d5fef0637f104d3f82374754b0ef175fadc663a8ca8c996178198c5dd77b3a8b34393d1482e4d

diff --git a/dev-libs/xmlsec/xmlsec-1.2.29.ebuild b/dev-libs/xmlsec/xmlsec-1.2.29.ebuild
new file mode 100644 (file)
index 0000000..1785b85
--- /dev/null
+++ b/dev-libs/xmlsec/xmlsec-1.2.29.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools
+
+DESCRIPTION="Command line tool for signing, verifying, encrypting and decrypting XML"
+HOMEPAGE="https://www.aleksey.com/xmlsec"
+SRC_URI="https://www.aleksey.com/xmlsec/download/${PN}1-${PV}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="doc gcrypt gnutls libressl nss +openssl static-libs test"
+REQUIRED_USE="|| ( gcrypt gnutls nss openssl )
+       gnutls? ( gcrypt )"
+
+RDEPEND=">=dev-libs/libxml2-2.7.4:=
+       >=dev-libs/libxslt-1.0.20:=
+       gcrypt? ( >=dev-libs/libgcrypt-1.4.0:0= )
+       gnutls? ( >=net-libs/gnutls-2.8.0:= )
+       nss? (
+               >=dev-libs/nspr-4.4.1:=
+               >=dev-libs/nss-3.9:=
+       )
+       openssl? (
+               !libressl? ( dev-libs/openssl:0= )
+               libressl? ( dev-libs/libressl:0= )
+       )"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig
+       test? (
+               nss? (
+                       >=dev-libs/nss-3.9[utils]
+               )
+       )"
+
+S="${WORKDIR}/${PN}1-${PV}"
+
+src_configure() {
+       econf \
+               $(use_enable doc docs) \
+               $(use_enable static-libs static) \
+               $(use_with gcrypt) \
+               $(use_with gnutls) \
+               $(use_with nss nspr) \
+               $(use_with nss) \
+               $(use_with openssl) \
+               --enable-mans \
+               --enable-pkgconfig
+}
+
+src_test() {
+       emake TMPFOLDER="${T}" check
+}
+
+src_install() {
+       default
+       find "${D}" -name '*.la' -delete || die
+}