net-wireless/aircrack-ng: simple bump

python 3.x work is ongoing, stand by

Package-Manager: Portage-2.3.85, Repoman-2.3.20
Signed-off-by: Rick Farina <zerochaos@gentoo.org>

diff --git a/net-wireless/aircrack-ng/Manifest b/net-wireless/aircrack-ng/Manifest
index b5f3291b13df3aa5bd4205c2cb68eb8c66cfabf9..c2c34db38b50553ac666e7f7076d2b9e69dee880 100644 (file)
--- a/net-wireless/aircrack-ng/Manifest
+++ b/net-wireless/aircrack-ng/Manifest
@@ -1 +1,2 @@
 DIST aircrack-ng-1.5.2.tar.gz 7138360 BLAKE2B cfc178d76273bb1cf6c34b1656a710d046a094f9c772a562f19ae783c30810cf7b6aa8668566ef6998af79090266771aeea8037b446eb0b9755b602ddcebc0d2 SHA512 72c249782dda3a875fbec98e4fe0e6044a6f123ebd36341a5f42733dfe6c26d96b5c74f67c0547b81c5dd5e2f52a6f475b424885f8e6fa21279ac539228038f5
+DIST aircrack-ng-1.6.tar.gz 7933308 BLAKE2B c4cacdc9b767789a7b2426857831c1f8166d3f2e11a71cffc1466f2d4006552dfe420a50e0085f3c74fbdc23770309bb81d49e0c5372b0e4a8fa5e294c16d942 SHA512 df65ec3032ff20dc4aae4921e6a9c330a51b5df89af02d4c6fbf691fcfade21658b1a2d5de286a7e729dc6fb740f6fd4e6b6f53649486ef64bc3d00d81a95bd5

diff --git a/net-wireless/aircrack-ng/aircrack-ng-1.6.ebuild b/net-wireless/aircrack-ng/aircrack-ng-1.6.ebuild
new file mode 100644 (file)
index 0000000..69db574
--- /dev/null
+++ b/net-wireless/aircrack-ng/aircrack-ng-1.6.ebuild
@@ -0,0 +1,119 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+# Upstream aircrack-ng supports python 3.x but lorcon doesn't yet and
+# it is needed for airdrop-ng. Will adjust when ready.
+#PYTHON_COMPAT=( python2_7 python3_{6,7,8})
+PYTHON_COMPAT=( python2_7 )
+DISTUTILS_OPTIONAL=1
+
+inherit toolchain-funcs distutils-r1 flag-o-matic autotools
+
+DESCRIPTION="WLAN tools for breaking 802.11 WEP/WPA keys"
+HOMEPAGE="http://www.aircrack-ng.org"
+
+if [[ ${PV} == "9999" ]] ; then
+       inherit git-r3
+       EGIT_REPO_URI="https://github.com/aircrack-ng/aircrack-ng.git"
+else
+       MY_PV=${PV/_/-}
+       SRC_URI="https://download.aircrack-ng.org/${P}.tar.gz"
+       KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~x86 ~amd64-linux ~x86-linux"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+
+IUSE="+airdrop-ng +airgraph-ng kernel_linux kernel_FreeBSD libressl +netlink +pcre +sqlite +experimental"
+
+DEPEND="net-libs/libpcap
+       sys-apps/hwloc:0=
+       !libressl? ( dev-libs/openssl:0= )
+       libressl? ( dev-libs/libressl:0= )
+       netlink? ( dev-libs/libnl:3 )
+       pcre? ( dev-libs/libpcre )
+       airdrop-ng? ( ${PYTHON_DEPS} )
+       airgraph-ng? ( ${PYTHON_DEPS} )
+       experimental? ( sys-libs/zlib )
+       sqlite? ( >=dev-db/sqlite-3.4 )"
+RDEPEND="${DEPEND}"
+PDEPEND="kernel_linux? (
+               net-wireless/iw
+               net-wireless/wireless-tools
+               sys-apps/ethtool
+               sys-apps/usbutils
+               sys-apps/pciutils )
+       sys-apps/hwids
+       airdrop-ng? ( net-wireless/lorcon[python,${PYTHON_USEDEP}] )"
+
+REQUIRED_USE="
+       airdrop-ng? ( ${PYTHON_REQUIRED_USE} )
+       airgraph-ng? ( ${PYTHON_REQUIRED_USE} )"
+
+src_prepare() {
+       default
+       eautoreconf
+}
+
+src_configure() {
+       econf \
+               STATIC_LIBDIR_NAME="$(get_libdir)" \
+               --disable-asan \
+               --enable-shared \
+               --disable-static \
+               --without-opt \
+               $(use_enable netlink libnl) \
+               $(use_with experimental) \
+               $(use_with sqlite sqlite3)
+}
+
+src_compile() {
+       if [[ $($(tc-getCC) --version) == clang* ]] ; then
+               #https://bugs.gentoo.org/show_bug.cgi?id=472890
+               filter-flags -frecord-gcc-switches
+       fi
+
+       default
+
+       if use airgraph-ng; then
+               cd "${S}/scripts/airgraph-ng"
+               distutils-r1_src_compile
+       fi
+       if use airdrop-ng; then
+               cd "${S}/scripts/airdrop-ng"
+               distutils-r1_src_compile
+       fi
+}
+
+src_install() {
+       default
+
+       if use airgraph-ng; then
+               cd "${S}/scripts/airgraph-ng"
+               distutils-r1_src_install
+       fi
+       if use airdrop-ng; then
+               cd "${S}/scripts/airdrop-ng"
+               distutils-r1_src_install
+       fi
+
+       # we don't need aircrack-ng's oui updater, we have our own
+       rm "${ED}"/usr/sbin/airodump-ng-oui-update
+}
+
+pkg_postinst() {
+       # Message is (c) FreeBSD
+       # http://www.freebsd.org/cgi/cvsweb.cgi/ports/net-mgmt/aircrack-ng/files/pkg-message.in?rev=1.5
+       if use kernel_FreeBSD ; then
+               einfo "Contrary to Linux, it is not necessary to use airmon-ng to enable the monitor"
+               einfo "mode of your wireless card.  So do not care about what the manpages say about"
+               einfo "airmon-ng, airodump-ng sets monitor mode automatically."
+               echo
+               einfo "To return from monitor mode, issue the following command:"
+               einfo "    ifconfig \${INTERFACE} -mediaopt monitor"
+               einfo
+               einfo "For aireplay-ng you need FreeBSD >= 7.0."
+       fi
+}

diff --git a/net-wireless/aircrack-ng/aircrack-ng-9999.ebuild b/net-wireless/aircrack-ng/aircrack-ng-9999.ebuild
index 5f518aa661d162cec6091bc6fa5fb52d66818cfb..fa7cdd3ca822d7c82f0380189b1ad0adece78718 100644 (file)
--- a/net-wireless/aircrack-ng/aircrack-ng-9999.ebuild
+++ b/net-wireless/aircrack-ng/aircrack-ng-9999.ebuild
@@ -17,7 +17,7 @@ if [[ ${PV} == "9999" ]] ; then
 else
        MY_PV=${PV/_/-}
        SRC_URI="https://download.aircrack-ng.org/${P}.tar.gz"
-       KEYWORDS="~amd64 ~arm ~ppc ~x86 ~amd64-linux ~x86-linux"
+       KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~x86 ~amd64-linux ~x86-linux"
 fi
 
 LICENSE="GPL-2"