dev-lang/nasm: switch to media-fonts/source-pro fonts

nasm has an ordered list of font preference. media-fonts/clearsans
alone is not enough to satisfy all nasm needs (see doc/psfonts.ph).

Use media-fonts/source-pro instead. This also happens to fix font
width in final generated .pdf.

Reported-by: Juergen Rose
Closes: https://bugs.gentoo.org/639038
Package-Manager: Portage-2.3.36, Repoman-2.3.9

diff --git a/dev-lang/nasm/nasm-2.13.03-r1.ebuild b/dev-lang/nasm/nasm-2.13.03-r1.ebuild
new file mode 100644 (file)
index 0000000..c0c02a3
--- /dev/null
+++ b/dev-lang/nasm/nasm-2.13.03-r1.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit flag-o-matic
+
+DESCRIPTION="groovy little assembler"
+HOMEPAGE="http://www.nasm.us/"
+SRC_URI="http://www.nasm.us/pub/nasm/releasebuilds/${PV/_}/${P/_}.tar.xz"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~x64-cygwin ~amd64-linux ~x86-linux ~x64-macos"
+IUSE="doc"
+
+# [fonts note] doc/psfonts.ph defines ordered list of font preference.
+# Currently 'media-fonts/source-pro' is most preferred and is able to
+# satisfy all 6 font flavours: tilt, chapter, head, etc.
+DEPEND="
+       dev-lang/perl
+       doc? (
+               app-text/ghostscript-gpl
+               dev-perl/Font-TTF
+               dev-perl/Sort-Versions
+               media-fonts/source-pro
+               virtual/perl-File-Spec
+       )
+"
+
+S=${WORKDIR}/${P/_}
+PATCHES=(
+       "${FILESDIR}"/${PN}-2.13.01-fix-docdir.patch
+       "${FILESDIR}"/${PN}-2.13.01-gcc-8.patch
+)
+
+src_configure() {
+       strip-flags
+       default
+}
+
+src_compile() {
+       default
+       use doc && emake doc
+}
+
+src_install() {
+       default
+       emake DESTDIR="${D}" install_rdf $(usex doc install_doc '')
+}