Add new version for Gnome 2.30

Package-Manager: portage-2.1.8.3/cvs/Linux x86_64

diff --git a/gnome-base/libgnome/ChangeLog b/gnome-base/libgnome/ChangeLog
index 75eaa823c69c46af1259d3ba9261833bdf77a448..9022b7356bd4e27cea59b0518ea94941afef5635 100644 (file)
--- a/gnome-base/libgnome/ChangeLog
+++ b/gnome-base/libgnome/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for gnome-base/libgnome
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-base/libgnome/ChangeLog,v 1.189 2010/06/04 20:45:34 maekke Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-base/libgnome/ChangeLog,v 1.190 2010/06/13 16:37:05 pacho Exp $
+
+*libgnome-2.30.0 (13 Jun 2010)
+
+  13 Jun 2010; Pacho Ramos <pacho@gentoo.org> +libgnome-2.30.0.ebuild:
+  Add new version for Gnome 2.30.
 
   04 Jun 2010; Markus Meier <maekke@gentoo.org> libgnome-2.28.0.ebuild:
   x86 stable, bug #314899

diff --git a/gnome-base/libgnome/libgnome-2.30.0.ebuild b/gnome-base/libgnome/libgnome-2.30.0.ebuild
new file mode 100644 (file)
index 0000000..eab9b81
--- /dev/null
+++ b/gnome-base/libgnome/libgnome-2.30.0.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/gnome-base/libgnome/libgnome-2.30.0.ebuild,v 1.1 2010/06/13 16:37:05 pacho Exp $
+
+EAPI="2"
+
+inherit gnome2 eutils
+
+DESCRIPTION="Essential Gnome Libraries"
+HOMEPAGE="http://www.gnome.org/"
+
+LICENSE="LGPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd ~x86-interix ~amd64-linux ~x86-linux ~sparc-solaris ~x86-solaris"
+IUSE="branding doc esd"
+
+SRC_URI="${SRC_URI}
+       branding? ( mirror://gentoo/gentoo-gdm-theme-r3.tar.bz2 )"
+
+RDEPEND=">=gnome-base/gconf-2
+       >=dev-libs/glib-2.16
+       >=gnome-base/gnome-vfs-2.5.3
+       >=gnome-base/libbonobo-2.13
+       >=dev-libs/popt-1.7
+       esd? (
+               >=media-sound/esound-0.2.26
+               >=media-libs/audiofile-0.2.3 )"
+
+DEPEND="${RDEPEND}
+       >=dev-util/intltool-0.40
+       >=dev-util/pkgconfig-0.17
+       doc? ( >=dev-util/gtk-doc-1 )"
+
+PDEPEND="gnome-base/gvfs"
+
+DOCS="AUTHORS ChangeLog NEWS README"
+
+pkg_setup() {
+       G2CONF="${G2CONF} --disable-schemas-install $(use_enable esd)"
+}
+
+src_prepare() {
+       gnome2_src_prepare
+
+       # Make sure menus have icons. People don't like change
+       epatch "${FILESDIR}/${PN}-2.28.0-menus-have-icons.patch"
+
+       use branding && epatch "${FILESDIR}"/${PN}-2.26.0-branding.patch
+
+       sed "s:'\^\$\$lang\$\$':\^\$\$lang\$\$:g" -i po/Makefile.in.in \
+               || die "sed failed"
+}
+
+src_install() {
+       gnome2_src_install
+
+       if use branding; then
+               # Add gentoo backgrounds
+               dodir /usr/share/pixmaps/backgrounds/gnome/gentoo
+               insinto /usr/share/pixmaps/backgrounds/gnome/gentoo
+               doins "${WORKDIR}"/gentoo-emergence/gentoo-emergence.png || die "doins 1 failed"
+               doins "${WORKDIR}"/gentoo-cow/gentoo-cow-alpha.png || die "doins 2 failed"
+       fi
+}

diff --git a/gnome-base/libgnomecanvas/ChangeLog b/gnome-base/libgnomecanvas/ChangeLog
index fd349ca1f2968ef7cad6a488c0491c7c572d35a1..40b48e2eaa11087cdbda7c899e9a165527aad1a2 100644 (file)
--- a/gnome-base/libgnomecanvas/ChangeLog
+++ b/gnome-base/libgnomecanvas/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for gnome-base/libgnomecanvas
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-base/libgnomecanvas/ChangeLog,v 1.120 2010/05/03 22:17:30 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-base/libgnomecanvas/ChangeLog,v 1.121 2010/06/13 16:41:36 pacho Exp $
+
+*libgnomecanvas-2.30.1 (13 Jun 2010)
+
+  13 Jun 2010; Pacho Ramos <pacho@gentoo.org> +libgnomecanvas-2.30.1.ebuild,
+  metadata.xml:
+  Add new version for Gnome 2.30.
 
   03 May 2010; Samuli Suominen <ssuominen@gentoo.org>
   libgnomecanvas-2.20.1.1.ebuild:

diff --git a/gnome-base/libgnomecanvas/libgnomecanvas-2.30.1.ebuild b/gnome-base/libgnomecanvas/libgnomecanvas-2.30.1.ebuild
new file mode 100644 (file)
index 0000000..89656d5
--- /dev/null
+++ b/gnome-base/libgnomecanvas/libgnomecanvas-2.30.1.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/gnome-base/libgnomecanvas/libgnomecanvas-2.30.1.ebuild,v 1.1 2010/06/13 16:41:36 pacho Exp $
+
+EAPI=2
+inherit virtualx gnome2
+
+DESCRIPTION="The Gnome 2 Canvas library"
+HOMEPAGE="http://www.gnome.org/"
+
+LICENSE="LGPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
+IUSE="doc glade"
+
+RDEPEND=">=x11-libs/gtk+-2.13
+       >=media-libs/libart_lgpl-2.3.8
+       >=x11-libs/pango-1.0.1
+       glade? ( >=gnome-base/libglade-2 )"
+
+DEPEND="${RDEPEND}
+       >=dev-lang/perl-5
+       sys-devel/gettext
+       >=dev-util/intltool-0.35
+       >=dev-util/pkgconfig-0.18
+       doc? ( >=dev-util/gtk-doc-1 )"
+
+DOCS="AUTHORS ChangeLog NEWS README"
+
+pkg_setup() {
+       G2CONF="${G2CONF} $(use_enable glade)"
+}
+
+src_prepare() {
+       # Fix intltoolize broken file, see upstream #577133
+       # TODO: report upstream their translations are broken (intltool)
+       sed "s:'\^\$\$lang\$\$':\^\$\$lang\$\$:g" -i po/Makefile.in.in \
+               || die "sed failed"
+}
+
+src_test() {
+       Xmake check || die "Test phase failed"
+}

diff --git a/gnome-base/libgnomecanvas/metadata.xml b/gnome-base/libgnomecanvas/metadata.xml
index da6fd63d0085c9671e7fff5f1244f5f9e880e2d7..ea5254563c04cdabd1c7f0285d0984d85b61d4ad 100644 (file)
--- a/gnome-base/libgnomecanvas/metadata.xml
+++ b/gnome-base/libgnomecanvas/metadata.xml
@@ -2,4 +2,7 @@
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
 <herd>gnome</herd>
+<use>
+       <flag name='glade'>Enable glade support</flag>
+</use>
 </pkgmetadata>