dev-python/jupyter: drop py2

Bug: https://bugs.gentoo.org/685040
Signed-off-by: Virgil Dupras <vdupras@gentoo.org>
Package-Manager: Portage-2.3.62, Repoman-2.3.11

diff --git a/dev-python/jupyter/jupyter-1.0.0-r2.ebuild b/dev-python/jupyter/jupyter-1.0.0-r2.ebuild
new file mode 100644 (file)
index 0000000..6083995
--- /dev/null
+++ b/dev-python/jupyter/jupyter-1.0.0-r2.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{5,6} )
+
+inherit distutils-r1
+
+DESCRIPTION="Jupyter metapackage. Install all the Jupyter components in one go"
+HOMEPAGE="https://jupyter.org"
+SRC_URI="
+       mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz
+       https://patch-diff.githubusercontent.com/raw/jupyter/jupyter/pull/198.patch -> ${P}-file-colision.patch
+       "
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc"
+
+RDEPEND="
+       dev-python/notebook[${PYTHON_USEDEP}]
+       dev-python/qtconsole[${PYTHON_USEDEP}]
+       dev-python/jupyter_console[${PYTHON_USEDEP}]
+       dev-python/nbconvert[${PYTHON_USEDEP}]
+       dev-python/ipykernel[${PYTHON_USEDEP}]
+       dev-python/ipywidgets[${PYTHON_USEDEP}]"
+DEPEND="doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )"
+PDEPEND=">=dev-python/jupyter_core-4.2.0[${PYTHON_USEDEP}]"
+
+PATCHES=( "${DISTDIR}"/${P}-file-colision.patch )
+
+python_prepare_all() {
+       # Prevent un-needed download during build
+       if use doc; then
+               sed -e "/^    'sphinx.ext.intersphinx',/d" -i docs/source/conf.py || die
+       fi
+
+       distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+       use doc && emake -C docs html
+}
+
+python_install_all() {
+       use doc && HTML_DOCS=( "${S}"/docs/build/html/. )
+       distutils-r1_python_install_all
+}