games-puzzle/sgt-puzzles: bump to 20190415

Package-Manager: Portage-2.3.62, Repoman-2.3.12
Signed-off-by: Göktürk Yüksek <gokturk@gentoo.org>

diff --git a/games-puzzle/sgt-puzzles/Manifest b/games-puzzle/sgt-puzzles/Manifest
index ba22b7f38572ac4eb6997f947775872815562235..032390917eebd254c07ed1956508a647af7020cb 100644 (file)
--- a/games-puzzle/sgt-puzzles/Manifest
+++ b/games-puzzle/sgt-puzzles/Manifest
@@ -1,2 +1,3 @@
 DIST puzzles-20171029.69773d8.tar.gz 2923623 BLAKE2B 2e97005aa5ea7e95b4f312067d406fd37f5f89638b335c5eee748f4d8c2977f663cde91ea29d57ffb1cb3eb5264cad36a46106dc8f14ddedcb0dc5f4b3e4c1f6 SHA512 ca9885bcadd0bb979167f2f0b6129a17aeab6d7fd31eeabc9d29ab526a5a137b03f1f4aea7a268109c5aee1a522d514bf522ad25673705f50addd685401d7fb8
+DIST puzzles-20190415.e2135d5.tar.gz 3286744 BLAKE2B 6b19cde3f95b5375bde74923a5f8e3deb9abb7d4d737ad5f2d18aa7895b973a9ca1ed4a495cf80da8390ed7fb63f1eb973c8053d52145e5752c56e38d3ac19d7 SHA512 5f38c96cff4e745a1c1615762c0e5f3f3dd056ff7dbf0f80a5953e658ae1460503c6394fe29301f5682485d6a6121869853a270dc60327821a3059ca6d971fa1
 DIST sgt-puzzles-icons-20160315.tar.xz 715536 BLAKE2B c50b3a6a0d0f8a052215dd9fba7c3eca5822bc7f866a825ad5e92391bb1867d141793877bc7c4545cc6da674bf273752612f7d3578a6a05b22cc2552ea798ce6 SHA512 2fe2c02984eb8c36ac6fb4195be7895b336b84f40ce8baeb23dc8a32aca9937ccf1d33050b4da3cfba3c87e124ecbdd940ee4e990b37eabe8e2af897c2e23b57

diff --git a/games-puzzle/sgt-puzzles/sgt-puzzles-20190415.ebuild b/games-puzzle/sgt-puzzles/sgt-puzzles-20190415.ebuild
new file mode 100644 (file)
index 0000000..687d723
--- /dev/null
+++ b/games-puzzle/sgt-puzzles/sgt-puzzles-20190415.ebuild
@@ -0,0 +1,116 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit eutils gnome2-utils toolchain-funcs autotools
+
+if [[ ${PV} == "99999999" ]] ; then
+       inherit git-r3
+       EGIT_REPO_URI="https://git.tartarus.org/simon/puzzles.git"
+       GENTOO_ICONS="20160315"
+       SRC_URI="https://dev.gentoo.org/~np-hardass/distfiles/${PN}/${PN}-icons-${GENTOO_ICONS}.tar.xz"
+       KEYWORDS=""
+else
+       MAGIC=e2135d5
+       SRC_URI="https://www.chiark.greenend.org.uk/~sgtatham/puzzles/puzzles-${PV}.${MAGIC}.tar.gz"
+       S=${WORKDIR}/puzzles-${PV}.${MAGIC}
+       KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="Simon Tatham's Portable Puzzle Collection"
+HOMEPAGE="https://www.chiark.greenend.org.uk/~sgtatham/puzzles/"
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="+doc gtk3"
+
+COMMON_DEPEND="
+       !gtk3? ( x11-libs/gtk+:2 )
+       gtk3? ( x11-libs/gtk+:3 )"
+
+RDEPEND="${COMMON_DEPEND}
+       x11-misc/xdg-utils" # Used by builtin help patch
+
+DEPEND="${COMMON_DEPEND}
+       dev-lang/perl
+       virtual/pkgconfig
+       doc? ( >=app-doc/halibut-1.2 )"
+
+PATCHES=( "${FILESDIR}/${PN}-20161207-builtin-help.patch" )
+
+src_unpack() {
+       default
+       if [[ ${PV} == "99999999" ]]; then
+               git-r3_src_unpack
+       fi
+}
+
+src_prepare() {
+       default
+
+       sed -i \
+               -e 's|-Werror||g' \
+               configure.ac || die
+       sed -i \
+               -e 's/-O2 -Wall .* -g/-Wall/' \
+               -e "s/libstr =/libstr = '\$(LDFLAGS) ' ./" \
+               mkfiles.pl || die
+       ./mkfiles.pl || die
+       eautoreconf
+
+       # Import icons from latest Gentoo tarball for live
+       if [[ ${PV} == "99999999" ]]; then
+               cp -R ../${PN}-icons/icons . || die
+       fi
+}
+
+src_configure() {
+       econf \
+               --program-prefix="${PN}_" \
+               --with-gtk=$(usex gtk3 3 2)
+}
+
+src_compile() {
+       emake CC="$(tc-getCC)"
+       if use doc ; then
+               halibut --text --html --info --pdf --ps puzzles.but || die
+       fi
+}
+
+src_install() {
+       default
+
+       local file name
+       for file in *.R ; do
+               [[ ${file} == "nullgame.R" ]] && continue
+               name=$(awk -F: '/exe:/ { print $3 }' "${file}")
+               file=${file%.R}
+               newicon -s 48 icons/${file}-48d24.png ${PN}_${file}.png
+               make_desktop_entry "${PN}_${file}" "${name}" "${PN}_${file}" "Game;LogicGame;X-${PN};"
+       done
+
+       if use doc ; then
+               DOCS=( puzzles.{pdf,ps,txt} )
+               HTML_DOCS=( *.html )
+               einstalldocs
+               doinfo puzzles.info{,-1,-2,-3}
+       fi
+
+       insinto /etc/xdg/menus/applications-merged
+       doins "${FILESDIR}/${PN}.menu"
+       insinto /usr/share/desktop-directories
+       doins "${FILESDIR}/${PN}.directory"
+}
+
+pkg_preinst() {
+       gnome2_icon_savelist
+}
+
+pkg_postinst() {
+       gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+       gnome2_icon_cache_update
+}

diff --git a/games-puzzle/sgt-puzzles/sgt-puzzles-99999999.ebuild b/games-puzzle/sgt-puzzles/sgt-puzzles-99999999.ebuild
index 7eaeac646bc6704589355a1fcae40c0297a552b6..687d7238d44cbadb835e1a33f9e22ef09587f01d 100644 (file)
--- a/games-puzzle/sgt-puzzles/sgt-puzzles-99999999.ebuild
+++ b/games-puzzle/sgt-puzzles/sgt-puzzles-99999999.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2018 Gentoo Foundation
+# Copyright 1999-2019 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=6
@@ -12,7 +12,7 @@ if [[ ${PV} == "99999999" ]] ; then
        SRC_URI="https://dev.gentoo.org/~np-hardass/distfiles/${PN}/${PN}-icons-${GENTOO_ICONS}.tar.xz"
        KEYWORDS=""
 else
-       MAGIC=69773d8
+       MAGIC=e2135d5
        SRC_URI="https://www.chiark.greenend.org.uk/~sgtatham/puzzles/puzzles-${PV}.${MAGIC}.tar.gz"
        S=${WORKDIR}/puzzles-${PV}.${MAGIC}
        KEYWORDS="~amd64 ~x86"