dev-db/tora: Switch to +postgres default, drop obsolete warning

Thanks-to: Sergey S. Starikoff <Ikonta@yandex.ru>
Closes: https://bugs.gentoo.org/645242
Package-Manager: Portage-2.3.41, Repoman-2.3.9

diff --git a/dev-db/tora/tora-3.2-r1.ebuild b/dev-db/tora/tora-3.2-r1.ebuild
new file mode 100644 (file)
index 0000000..dd82fa3
--- /dev/null
+++ b/dev-db/tora/tora-3.2-r1.ebuild
@@ -0,0 +1,93 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit cmake-utils eutils xdg-utils
+
+if [[ ${PV} == 9999 ]]; then
+       EGIT_REPO_URI="https://github.com/tora-tool/tora"
+       inherit git-r3
+else
+       SRC_URI="https://github.com/tora-tool/tora/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+       KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="SQL IDE for Oracle, MySQL and PostgreSQL dbs"
+HOMEPAGE="https://github.com/tora-tool/tora/wiki"
+IUSE="doc mysql oracle +postgres"
+REQUIRED_USE="|| ( mysql oracle postgres )"
+
+SLOT="0"
+LICENSE="GPL-2"
+
+RDEPEND="
+       dev-libs/ferrisloki
+       dev-qt/qtcore:5
+       dev-qt/qtgui:5
+       dev-qt/qtnetwork:5
+       dev-qt/qtprintsupport:5
+       dev-qt/qtsql:5[mysql?,postgres?]
+       dev-qt/qtwidgets:5
+       >=x11-libs/qscintilla-2.10.1:=[qt5(+)]
+       oracle? ( || ( =dev-db/oracle-instantclient-basic-11* dev-db/oracle-instantclient ) )
+       postgres? ( dev-db/postgresql:* )
+"
+DEPEND="${RDEPEND}
+       dev-qt/linguist:5
+       virtual/pkgconfig
+       doc? ( app-doc/doxygen )
+"
+
+PATCHES=( "${FILESDIR}/${P}-missing-header.patch" )
+
+src_prepare() {
+       cmake-utils_src_prepare
+
+       # fixed in master, only care about recent qscintilla lib name:
+       sed -e "/FIND_LIBRARY(QSCINTILLA_LIBRARY/s/qt5scintilla2/qscintilla2_qt5/" \
+               -i cmake/modules/FindQScintilla.cmake || die "Failed to fix FindQScintilla.cmake"
+
+       rm -r extlibs/{loki,qscintilla2} || die # ferrisloki, bug #383109
+
+       sed -e "/COPYING/ d" \
+               -i CMakeLists.txt || die "Removal of COPYING file failed"
+
+       # bug 547520
+       grep -rlZ '$$ORIGIN' . | xargs -0 sed -i 's|:$$ORIGIN[^:"]*||' || \
+               die 'Removal of $$ORIGIN failed'
+}
+
+src_configure() {
+       local mycmakeargs=(
+               -DENABLE_DB2=OFF
+               -DQT5_BUILD=ON
+               -DWANT_INTERNAL_LOKI=OFF
+               -DWANT_INTERNAL_QSCINTILLA=OFF
+               -DWANT_RPM=OFF
+               -DLOKI_LIBRARY="$(pkg-config --variable=libdir ferrisloki)/libferrisloki.so"
+               -DLOKI_INCLUDE_DIR="$(pkg-config --variable=includedir ferrisloki)/FerrisLoki"
+               $(cmake-utils_use_find_package doc Doxygen)
+               -DENABLE_ORACLE=$(usex oracle)
+               -DUSE_PCH=OFF
+               -DENABLE_PGSQL=$(usex postgres)
+       )
+       cmake-utils_src_configure
+}
+
+src_install() {
+       cmake-utils_src_install
+
+       doicon src/icons/${PN}.xpm || die
+       domenu src/${PN}.desktop || die
+}
+
+pkg_postinst() {
+       xdg_mimeinfo_database_update
+       xdg_desktop_database_update
+}
+
+pkg_postrm() {
+       xdg_mimeinfo_database_update
+       xdg_desktop_database_update
+}

diff --git a/dev-db/tora/tora-9999.ebuild b/dev-db/tora/tora-9999.ebuild
index 41ee84ac7f54c67702b5610b40d7825c6711b190..2f79f2291a8144cbe841be2bb1aef7317e70df56 100644 (file)
--- a/dev-db/tora/tora-9999.ebuild
+++ b/dev-db/tora/tora-9999.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2017 Gentoo Foundation
+# Copyright 1999-2018 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=6
@@ -15,7 +15,8 @@ fi
 
 DESCRIPTION="SQL IDE for Oracle, MySQL and PostgreSQL dbs"
 HOMEPAGE="https://github.com/tora-tool/tora/wiki"
-IUSE="doc mysql oracle pch postgres"
+IUSE="doc mysql oracle pch +postgres"
+REQUIRED_USE="|| ( mysql oracle postgres )"
 
 SLOT="0"
 LICENSE="GPL-2"
@@ -29,7 +30,7 @@ RDEPEND="
        dev-qt/qtsql:5[mysql?,postgres?]
        dev-qt/qtwidgets:5
        >=x11-libs/qscintilla-2.10.1:=[qt5(+)]
-       oracle? ( =dev-db/oracle-instantclient-basic-11* )
+       oracle? ( || ( =dev-db/oracle-instantclient-basic-11* dev-db/oracle-instantclient ) )
        postgres? ( dev-db/postgresql:* )
 "
 DEPEND="${RDEPEND}
@@ -38,19 +39,6 @@ DEPEND="${RDEPEND}
        doc? ( app-doc/doxygen )
 "
 
-pkg_setup() {
-       if use oracle && [[ -z "$ORACLE_HOME" ]]; then
-               eerror "ORACLE_HOME variable is not set."
-               eerror
-               eerror "You must install Oracle >= 8i client for Linux in"
-               eerror "order to compile TOra with Oracle support."
-               eerror
-               eerror "You can download the Oracle software from"
-               eerror "http://www.oracle.com/technetwork/database/features/instant-client/index.html"
-               die
-       fi
-}
-
 src_prepare() {
        cmake-utils_src_prepare