media-libs/libplacebo: update to v2.43.0

This includes a new USE flag, for the OpenGL support added in this
version of libplacebo. We bump up the test timeout because the OpenGL
tests can take a while to execute, especially on machines where they're
running via llvmpipe or swrast.

Also synchronize the live ebuild.

Signed-off-by: Niklas Haas <git@haasn.xyz>
Closes: https://github.com/gentoo/gentoo/pull/15465
Signed-off-by: Georgy Yakovlev <gyakovlev@gentoo.org>

diff --git a/media-libs/libplacebo/Manifest b/media-libs/libplacebo/Manifest
index a268003a36286e51a41f8c8eb7985794a23c0081..08b8aa7b6d9001ac99e0973a00070e6de8ea36aa 100644 (file)
--- a/media-libs/libplacebo/Manifest
+++ b/media-libs/libplacebo/Manifest
@@ -1,2 +1,3 @@
 DIST libplacebo-v1.21.0.tar.gz 326918 BLAKE2B fe9500de23487d7d5dfc51d9f94dd3d33d22bdac3005fc3334814c53a76a46cebd40655675b5172f058d02dd865385a993b3c52a863b9e9b32ac0bc4801e0126 SHA512 5de95b8cc48ba4ec9bc3afb8c8f2c4fae0d53ce6e69ffb53884c3a3ee2580998bae46b8934e462740b6c9c2e66e3c5d5f009f9b0f8ad2cb7b4fba829891cf333
 DIST libplacebo-v1.29.1.tar.gz 330673 BLAKE2B 3094f167afb45097ef6e494d7f6f6d61b7ee4ed00bab9f1d33bfd27b032020489eb43005a30a44934416dc52577eb7fc66baf367fdfda71652e97214d87023df SHA512 9f09560832a88e670d6c31e9f5b9cbc03de437bfb19ceb0985140307b5cdf20e2050a1dab5d07f18258dfa3e5429a51f1d3d54532099be4bfc6a0dafe3ffd516
+DIST libplacebo-v2.43.0.tar.gz 356219 BLAKE2B b5f36dc4b7a0b35a47efc64064d0d7e9cf023dea2974fe355d29a6c835efa67b6f50ec500fa3ce50b932fef5d035a470f0adc8377cd274c5904fb4ffc303bb0c SHA512 c57463a9fcde1b259620fcb7ce6470b0d06e45ed837b4eca35ff0931e4c440ef613590485119ed21237f9cf3c3cdb617253f17699d9d252070f30d5dcbc233ab

diff --git a/media-libs/libplacebo/libplacebo-2.43.0.ebuild b/media-libs/libplacebo/libplacebo-2.43.0.ebuild
new file mode 100644 (file)
index 0000000..b0088da
--- /dev/null
+++ b/media-libs/libplacebo/libplacebo-2.43.0.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+if [[ "${PV}" == "9999" ]]; then
+       EGIT_REPO_URI="https://code.videolan.org/videolan/libplacebo.git"
+       inherit git-r3
+else
+       KEYWORDS="~amd64 ~ppc64 ~x86"
+       SRC_URI="https://code.videolan.org/videolan/libplacebo/-/archive/v${PV}/libplacebo-v${PV}.tar.gz"
+       S="${WORKDIR}/${PN}-v${PV}"
+fi
+
+inherit meson multilib-minimal
+
+DESCRIPTION="Reusable library for GPU-accelerated image processing primitives"
+HOMEPAGE="https://github.com/haasn/libplacebo"
+
+LICENSE="LGPL-2.1+"
+SLOT="0/$(ver_cut 2)" # libplacebo.so version
+IUSE="glslang lcms +opengl +shaderc test +vulkan"
+REQUIRED_USE="vulkan? ( || ( glslang shaderc ) )"
+
+RDEPEND="glslang? ( dev-util/glslang[${MULTILIB_USEDEP}] )
+       lcms? ( media-libs/lcms:2[${MULTILIB_USEDEP}] )
+       opengl? ( media-libs/libepoxy[${MULTILIB_USEDEP}] )
+       shaderc? ( >=media-libs/shaderc-2017.2[${MULTILIB_USEDEP}] )
+       vulkan? ( media-libs/vulkan-loader[${MULTILIB_USEDEP}] )"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+RESTRICT="!test? ( test )"
+
+multilib_src_configure() {
+       local emesonargs=(
+               $(meson_feature glslang)
+               $(meson_feature lcms)
+               $(meson_feature opengl)
+               $(meson_feature shaderc)
+               $(meson_feature vulkan)
+               $(meson_use test tests)
+       )
+       meson_src_configure
+}
+
+multilib_src_compile() {
+       meson_src_compile
+}
+
+multilib_src_test() {
+       meson_src_test -t 10
+}
+
+multilib_src_install() {
+       meson_src_install
+}

diff --git a/media-libs/libplacebo/libplacebo-9999.ebuild b/media-libs/libplacebo/libplacebo-9999.ebuild
index 53dde3ad005ee4c807bf0003bda1418b67f930c9..1c2ef2ff86ae51bca908d82aaf3781e43de9f8af 100644 (file)
--- a/media-libs/libplacebo/libplacebo-9999.ebuild
+++ b/media-libs/libplacebo/libplacebo-9999.ebuild
@@ -7,7 +7,7 @@ if [[ "${PV}" == "9999" ]]; then
        EGIT_REPO_URI="https://code.videolan.org/videolan/libplacebo.git"
        inherit git-r3
 else
-       KEYWORDS="~amd64 ~ppc64"
+       KEYWORDS="~amd64 ~ppc64 ~x86"
        SRC_URI="https://code.videolan.org/videolan/libplacebo/-/archive/v${PV}/libplacebo-v${PV}.tar.gz"
        S="${WORKDIR}/${PN}-v${PV}"
 fi
@@ -20,11 +20,12 @@ HOMEPAGE="https://github.com/haasn/libplacebo"
 LICENSE="LGPL-2.1+"
 # Please add a sub-slot for releases depending on libplacebo.so version
 SLOT="0"
-IUSE="glslang lcms +shaderc test +vulkan"
+IUSE="glslang lcms +opengl +shaderc test +vulkan"
 REQUIRED_USE="vulkan? ( || ( glslang shaderc ) )"
 
 RDEPEND="glslang? ( dev-util/glslang[${MULTILIB_USEDEP}] )
        lcms? ( media-libs/lcms:2[${MULTILIB_USEDEP}] )
+       opengl? ( media-libs/libepoxy[${MULTILIB_USEDEP}] )
        shaderc? ( >=media-libs/shaderc-2017.2[${MULTILIB_USEDEP}] )
        vulkan? ( media-libs/vulkan-loader[${MULTILIB_USEDEP}] )"
 DEPEND="${RDEPEND}"
@@ -36,6 +37,7 @@ multilib_src_configure() {
        local emesonargs=(
                $(meson_feature glslang)
                $(meson_feature lcms)
+               $(meson_feature opengl)
                $(meson_feature shaderc)
                $(meson_feature vulkan)
                $(meson_use test tests)
@@ -48,7 +50,7 @@ multilib_src_compile() {
 }
 
 multilib_src_test() {
-       meson_src_test
+       meson_src_test -t 10
 }
 
 multilib_src_install() {