dev-libs/xmlsec: version bump

Closes: https://bugs.gentoo.org/show_bug.cgi?id=671228
Signed-off-by: Alon Bar-Lev <alonbl@gentoo.org>
Package-Manager: Portage-2.3.51, Repoman-2.3.11

diff --git a/dev-libs/xmlsec/Manifest b/dev-libs/xmlsec/Manifest
index 3c8103ad8a77cb44fc934662254d759569ab8b0f..7b78da91ee148463a2caf7c67c75c5282e023da1 100644 (file)
--- a/dev-libs/xmlsec/Manifest
+++ b/dev-libs/xmlsec/Manifest
@@ -1 +1,2 @@
 DIST xmlsec1-1.2.26.tar.gz 1922183 BLAKE2B 8cb8557a7d24df756655a7dfa45091445adc89cb67169a7620d9d1116f3fb3d982ea45199a53475e29300478c07e8e1168cec79cf9c3b5ff1dd6c840123b982b SHA512 1e3dc3c8c192eefee7b055787bef52ce3bcfafa786224f68af065aa45f4d7da93232da973359b3135615c5981ad4df7c124047d3934e552ab78439472685a7a4
+DIST xmlsec1-1.2.27.tar.gz 2013651 BLAKE2B fa46a25e3aaef432134d1c98a0e7bf0aba83f2ef6d1aff3774d6d37c5f6f392d1c2c11a0fe433ee910c39b56400c96b74ab061577948622b14a1116fa1ec2947 SHA512 01f7231d7d7ac8037aecc1f922acc572cbfe0903abf5bd5879d836438c36684e23402b803d20806fff6b1cdc5ad9af114d1341b10b336f71c0bce28b4716f920

diff --git a/dev-libs/xmlsec/xmlsec-1.2.27.ebuild b/dev-libs/xmlsec/xmlsec-1.2.27.ebuild
new file mode 100644 (file)
index 0000000..be5606a
--- /dev/null
+++ b/dev-libs/xmlsec/xmlsec-1.2.27.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools
+
+DESCRIPTION="Command line tool for signing, verifying, encrypting and decrypting XML"
+HOMEPAGE="https://www.aleksey.com/xmlsec"
+SRC_URI="https://www.aleksey.com/xmlsec/download/${PN}1-${PV}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="doc gcrypt gnutls libressl nss +openssl static-libs"
+REQUIRED_USE="|| ( gcrypt gnutls nss openssl )
+       gnutls? ( gcrypt )"
+
+RDEPEND=">=dev-libs/libxml2-2.7.4
+       >=dev-libs/libxslt-1.0.20
+       gcrypt? ( >=dev-libs/libgcrypt-1.4.0:0 )
+       gnutls? ( >=net-libs/gnutls-2.8.0 )
+       nss? (
+               >=dev-libs/nspr-4.4.1
+               >=dev-libs/nss-3.9
+       )
+       openssl? (
+               !libressl? ( dev-libs/openssl:0= )
+               libressl? ( dev-libs/libressl:0= )
+       )"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+S="${WORKDIR}/${PN}1-${PV}"
+
+src_prepare() {
+       default
+       # conditionally install extra documentation
+       if ! use doc ; then
+               sed -i '/^SUBDIRS/s/docs//' Makefile.am || die
+               eautoreconf
+       fi
+}
+
+src_configure() {
+       econf \
+               --enable-pkgconfig \
+               --with-html-dir=/usr/share/doc/${PF}/html \
+               $(use_enable static-libs static) \
+               $(use_with gcrypt gcrypt "") \
+               $(use_with gnutls gnutls "") \
+               $(use_with nss nspr "") \
+               $(use_with nss nss "") \
+               $(use_with openssl openssl "") \
+               $(use_enable openssl aes)
+}
+
+src_test() {
+       emake TMPFOLDER="${T}" check
+}
+
+src_install() {
+       default
+       find "${D}" -name '*.la' -delete || die
+}