x11-libs/qscintilla: bump to 2.10.7, EAPI 7

Package-Manager: Portage-2.3.48, Repoman-2.3.10

diff --git a/x11-libs/qscintilla/Manifest b/x11-libs/qscintilla/Manifest
index 9726cb430a4c0295cd90c5272e3877a9e51b28d9..67300618010d1c96291388562c0ecd5d0674b91d 100644 (file)
--- a/x11-libs/qscintilla/Manifest
+++ b/x11-libs/qscintilla/Manifest
@@ -1 +1,2 @@
 DIST QScintilla_gpl-2.10.4.tar.gz 2721322 BLAKE2B df50dd0a34db96dd57147ddc399d4a30751b1bb4922dc1b8b3c3c1989e810937dc8345f92128e8a606b1edc04fde4b930a424ab8344818c9899c8fe496793a77 SHA512 dee6684f68173784d098931554c839a30e129b89f980cd9704f818c44eb7023199bd3682e4b342091fa3e0ce577ec576d34046477bdd1d7fc58ca5dd2ba947a3
+DIST QScintilla_gpl-2.10.7.tar.gz 2734778 BLAKE2B 9fea764828e1c95ce842b06b06c45398b52669c0823a660bcd45a4af4a33a4a5b75b6349f84dc844e18d394c301bbb66f3485abd9f56a5c056d2b507b67a0148 SHA512 d5489a308da265f09c305128d9984b195c90003e52a55f5342c8ea50090392619425a0fc3df692aae0d09467d5b0b496b548eb31ff93cba97c9f4f406500007c

diff --git a/x11-libs/qscintilla/qscintilla-2.10.7.ebuild b/x11-libs/qscintilla/qscintilla-2.10.7.ebuild
new file mode 100644 (file)
index 0000000..aa76e89
--- /dev/null
+++ b/x11-libs/qscintilla/qscintilla-2.10.7.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit flag-o-matic qmake-utils
+
+MY_P=QScintilla_gpl-${PV/_pre/.dev}
+
+DESCRIPTION="A Qt port of Neil Hodgson's Scintilla C++ editor class"
+HOMEPAGE="https://www.riverbankcomputing.com/software/qscintilla/intro"
+SRC_URI="mirror://sourceforge/pyqt/${MY_P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0/13"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86"
+IUSE="designer doc"
+
+DEPEND="
+       dev-qt/qtcore:5
+       dev-qt/qtgui:5
+       dev-qt/qtprintsupport:5
+       dev-qt/qtwidgets:5
+       designer? ( dev-qt/designer:5 )
+"
+RDEPEND="${DEPEND}"
+
+S=${WORKDIR}/${MY_P}
+
+src_unpack() {
+       default
+
+       # Sub-slot sanity check
+       local subslot=${SLOT#*/}
+       local version=$(sed -nre 's:.*VERSION\s*=\s*([0-9\.]+):\1:p' "${S}"/Qt4Qt5/qscintilla.pro || die)
+       local major=${version%%.*}
+       if [[ ${subslot} != ${major} ]]; then
+               eerror
+               eerror "Ebuild sub-slot (${subslot}) does not match QScintilla major version (${major})"
+               eerror "Please update SLOT variable as follows:"
+               eerror "    SLOT=\"${SLOT%%/*}/${major}\""
+               eerror
+               die "sub-slot sanity check failed"
+       fi
+}
+
+qsci_run_in() {
+       pushd "$1" >/dev/null || die
+       shift || die
+       "$@" || die
+       popd >/dev/null || die
+}
+
+src_configure() {
+       if use designer; then
+               # prevent building against system version (bug 466120)
+               append-cxxflags -I../Qt4Qt5
+               append-ldflags -L../Qt4Qt5
+       fi
+
+       qsci_run_in Qt4Qt5 eqmake5
+       use designer && qsci_run_in designer-Qt4Qt5 eqmake5
+}
+
+src_compile() {
+       qsci_run_in Qt4Qt5 emake
+       use designer && qsci_run_in designer-Qt4Qt5 emake
+}
+
+src_install() {
+       qsci_run_in Qt4Qt5 emake INSTALL_ROOT="${D}" install
+       use designer && qsci_run_in designer-Qt4Qt5 emake INSTALL_ROOT="${D}" install
+
+       DOCS=( ChangeLog NEWS )
+       use doc && HTML_DOCS=( doc/html-Qt4Qt5/. )
+       einstalldocs
+}