net-analyzer/cacti-spine: Version 1.2.9

Package-Manager: Portage-2.3.88, Repoman-2.3.20
Signed-off-by: Jeroen Roovers <jer@gentoo.org>

diff --git a/net-analyzer/cacti-spine/Manifest b/net-analyzer/cacti-spine/Manifest
index 9cc03813bf6ebde705ee8e598a9f2b848cce1147..fc71161be344ba90cb34b0a25a64183a828215bf 100644 (file)
--- a/net-analyzer/cacti-spine/Manifest
+++ b/net-analyzer/cacti-spine/Manifest
@@ -1 +1,2 @@
 DIST cacti-spine-1.2.8.tar.gz 106801 BLAKE2B 813d4b6d4a4a632cc6d59c5c4eeeb37df78995ca5952e77204a9b5f8b599b34fe043b9f8c1ae81ad20600c08403ff06c04119db53bb03e37788fc11e5e39be6a SHA512 7f9a90f5e41a8a72d0068321b119f5ed7768fd7939bf5a994627b2f199158440639e88d31da35444e28fb73f8dbb57c1012f01ae09d24f0478d8e75a21bb942a
+DIST cacti-spine-1.2.9.tar.gz 106572 BLAKE2B 803d16b6708e4cc5fc5ea9a5cb49bfd535fea421a873ce9baf74e1de75597a5a4941a909219d729e291ff3201c0f9c2a8304381144d935778ef331779395c688 SHA512 668b25cb89fad331ae4bc726b797bbeade74c90500af348748a995be0de2f699264cd24e98ea709214453328058e1dba6399dca2074bb6ce71e0d4b434b9dee4

diff --git a/net-analyzer/cacti-spine/cacti-spine-1.2.9.ebuild b/net-analyzer/cacti-spine/cacti-spine-1.2.9.ebuild
new file mode 100644 (file)
index 0000000..a5c1da2
--- /dev/null
+++ b/net-analyzer/cacti-spine/cacti-spine-1.2.9.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit autotools
+
+MY_P=${PN}-${PV/_p/-}
+
+DESCRIPTION="Spine is a fast poller for Cacti (formerly known as Cactid)"
+HOMEPAGE="https://cacti.net/spine_info.php"
+SRC_URI="https://www.cacti.net/downloads/spine/${MY_P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~hppa ~ppc ~ppc64 ~sparc ~x86"
+IUSE="libressl"
+
+CDEPEND="
+       !libressl? ( dev-libs/openssl:0= )
+       libressl? ( dev-libs/libressl:0= )
+       net-analyzer/net-snmp:=
+       dev-db/mysql-connector-c:0=
+"
+DEPEND="
+       ${CDEPEND}
+       sys-apps/help2man
+"
+RDEPEND="
+       ${CDEPEND}
+       >net-analyzer/cacti-0.8.8
+"
+PATCHES=(
+       "${FILESDIR}"/${PN}-0.8.8g-net-snmp.patch
+)
+
+src_prepare() {
+       default
+
+       eautoreconf
+}
+
+src_install() {
+       dosbin spine
+
+       insinto /etc/
+       insopts -m0640 -o root
+       newins spine.conf{.dist,}
+
+       doman spine.1
+       dodoc CHANGELOG
+}