www-client/opera-beta: Version bump.

Package-Manager: Portage-2.3.8, Repoman-2.3.3

diff --git a/www-client/opera-beta/Manifest b/www-client/opera-beta/Manifest
index c00c7a9ea28eeb66258df0ed8203ecb660207243..4d345ff9dd63e6e0738552c4c725a03b09be1719 100644 (file)
--- a/www-client/opera-beta/Manifest
+++ b/www-client/opera-beta/Manifest
@@ -1 +1,2 @@
 DIST opera-beta_47.0.2631.34_amd64.deb 50158936 SHA256 fc4e70cf8cb669cb08dc4e2086a788f5f1ec88d963a94faf0daa73b713ae8d6f SHA512 eff13d5be2ba626f355d72ba65c40a14732d31f74a97cb5e7930251180d52cb7e92829ff0d3481995b0247b21c9f5a342f55a594cc42fd42da1fa423b1f06e08 WHIRLPOOL e3034c0b6de10449e6a31ee7ced81b7ba70d43a7ad5afb52071dfce4e52ea1ec0a0ce28b3fc8ef518d407955d40397964bc48b2efbdcf928bc63e1ac113a5a83
+DIST opera-beta_48.0.2685.7_amd64.deb 50257470 SHA256 cec4ebc868ff36d369ea159fd901e4a8f0518751d03ccfe9b3469ae9e4e75d7c SHA512 cee7eca4925a2352c7da159777d096dfce904c294e4d61bd1c18bc484534aba581c181c377db11a6c2ac1883dd01a3d2ba5692b1e6c2bc4409aa716836baf41b WHIRLPOOL 959b272e9b28cb79d344b117f83d041e351a187740d5158a4b88b40e30465d8519c78ee242e7f84656d9c20e8f447ef5af322205bb06f9b1596b7f804f323d31

diff --git a/www-client/opera-beta/opera-beta-48.0.2685.7.ebuild b/www-client/opera-beta/opera-beta-48.0.2685.7.ebuild
new file mode 100644 (file)
index 0000000..b72074e
--- /dev/null
+++ b/www-client/opera-beta/opera-beta-48.0.2685.7.ebuild
@@ -0,0 +1,89 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+CHROMIUM_LANGS="
+       be bg bn ca cs da de el en-GB es-419 es fil fi fr-CA fr he hi hr hu id it
+       ja ko lt lv ms nb nl pl pt-BR pt-PT ro ru sk sr sv sw ta te th tr uk vi
+       zh-CN zh-TW
+"
+inherit chromium-2 multilib unpacker
+
+DESCRIPTION="A fast and secure web browser"
+HOMEPAGE="http://www.opera.com/"
+LICENSE="OPERA-2014"
+SLOT="0"
+SRC_URI_BASE="http://get.geo.opera.com/pub/"
+SRC_URI="
+       amd64?  ( "${SRC_URI_BASE}${PN}/${PV}/linux/${PN}_${PV}_amd64.deb" )
+"
+KEYWORDS="~amd64"
+
+RDEPEND="
+       dev-libs/expat
+       dev-libs/glib:2
+       dev-libs/nspr
+       dev-libs/nss
+       gnome-base/gconf:2
+       media-libs/alsa-lib
+       media-libs/fontconfig
+       media-libs/freetype
+       net-misc/curl
+       net-print/cups
+       sys-apps/dbus
+       x11-libs/cairo
+       x11-libs/gdk-pixbuf
+       x11-libs/gtk+:2
+       x11-libs/libX11
+       x11-libs/libXScrnSaver
+       x11-libs/libXcomposite
+       x11-libs/libXcursor
+       x11-libs/libXdamage
+       x11-libs/libXext
+       x11-libs/libXfixes
+       x11-libs/libXi
+       x11-libs/libXrandr
+       x11-libs/libXrender
+       x11-libs/libXtst
+       x11-libs/libnotify
+       x11-libs/pango[X]
+"
+
+QA_PREBUILT="*"
+S=${WORKDIR}
+OPERA_HOME="usr/$(get_libdir)/${PN}"
+
+src_unpack() {
+       unpack_deb ${A}
+}
+
+src_prepare() {
+       case ${ARCH} in
+               amd64)
+                       mv usr/lib/x86_64-linux-gnu usr/$(get_libdir) || die
+                       rm -r usr/lib || die
+                       ;;
+               x86)
+                       mv usr/lib/i386-linux-gnu/${PN} usr/$(get_libdir)/ || die
+                       ;;
+       esac
+
+       rm usr/bin/${PN} || die
+
+       rm usr/share/doc/${PN}/copyright || die
+       mv usr/share/doc/${PN} usr/share/doc/${PF} || die
+
+       pushd "${OPERA_HOME}/localization" > /dev/null || die
+       chromium_remove_language_paks
+       popd > /dev/null || die
+
+       sed -i \
+               -e 's|^TargetEnvironment|X-&|g' \
+               usr/share/applications/${PN}.desktop || die
+}
+
+src_install() {
+       mv * "${D}" || die
+       dosym ../$(get_libdir)/${PN}/${PN} /usr/bin/${PN}
+       fperms 4711 /usr/$(get_libdir)/${PN}/opera_sandbox
+}