dev-python/boto3: add python3_7

Package-Manager: Portage-2.3.48, Repoman-2.3.10

diff --git a/dev-python/boto3/boto3-1.9.4-r1.ebuild b/dev-python/boto3/boto3-1.9.4-r1.ebuild
new file mode 100644 (file)
index 0000000..c4a2a22
--- /dev/null
+++ b/dev-python/boto3/boto3-1.9.4-r1.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 python3_4 python3_5 python3_6 python3_7 )
+
+inherit distutils-r1 vcs-snapshot
+
+DESCRIPTION="The AWS SDK for Python"
+HOMEPAGE="https://github.com/boto/boto3"
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE="doc test"
+
+if [[ "${PV}" == "9999" ]]; then
+       EGIT_REPO_URI="https://github.com/boto/boto3"
+       inherit git-r3
+else
+       SRC_URI="https://github.com/boto/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+       KEYWORDS="~amd64 ~arm64 ~x86 ~amd64-linux ~x86-linux"
+fi
+
+RDEPEND="
+       >=dev-python/botocore-1.12.4[${PYTHON_USEDEP}]
+       dev-python/jmespath[${PYTHON_USEDEP}]
+       dev-python/s3transfer[${PYTHON_USEDEP}]
+"
+DEPEND="
+       dev-python/setuptools[${PYTHON_USEDEP}]
+       doc? (
+               dev-python/guzzle_sphinx_theme[${PYTHON_USEDEP}]
+               dev-python/sphinx[${PYTHON_USEDEP}]
+       )
+       test? (
+               ${RDEPEND}
+               dev-python/mock[${PYTHON_USEDEP}]
+               dev-python/nose[${PYTHON_USEDEP}]
+       )
+"
+
+python_compile_all() {
+       use doc && emake -C docs html
+}
+
+python_test() {
+       nosetests -v tests/unit/ tests/functional/ || die "test failed under ${EPYTHON}"
+}
+
+python_install_all() {
+       use doc && local HTML_DOCS=( docs/build/html/. )
+
+       distutils-r1_python_install_all
+}

diff --git a/dev-python/boto3/boto3-9999.ebuild b/dev-python/boto3/boto3-9999.ebuild
index d62092d13cee7101055e22f0d2f4135c1bd485bf..c4a2a2204096a7590d8443254a0d106556c7ba6e 100644 (file)
--- a/dev-python/boto3/boto3-9999.ebuild
+++ b/dev-python/boto3/boto3-9999.ebuild
@@ -2,7 +2,7 @@
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=6
-PYTHON_COMPAT=( python2_7 python3_4 python3_5 python3_6 )
+PYTHON_COMPAT=( python2_7 python3_4 python3_5 python3_6 python3_7 )
 
 inherit distutils-r1 vcs-snapshot