media-fonts/intlfonts: Bump to EAPI 7

Bug: https://bugs.gentoo.org/697304
Signed-off-by: Michał Górny <mgorny@gentoo.org>

diff --git a/media-fonts/intlfonts/intlfonts-1.2.1.ebuild b/media-fonts/intlfonts/intlfonts-1.2.1.ebuild
index 8d3c3fe2dc78f352ff1d5ddca7880a9ebb2389c2..2f64bafdef9d5dc710279a59f0d78faea44d7326 100644 (file)
--- a/media-fonts/intlfonts/intlfonts-1.2.1.ebuild
+++ b/media-fonts/intlfonts/intlfonts-1.2.1.ebuild
@@ -1,34 +1,35 @@
 # Copyright 1999-2019 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=0
+EAPI=7
 
 inherit font
 
-IUSE="bdf"
-
 DESCRIPTION="International X11 fixed fonts"
 HOMEPAGE="https://www.gnu.org/directory/intlfonts.html"
 SRC_URI="mirror://gnu/${PN}/${P}.tar.gz"
 
-LICENSE="GPL-2"
-
+LICENSE="freedist"
 SLOT="0"
 KEYWORDS="alpha amd64 arm hppa ia64 ppc ppc64 s390 sh sparc x86"
+IUSE="bdf"
 
 DEPEND="x11-apps/bdftopcf
-               >=x11-apps/mkfontscale-1.2.0"
-RDEPEND=""
+       >=x11-apps/mkfontscale-1.2.0"
+
+DOCS=( ChangeLog NEWS README Emacs.ap )
 
-src_compile() {
-       econf --with-fontdir=/usr/share/fonts/${PN}
+src_configure() {
+       local myconf=(
+               --with-fontdir=/usr/share/fonts/${PN}
+               --enable-compress='gzip -9'
+               $(use_with bdf)
+       )
+       econf "${myconf[@]}"
 }
 
 src_install() {
-       emake install fontdir="${D}/usr/share/fonts/${PN}" || die
-       find "${D}/usr/share/fonts/${PN}" -name '*.pcf' | xargs gzip -9
-       use bdf || rm -rf "${D}/usr/share/fonts/${PN}/bdf"
-       dodoc ChangeLog NEWS README
-       dodoc Emacs.ap
+       emake install fontdir="${ED}/usr/share/fonts/${PN}"
+       einstalldocs
        font_xfont_config
 }