dev-libs/libgusb: bump to 0.3.1

Closes: https://bugs.gentoo.org/698154
Package-Manager: Portage-2.3.82, Repoman-2.3.20
Signed-off-by: Jason A. Donenfeld <zx2c4@gentoo.org>

diff --git a/dev-libs/libgusb/Manifest b/dev-libs/libgusb/Manifest
index bdddc3e42bc686baf9828f2b97007315f72746ec..197f5f0b19662c4f9b946bb7a1cd30ea8c99e31c 100644 (file)
--- a/dev-libs/libgusb/Manifest
+++ b/dev-libs/libgusb/Manifest
@@ -1 +1,2 @@
 DIST libgusb-0.2.11.tar.xz 291992 BLAKE2B f43065fac0fcfbc3e392b90dc05537746ce1325d623161e93e1a306b87b07012ef4e11242514cd3da0b83a7df6adc052e20fd3336b53d2543ed9e23886a776f5 SHA512 f9c3c204b5f0feaf706b23dd9a174feb36a9f3c8db8ffb5dcdefa66b18ba0ac963c6041d2d91a6a2f6e23036fc6486d142210bd5348e10c026a6defeb0bee096
+DIST libgusb-0.3.1.tar.xz 38568 BLAKE2B d09afae9d210fde1411de5a0b9b8852eef49f88558ff4c434ef5f2ed9c1c6c29600b96dad73f6873027c5ce0987a3fd99691ffd97d90cfba9f63fbb2cc73f8cd SHA512 5c864e35ec64d1e52ec15ab971c75e0ee3e4664223a6b365815a54819f23342889e5f9739b998799a3af3d37ee75f0ae38ee0d8bca4ed1e2d6ff712f65a53b9a

diff --git a/dev-libs/libgusb/libgusb-0.3.1.ebuild b/dev-libs/libgusb/libgusb-0.3.1.ebuild
new file mode 100644 (file)
index 0000000..b0e759e
--- /dev/null
+++ b/dev-libs/libgusb/libgusb-0.3.1.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+VALA_USE_DEPEND="vapigen"
+
+inherit meson multilib-minimal vala
+
+DESCRIPTION="GObject wrapper for libusb"
+HOMEPAGE="https://github.com/hughsie/libgusb"
+SRC_URI="https://people.freedesktop.org/~hughsient/releases/${P}.tar.xz"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86"
+
+IUSE="gtk-doc +introspection static-libs test vala"
+REQUIRED_USE="vala? ( introspection )"
+
+RDEPEND="
+       >=dev-libs/glib-2.44:2[${MULTILIB_USEDEP}]
+       virtual/libusb:1[udev,${MULTILIB_USEDEP}]
+       introspection? ( >=dev-libs/gobject-introspection-1.54:= )
+       sys-apps/hwids
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+       gtk-doc? (
+               app-text/docbook-xml-dtd:4.1.2
+               app-text/docbook-xml-dtd:4.4
+               dev-util/gtk-doc
+       )
+       vala? ( $(vala_depend) )
+       virtual/pkgconfig[${MULTILIB_USEDEP}]
+"
+
+RESTRICT="!test? ( test )"
+
+src_prepare() {
+       use vala && vala_src_prepare
+       default
+}
+
+multilib_src_configure() {
+       local emesonargs=(
+               -Ddefault_library=$(usex static-libs both shared)
+               $(meson_use test tests)
+               -Dvapi=$(multilib_native_usex vala true false)
+               -Dusb_ids="${EPREFIX}"/usr/share/misc/usb.ids
+               -Ddocs=$(multilib_native_usex gtk-doc true false)
+               -Dintrospection=$(multilib_native_usex introspection true false)
+       )
+       meson_src_configure
+}
+
+multilib_src_compile() {
+       meson_src_compile
+}
+
+multilib_src_test() {
+       meson_src_test
+}
+
+multilib_src_install() {
+       meson_src_install
+}