games-simulation/flightgear: Add live ebuilds

diff --git a/dev-games/simgear/simgear-9999.ebuild b/dev-games/simgear/simgear-9999.ebuild
new file mode 100644 (file)
index 0000000..f151217
--- /dev/null
+++ b/dev-games/simgear/simgear-9999.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+CMAKE_WARN_UNUSED_CLI=1
+inherit eutils cmake-utils git-r3
+
+DESCRIPTION="Development library for simulation games"
+HOMEPAGE="http://www.simgear.org/"
+EGIT_REPO_URI="git://git.code.sf.net/p/flightgear/${PN}
+       git://mapserver.flightgear.org/${PN}"
+EGIT_BRANCH="next"
+
+LICENSE="GPL-2"
+KEYWORDS=""
+SLOT="0"
+IUSE="curl debug subversion test"
+
+COMMON_DEPEND="
+       dev-libs/expat
+       >=dev-games/openscenegraph-3.2.0
+       media-libs/openal
+       sys-libs/zlib
+       virtual/opengl
+       curl? ( net-misc/curl )
+"
+DEPEND="${COMMON_DEPEND}
+       >=dev-libs/boost-1.44
+"
+RDEPEND="${COMMON_DEPEND}
+       subversion? ( dev-vcs/subversion )
+"
+
+DOCS=(AUTHORS ChangeLog NEWS README Thanks)
+
+src_configure() {
+       local mycmakeargs=(
+               -DENABLE_CURL=$(usex curl)
+               -DENABLE_PKGUTIL=ON
+               -DENABLE_RTI=OFF
+               -DENABLE_SOUND=ON
+               -DENABLE_TESTS=$(usex test)
+               -DSIMGEAR_HEADLESS=OFF
+               -DSIMGEAR_SHARED=ON
+               -DSYSTEM_EXPAT=ON
+       )
+       cmake-utils_src_configure
+}

diff --git a/games-simulation/flightgear-data/flightgear-data-9999.ebuild b/games-simulation/flightgear-data/flightgear-data-9999.ebuild
new file mode 100644 (file)
index 0000000..e261f2e
--- /dev/null
+++ b/games-simulation/flightgear-data/flightgear-data-9999.ebuild
@@ -0,0 +1,29 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit git-r3
+
+DESCRIPTION="FlightGear data files"
+HOMEPAGE="http://www.flightgear.org/"
+EGIT_REPO_URI="git://git.code.sf.net/p/flightgear/fgdata
+       git://mapserver.flightgear.org/fgdata"
+EGIT_BRANCH="next"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS=""
+IUSE=""
+
+# data files split to separate package since 2.10.0
+RDEPEND="
+       !<games-simulation/flightgear-2.10.0
+"
+
+src_install() {
+       insinto /usr/share/flightgear
+       rm -fr .git
+       doins -r *
+}

diff --git a/games-simulation/flightgear/flightgear-9999.ebuild b/games-simulation/flightgear/flightgear-9999.ebuild
new file mode 100644 (file)
index 0000000..2d73c20
--- /dev/null
+++ b/games-simulation/flightgear/flightgear-9999.ebuild
@@ -0,0 +1,134 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+CMAKE_WARN_UNUSED_CLI=1
+inherit cmake-utils bash-completion-r1 git-r3
+
+DESCRIPTION="Open Source Flight Simulator"
+HOMEPAGE="http://www.flightgear.org/"
+EGIT_REPO_URI="git://git.code.sf.net/p/${PN}/${PN}
+       git://mapserver.flightgear.org/${PN}"
+EGIT_BRANCH="next"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS=""
+IUSE="dbus debug examples qt5 test +udev +utils vim-syntax"
+
+COMMON_DEPEND="
+       dev-db/sqlite:3
+       >=dev-games/openscenegraph-3.2.0[png]
+       ~dev-games/simgear-${PV}
+       media-libs/openal
+       media-libs/speex
+       media-sound/gsm
+       sys-libs/zlib
+       x11-libs/libX11
+       dbus? ( >=sys-apps/dbus-1.6.18-r1 )
+       qt5? (
+               >=dev-qt/qtcore-5.4.1:5
+               >=dev-qt/qtgui-5.4.1:5
+               >=dev-qt/qtwidgets-5.4.1:5
+       )
+       udev? ( virtual/udev )
+       utils? (
+               media-libs/freeglut
+               media-libs/libpng:0
+               virtual/opengl
+       )
+"
+DEPEND="${COMMON_DEPEND}
+       >=dev-libs/boost-1.44
+       >=media-libs/plib-1.8.5
+"
+RDEPEND="${COMMON_DEPEND}
+       ~games-simulation/${PN}-data-${PV}
+"
+
+DOCS=(AUTHORS ChangeLog NEWS README Thanks)
+
+src_configure() {
+       local mycmakeargs=(
+               -DENABLE_FGCOM=$(usex utils)
+               -DENABLE_FGELEV=$(usex utils)
+               -DENABLE_FGJS=$(usex utils)
+               -DENABLE_FGVIEWER=$(usex utils)
+               -DENABLE_FLITE=OFF
+               -DENABLE_GPSSMOOTH=$(usex utils)
+               -DENABLE_JS_DEMO=$(usex utils)
+               -DENABLE_JSBSIM=ON
+               -DENABLE_LARCSIM=ON
+               -DENABLE_LOGGING=$(usex test)
+               -DENABLE_METAR=$(usex utils)
+               -DENABLE_PROFILE=OFF
+               -DENABLE_QT=$(usex qt5)
+               -DENABLE_RTI=OFF
+               -DENABLE_TERRASYNC=$(usex utils)
+               -DENABLE_TESTS=$(usex test)
+               -DENABLE_UIUC_MODEL=ON
+               -DENABLE_YASIM=ON
+               -DEVENT_INPUT=$(usex udev)
+               -DFG_DATA_DIR=/usr/share/${PN}
+               -DJSBSIM_TERRAIN=ON
+               -DSIMGEAR_SHARED=ON
+               -DSP_FDMS=ON
+               -DSYSTEM_FLITE=ON
+               -DSYSTEM_HTS_ENGINE=ON
+               -DSYSTEM_SPEEX=ON
+               -DSYSTEM_GSM=ON
+               -DSYSTEM_SQLITE=ON
+               -DUSE_DBUS=$(usex dbus)
+               -DWITH_FGPANEL=$(usex utils)
+       )
+
+       cmake-utils_src_configure
+}
+
+src_install() {
+       cmake-utils_src_install
+
+       # Install icons and menu entry
+       local s
+       for s in 16 22 24 32 48 64 128; do
+               doicon -s ${s} icons/${s}x${s}/apps/${PN}.png
+               use utils && doicon -s ${s} icons/${s}x${s}/apps/fgcom.png
+       done
+       doicon -s scalable icons/scalable/${PN}.svg
+       use utils && doicon -s scalable icons/scalable/fgcom.svg
+
+       newmenu package/${PN}.desktop ${PN}.desktop
+
+       # Install bash completion (TODO zsh)
+       # Uncomment below when scripts stops writing files...
+#      sed -e "s|/usr/local/share/FlightGear|${GAMES_DATADIR}/${PN}|" \
+#              -i scripts/completion/fg-completion.bash || die 'unable to replace FG_ROOT'
+#      newbashcomp scripts/completion/fg-completion.bash ${PN}
+
+       # Install examples and other misc files
+       if use examples; then
+               insinto /usr/share/doc/"${PF}"/examples
+               doins -r scripts/java scripts/perl scripts/python
+               insinto /usr/share/doc/"${PF}"/examples/c++
+               doins -r scripts/example/*
+               insinto /usr/share/doc/"${PF}"/tools
+               doins -r scripts/atis scripts/tools/*
+       fi
+
+       # Install nasal script syntax
+       if use vim-syntax; then
+               insinto /usr/share/vim/vimfiles/syntax
+               doins scripts/syntax/{ac3d,nasal}.vim
+               insinto /usr/share/vim/vimfiles/ftdetect/
+               doins "${FILESDIR}"/{ac3d,nasal}.vim
+       fi
+}
+
+pkg_postinst() {
+       einfo "Please note that data files location changed to /usr/share/flightgear"
+       if use qt5; then
+               einfo "To use launcher, run fgfs with '--launcher' parameter"
+       fi
+}