dev-python/automat: Bump to 20.2.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

diff --git a/dev-python/automat/Manifest b/dev-python/automat/Manifest
index 1cb5e1e7e877351ade72fd25230d13bc4d3ef879..5ed71454031ed8b31487786aa51fa4db4f6235e7 100644 (file)
--- a/dev-python/automat/Manifest
+++ b/dev-python/automat/Manifest
@@ -1 +1,2 @@
 DIST Automat-0.8.0.tar.gz 59687 BLAKE2B 56e4ec76564d321ca9a709c484077a4003eea2842160e226728aaaa4ec6ebc2486482f79cd919bef7bbec8baeee7a34ca2a11d48665bb36c79c5a45a3c97e992 SHA512 2dbd4e784f65b02a8c93fc5f15236df3649d667a9792f6cac929dbac5d971495bdab4825df0fcd6817b9a9f79b7a5d8cfbdf8e4d18605f0761546b31b3091ad7
+DIST Automat-20.2.0.tar.gz 61679 BLAKE2B 9dfb93a0bf0a348d8f7de0796b3e5715947eb84cc0aa507a453f438d2027ae877280ed6d7896192cee46f31c7d1c0eb6cb3dee36e1f13a315071513920c5b6d0 SHA512 715cb5dc087288492e6465a29e7d8502a84fadf451bc3d29da86335ea1c20f8efd9549f0c1eaac8800559dd8001dd73736c3bfacdc6321c83a35d2288d69632c

diff --git a/dev-python/automat/automat-20.2.0.ebuild b/dev-python/automat/automat-20.2.0.ebuild
new file mode 100644 (file)
index 0000000..d07dff7
--- /dev/null
+++ b/dev-python/automat/automat-20.2.0.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python2_7 python3_{6..9} pypy3 )
+DISTUTILS_USE_SETUPTOOLS=rdepend
+
+inherit distutils-r1
+
+MY_PN="A${PN:1}"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Self-service finite-state machines for the programmer on the go"
+HOMEPAGE="https://github.com/glyph/automat https://pypi.org/project/Automat/"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="examples"
+
+RDEPEND="
+       >=dev-python/attrs-19.2.0[${PYTHON_USEDEP}]
+       dev-python/six[${PYTHON_USEDEP}]
+"
+BDEPEND="
+       ${RDEPEND}
+       dev-python/m2r[${PYTHON_USEDEP}]
+"
+
+S="${WORKDIR}/${MY_P}"
+
+PATCHES=(
+       "${FILESDIR}/automat-0.8.0-no-setup-py-m2r-import.patch"
+)
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+       if use test ; then
+               # Remove since this is upstream benchmarking tests
+               rm -r benchmark || die "FAILED to remove benchmark tests"
+       fi
+
+       # avoid a setuptools_scm dependency
+       sed -r -i "s:use_scm_version=True:version='${PV}': ;
+               s:[\"']setuptools[_-]scm[\"'](,|)::" setup.py || die
+
+       distutils-r1_python_prepare_all
+}
+
+python_install_all() {
+       if use examples; then
+               docinto examples
+               dodoc docs/examples/*.py
+       fi
+
+       distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+       einfo "For additional visualization functionality install these optional dependencies"
+       einfo "    >=dev-python/twisted-16.1.1"
+       einfo "    media-gfx/graphviz[python]"
+}