dev-python/flask: bump to 1.0.2

* EAPI 7
* Python 3.7

Package-Manager: Portage-2.3.47, Repoman-2.3.10

diff --git a/dev-python/flask/Manifest b/dev-python/flask/Manifest
index 27d6d17b9fac3023e5bb17c71fa77a2af66f2b44..5ba04ead1a6ee9e7d6610d1babb77b340db5f6e4 100644 (file)
--- a/dev-python/flask/Manifest
+++ b/dev-python/flask/Manifest
@@ -1 +1,2 @@
 DIST Flask-0.12.2.tar.gz 548510 BLAKE2B bd92d0e7e6ff36d371ffd958708517d16e41d1475af9153bf3d5234c33aa5c0ab415cbd254b711731cf8cffddac94b475f62d9fff2f9fe756b0fa30bb36d4343 SHA512 c00bb807e8fbc943e23a3721acf5b04320e7a58d658bca46bdf83a345b4c4d5729accae338505e134f01bc908adec9555fd94e8c87ef6f0367e6037215c06319
+DIST Flask-1.0.2.tar.gz 644534 BLAKE2B dd024f6f7a68691c759e3fd494a9482c4ab5216b5c7486fc1717346f953678c3198deedd657e7ddd3a5deff57ce31b1afdc40ef2ba9cc2fbed48f3afc223f6d0 SHA512 0ddf5d8bb0b0ae61f990096dffe3cf02744d7986015d05ae2cc09dfe0def17df44e2a4c58e330d17c7bd8c3eb74014dee5e2edef6e300b8e4ed756c251938f52

diff --git a/dev-python/flask/flask-1.0.2.ebuild b/dev-python/flask/flask-1.0.2.ebuild
new file mode 100644 (file)
index 0000000..6b34003
--- /dev/null
+++ b/dev-python/flask/flask-1.0.2.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 python3_{5,6,7} pypy{,3} )
+
+inherit distutils-r1
+
+DESCRIPTION="A microframework based on Werkzeug, Jinja2 and good intentions"
+HOMEPAGE="https://github.com/pallets/flask/"
+MY_PN="Flask"
+MY_P="${MY_PN}-${PV}"
+if [[ ${PV} == *9999* ]]; then
+       EGIT_REPO_URI="https://github.com/mitsuhiko/flask.git"
+       inherit git-r3
+else
+       SRC_URI="mirror://pypi/${MY_P:0:1}/${MY_PN}/${MY_P}.tar.gz"
+       KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+       S="${WORKDIR}/${MY_P}"
+fi
+
+LICENSE="BSD"
+SLOT="0"
+IUSE="doc examples test"
+
+RDEPEND="dev-python/click[${PYTHON_USEDEP}]
+       dev-python/blinker[${PYTHON_USEDEP}]
+       dev-python/itsdangerous[${PYTHON_USEDEP}]
+       >=dev-python/jinja-2.10[${PYTHON_USEDEP}]
+       >=dev-python/werkzeug-0.14[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+       dev-python/setuptools[${PYTHON_USEDEP}]
+       doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+       test? ( dev-python/pytest[${PYTHON_USEDEP}] )"
+
+python_prepare_all() {
+       # Prevent un-needed d'loading
+       sed -e "s/ 'sphinx.ext.intersphinx',//" -i docs/conf.py || die
+       distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+       use doc && emake -C docs html
+}
+
+python_test() {
+       PYTHONPATH=${S}/examples/flaskr:${S}/examples/minitwit${PYTHONPATH:+:${PYTHONPATH}} \
+               py.test -v || die "Testing failed with ${EPYTHON}"
+}
+
+python_install_all() {
+       use examples && dodoc -r examples
+       use doc && HTML_DOCS=( docs/_build/html/. )
+
+       distutils-r1_python_install_all
+}

diff --git a/dev-python/flask/flask-9999.ebuild b/dev-python/flask/flask-9999.ebuild
index 3329ccaa5a94b43939e413b973eff89f65ce732f..6b340034d5173466f4afa94ba991e03d326640be 100644 (file)
--- a/dev-python/flask/flask-9999.ebuild
+++ b/dev-python/flask/flask-9999.ebuild
@@ -1,14 +1,14 @@
 # Copyright 1999-2018 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=6
+EAPI=7
 
-PYTHON_COMPAT=( python2_7 python3_{4,5,6} )
+PYTHON_COMPAT=( python2_7 python3_{5,6,7} pypy{,3} )
 
 inherit distutils-r1
 
 DESCRIPTION="A microframework based on Werkzeug, Jinja2 and good intentions"
-HOMEPAGE="https://pypi.org/project/Flask/"
+HOMEPAGE="https://github.com/pallets/flask/"
 MY_PN="Flask"
 MY_P="${MY_PN}-${PV}"
 if [[ ${PV} == *9999* ]]; then
@@ -16,7 +16,7 @@ if [[ ${PV} == *9999* ]]; then
        inherit git-r3
 else
        SRC_URI="mirror://pypi/${MY_P:0:1}/${MY_PN}/${MY_P}.tar.gz"
-       KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86"
+       KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
        S="${WORKDIR}/${MY_P}"
 fi
 
@@ -24,21 +24,29 @@ LICENSE="BSD"
 SLOT="0"
 IUSE="doc examples test"
 
-RDEPEND="dev-python/blinker[${PYTHON_USEDEP}]
-       >=dev-python/itsdangerous-0.21[${PYTHON_USEDEP}]
-       >=dev-python/jinja-2.4[${PYTHON_USEDEP}]
-       >=dev-python/werkzeug-0.7[${PYTHON_USEDEP}]"
+RDEPEND="dev-python/click[${PYTHON_USEDEP}]
+       dev-python/blinker[${PYTHON_USEDEP}]
+       dev-python/itsdangerous[${PYTHON_USEDEP}]
+       >=dev-python/jinja-2.10[${PYTHON_USEDEP}]
+       >=dev-python/werkzeug-0.14[${PYTHON_USEDEP}]"
 DEPEND="${RDEPEND}
        dev-python/setuptools[${PYTHON_USEDEP}]
        doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
        test? ( dev-python/pytest[${PYTHON_USEDEP}] )"
 
+python_prepare_all() {
+       # Prevent un-needed d'loading
+       sed -e "s/ 'sphinx.ext.intersphinx',//" -i docs/conf.py || die
+       distutils-r1_python_prepare_all
+}
+
 python_compile_all() {
        use doc && emake -C docs html
 }
 
 python_test() {
-       py.test tests || die "Testing failed with ${EPYTHON}"
+       PYTHONPATH=${S}/examples/flaskr:${S}/examples/minitwit${PYTHONPATH:+:${PYTHONPATH}} \
+               py.test -v || die "Testing failed with ${EPYTHON}"
 }
 
 python_install_all() {