gnome-extra/cinnamon-settings-daemon: New upstream version 4.0.2

Signed-off-by: Kristian Fiskerstrand <k_f@gentoo.org>
Package-Manager: Portage-2.3.51, Repoman-2.3.11

diff --git a/gnome-extra/cinnamon-settings-daemon/Manifest b/gnome-extra/cinnamon-settings-daemon/Manifest
index 509210bf4f743ccf998f6d23fa5b047d52ab73c3..c6222a451b25da1d248686b00bedd4c1c4ecd98d 100644 (file)
--- a/gnome-extra/cinnamon-settings-daemon/Manifest
+++ b/gnome-extra/cinnamon-settings-daemon/Manifest
@@ -1,2 +1,3 @@
 DIST cinnamon-settings-daemon-3.6.1.tar.gz 995005 BLAKE2B c512fe53b707099dca0926893f03056d508bbe22026367c3212a99f22df60d629e02e080fccdeb73151c7aa7e93396b47bede1820059f4a53eace11a56ae5521 SHA512 48a28decff08a191f4ec604386c3bb5c07001d4bc4f7b6d1da379626b41650653fdd14205bbed5321c41fbc281e8638b17e1de30dbba5d299f79cde03216cb33
 DIST cinnamon-settings-daemon-3.8.4.tar.gz 660607 BLAKE2B 1db6e8677c9f9e1fc649d29b3de46d2797f01dbaad3a907329eb6781c6c4ec17706d06045ae230315c7802a5ea176dda73dfcd437fd07e3398ad732e96240a83 SHA512 5bd91e781d47413b50b69b6a8d4cbe9060579452db7408d375f01b05b4070caa684d333ef875a7dda85d1acad3442cddd38e13167fa198e3a5540fef7bedfb75
+DIST cinnamon-settings-daemon-4.0.2.tar.gz 662735 BLAKE2B 158e2ee120e2b359c6d84aa52c6b2c9214148fcf48cdc8ed9c777344f21ce82b5c3e4d0b358046abb1de8fc23a43b7cced02b77b43c1230fc2d97db58423e125 SHA512 3e51628339ae7766c37090c82a7550e2f925843ca62ef9cca606568c9771a8f16035735b3db612aae0938553fd37fb6eaf8d30437baa501160221d1b71d0e94e

diff --git a/gnome-extra/cinnamon-settings-daemon/cinnamon-settings-daemon-4.0.2.ebuild b/gnome-extra/cinnamon-settings-daemon/cinnamon-settings-daemon-4.0.2.ebuild
new file mode 100644 (file)
index 0000000..1a4d83a
--- /dev/null
+++ b/gnome-extra/cinnamon-settings-daemon/cinnamon-settings-daemon-4.0.2.ebuild
@@ -0,0 +1,87 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+GNOME2_LA_PUNT="yes"
+
+inherit autotools eutils gnome2 virtualx
+
+DESCRIPTION="Cinnamon's settings daemon"
+HOMEPAGE="http://cinnamon.linuxmint.com/"
+SRC_URI="https://github.com/linuxmint/cinnamon-settings-daemon/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+colord cups input_devices_wacom smartcard systemd"
+RESTRICT=test
+
+# udev is non-optional since lots of plugins, not just gudev, pull it in
+RDEPEND="
+       >=dev-libs/glib-2.38:2
+       >=gnome-base/libgnomekbd-3.6
+       >=gnome-base/librsvg-2.36.2
+       >=gnome-extra/cinnamon-desktop-2.8.0:0=
+       media-libs/fontconfig
+       >=media-libs/lcms-2.2:2
+       media-libs/libcanberra:0=[gtk3]
+       sys-apps/dbus
+       >=sys-auth/polkit-0.97
+       x11-libs/gdk-pixbuf:2
+       >=x11-libs/gtk+-3.9.10:3
+       >=x11-libs/libnotify-0.7.3:0=
+       x11-libs/libX11
+       x11-libs/libXext
+       x11-libs/libXfixes
+       x11-libs/libXi
+       x11-libs/libxklavier
+       virtual/libgudev:=
+       >=sys-power/upower-0.9.11
+
+       colord? ( >=x11-misc/colord-0.1.27:= )
+       cups? ( >=net-print/cups-1.4[dbus] )
+       input_devices_wacom? (
+               >=dev-libs/libwacom-0.7
+               x11-drivers/xf86-input-wacom
+               x11-libs/libXtst )
+       smartcard? ( >=dev-libs/nss-3.11.2 )
+       systemd? ( sys-apps/systemd:0= )
+       !systemd? (     sys-auth/elogind:0= )
+"
+DEPEND="${RDEPEND}
+       dev-libs/libxml2:2
+       >=dev-util/intltool-0.37.1
+       x11-base/xorg-proto
+       virtual/pkgconfig
+"
+
+src_prepare() {
+       # make colord and wacom optional
+       eapply "${FILESDIR}"/${PN}-3.0.1-optional.patch
+       eapply "${FILESDIR}"/${PN}-3.8.0-accountservice.patch
+
+       # Disable broken test
+       sed -e '/g_test_add_func ("\/color\/edid/d' \
+               -i plugins/color/gcm-self-test.c || die
+
+       eautoreconf
+       gnome2_src_prepare
+}
+
+src_configure() {
+       # no point in disabling gudev since other plugins pull it in
+       gnome2_src_configure \
+               --disable-static \
+               --enable-gudev \
+               --enable-polkit \
+               --enable-logind \
+               --disable-accountservice \
+               $(use_enable colord color) \
+               $(use_enable cups) \
+               $(use_enable smartcard smartcard-support) \
+               $(use_enable input_devices_wacom wacom)
+}
+
+src_test() {
+       virtx emake check
+}